Code: Ability Resource Thread

FamiliaWerneck said:

Just a quick question. Is there a limit for how many characteres I can use to make an ability description?
Because I was expanding an already expanded table, and all the descriptions that were there already took up 32 characters (the ones that didn't had FFs completing it until they were 32 bytes long).
But the very first ability I try to insert is longer than that (I'm reinserting it, actually, thus I know it's already in the game and it has more than 32 characters).
If they don't have a limit, why the first abilities I read had all FFs completing 32 bytes? Also, if I can use more than 32 characters, how can I do it? Just an FF between two abilities descriptions is enough?

Click to expand...

MrDollSteak said:

Emerald you can't, but Fire Red you can probably push it to about 50-60?

Click to expand...

MrDollSteak said:

I have fixed that damn routine so many times haha, it definitely compiles now.

Click to expand...

mamamama said:

Prankster, Gale Wing etc.:The routine still wont compile for me. Thumb closes down too fast for me to have a look, but there seems to be two lines that creates the failure.

Overcoat: Works fine in Hail and Sandstorm. However, it doesn't stop Stun Spore/Effect Spore etc. from working (1st routine) and the game resets when an Overcoated 'mon uses an attack such as pound on an effect spore 'mon (2nd routine).

No Guard: The ability itself seems to work fine now. Still a problem with toxic though. Toxic now misses as if it were a non-poison 'mon using it even though the 'mon is a poison-type.

Click to expand...

LCCoolJ95 said:

You're supposed to Paste Write, not Paste Insert.

Click to expand...

MrDollSteak said:

Magic Guard, Overcoat

Click to expand...

Sky High said:

This isn't Ability-related but I wonder if Safety Goggles can be included there. The item's effect is to immune weather-related damage and powder moves.

Click to expand...

KDS said:

Parental Bond:-

Fire Red:-

Spoiler:

Routine I:

Spoiler:

Code:

.text
.align 2
.thumb
.thumb_func
.global parentallock

ParentalMultiStopper:
      ldr r1, .ParentalByte
      mov r8, r1
      ldrb r0, [r1]
      cmp r0, #0x0
      bne Exit

ParentalAbilityCheck:
      ldr r2, .BattleStruct
      mov r9, r2
      ldr r4, .UserBank
      mov r6, #0x58
      ldrb r1, [r4]
      mul r1, r6
      add r1, r1, r2
      add r1, #0x20
      ldrb r0, [r1]
      cmp r0, [B][U]#0xBA[/U][/B]
      bne Exit

MoveBanListCheck:
      ldr r7, .CurrMove
      ldrh r1, [r7]
      lsl r0, r1, #0x01
      add r1, r1, r0
      lsl r1, r1, #0x02
      ldr r2, .MoveData
      add r2, r2, r1
      mov r10, r2

CheckForStatusMove:
      ldrb r2, [r2, #0xA]
      cmp r2, #0x2
      beq Exit
      ldr r2, .TableLoc
      ldr r3, =0xFEFE

Loop:
      ldrh r5, [r2]
      cmp r5, r3
      beq DoubleBattleCheck
      cmp r5, r7
      beq Exit
      add r2, #0x2
      b Loop

DoubleBattleCheck:
      mov r5, r9
      ldr r0, .BattleTypeFlags
      ldr r0, [r0, #0x0]
      mov r1, #0x1
      and r0, r1
      cmp r0, #0x0
      beq SingleTargetHPCheck
      mov r1, r10
      ldrb r0, [r1, #0x6]
      mov r2, #0x0       
      cmp r0, #0x8
      beq NoOfFoeCheck
      cmp r0, #0x20
      bne SingleTargetHPCheck

UserPartnerHP:
      ldrb r3, [r4]
      mov r1, #0x2
      eor r3, r1 
      mul r3, r6
      add r3, r5
      ldrh r0, [r3, #0x28]
      cmp r0, #0x0
      beq NoOfFoeCheck
      add r2, #0x1

NoOfFoeCheck:
      ldrb r3, [r4]
      mov r1, #0x1
      eor r3, r1
      and r3, r1
      mul r3, r6
      add r3, r5
      ldrh r0, [r3, #0x28]
      cmp r0, #0x0
      beq CheckNextIter
      add r2, #0x1 

CheckNextIter:
      lsl r6, r6, #0x1
      add r3, r6
      ldrh r0, [r3, #0x28]
      cmp r0, #0x0
      beq CheckNoOfAliveTargets
      add r2, #0x1
 
CheckNoOfAliveTargets:
      cmp r2, #0x1
      beq Success
      cmp r2, #0x2
      blt Exit

SetParentalBan:
      mov r1, r8
      mov r0, #0x3
      strb r0, [r1]
      b Exit

SingleTargetHPCheck:
      ldrb r3, [r4, #0x1]
      mul r3, r6
      add r3, r5
      ldrh r0, [r3, #0x28]
      cmp r0, #0x0
      beq Exit

Success:
      mov r1, r8
      mov r0, #0x2
      strb r0, [r1]

Exit:
      mov r0, #0x0
      mov r9, r0
      ldr r1, =0x2023FC8
      ldr r2, =0x2023FE8
      mov r10, r1
      mov r8, r2
      ldr r0, =0x8019302+1
      bx r0

.align 2
.ParentalByte: .word 0x0203C03C
.BattleStruct: .word 0x02023BE4
.UserBank: .word 0x02023D6B
.CurrMove: .word 0x02023D4A
[B].MoveData: .word 0x08250C04[/B]
[B].TableLoc: .word 0x08DDDDDD[/B]
.BattleTypeFlags: .word 0x02022B4C
/*At x192E0: 00 48 00 47 XX+1 XX XX 08*/

Table at DDDDDD

Code:

04 00 0C 00 0D 00 18 00 13 00 1F 00 20 00 29 00 2A 00 4C 00 5A 00 82 00 83 00 8C 00 8F 00 9A 00 9B 00 A7 00 C6 00 03 00 78 00 5E 01 DC 00 FB 00 12 01 23 01 24 01 49 01 4D 01 54 01 61 01 F8 00 5B 00 13 00 8F 00 99 00 1B 01 FE FE

This is a table that contains the indices (Half Words) of damaging moves not supported by Parental Bond like Multi-Hit, Charging Turn Moves etc. Terminated by FEFE. Add indices for new moves like Dual Chop, Double Hit etc.

Routine II:

Spoiler:

Code:

.text
.align 2
.thumb
.thumb_func
.global parentalbond

ParentalChecker:
      ldr r1, .ParentalByte
      mov r8, r1
      ldrb r0, [r1]
      cmp r0, #0x2
      bne Exit

CheckOutcome:
      ldr r1, .Outcome
      ldrb r0, [r1]
      mov r1, #0x29
      and r0, r1
      cmp r0, #0x0
      bne Exit

UserHPCheck:
      ldr r2, .BattleStruct
      ldr r4, .UserBank
      mov r6, #0x58
      ldrb r1, [r4]
      mul r1, r6
      add r1, r1, r2
      ldrh r0, [r1, #0x28]
      cmp r0, #0x0
      beq Exit

TargetHPCheck:
      ldrb r1, [r4, #0x1]
      mul r1, r6
      add r1, r1, r2
      ldrh r0, [r1, #0x28]
      cmp r0, #0x0
      beq Exit 

CheckDamage:
      ldr r2, .DamageStruct
      add r0, r4, #0x1
      ldrb r1, [r0, #0x0]
      lsl r0, r1, #0x2
      add r0, r0, r1
      lsl r1, r0, #0x2
      add r0, r1, #0x4
      add r0, r0, r2
      ldr r1, [r0, #0x0]
      cmp r1, #0x0
      beq Exit

CheckAsleep:
      ldr r5, .HitMarker
      ldr r2, [r5]
      mov r0, #0x80
      lsl r0, r0, #0xC
      and r0, r2
      cmp r0, #0
      bne Exit
      
Success:
      mov r0, #0x80
      lsl r0, r0, #0x4
      orr r2, r0
      str r2, [r5] /*Avoid PP Reduction Next Strike */
      mov r1, r8
      ldr r2, .CurrMove
      mov r8, r2
      mov r0, #0x1
      strb r0, [r1]
      mov r4, #0x0
      ldr r0, =0x80232F8+1
      bx r0 

Exit:
      ldr r0, =0x8023BAC+1
      bx r0

.align 2
.ParentalByte: .word 0x0203C03C
.BattleStruct: .word 0x02023BE4
.DamageStruct: .word 0x02023ECC
.Outcome: .word 0x02023DCC
.UserBank: .word 0x02023D6B
.CurrMove: .word 0x02023D4A
.HitMarker: .word 0x02023DD0

Make the pointer to this routine the 3rd last entry of Jump Table in cmd49 while expanding it as donehere .

Routine III:

Spoiler:

Code:

.text
.align 2
.thumb
.thumb_func
.global childturnaccuracy

CheckChildTurn:
  ldr r4, .ParentalByte
  ldrb r4, [r4]
  ldr r0, .ScriptPointer
  cmp r4, #0x1
  bne Exit

EnsureAccuracy:
   ldr r1, [r0]
   add r1, #0x7
   str r1, [r0]
   ldr r0, =0x0801E1C2+1
   bx r0  

Exit:
   ldr r0, [r0]
   ldrb r6, [r0, #5]
   ldrb r0, [r0, #6]
   lsl r0, r0, #8
   orr r6, r0
   ldr r0, =0x801DDDC+1
   bx r0

.align 2
.ParentalByte: .word 0x0203C03C
.ScriptPointer: .word 0x02023D74


/*At x1ddd0: 00 48 00 47 XX+1 XX XX 08*/

Routine IV:

Spoiler:

Code:

.text
.align 2
.thumb
.thumb_func
.global childturnpower

CheckChildTurn:
  ldr r4, .ParentalByte
  ldrb r4, [r4]
  cmp r4, #0x1
  bne Exit

HalfDamage:
  ldr r4, .Damage
  ldrh r5, [r4]
  lsr r5, r5, #0x1
  cmp r5, #0x0
  bne NotZero
  mov r5, #0x1

NotZero:
  strh r5, [r4]

Exit:
   ldr r0, [r1]
   add r0, #0x1
   str r0, [r1]
   add sp, #0x10
   pop {r4-r7}
   pop {r0}
   bx r0

.align 2
.ParentalByte: .word 0x0203C03C
.Damage: .word 0x02023D50

/*At x1e644: 00 4C 20 47 XX+1 XX XX 08*/

Routine V:

Spoiler:

Code:

.text
.align 2
.thumb
.thumb_func
.global restoreabilities
     
EndTurn:
         ldr r0, .Outcome
    mov r1, #0x0
    strb r1, [r0]
    ldr r0, .Index
    strb r1, [r0]
        ldr r0, .ParentalByte
        strb r1, [r0]
RestoreAbilities:
    push {r2-r6}
    ldr r4, .Battlers
    ldrb r4, [r4]
    mov r3, #0x0
    ldr r5, .DisabledAbilityLoc
    ldr r6, .BattleData
Loop:
    ldrb r2 [r5, #0x0]
    cmp r2, #0x0
    beq EndLoop
    strb r2, [r6]
    strb r1, [r5]
EndLoop:
    add r3, r3, #0x1
    cmp r3, r4
    bge Exit
    add r5, r5, #0x1
    add r6, r6, #0x58
    b Loop
Exit:
    pop {r2-r6}
    ldr r1, .EndLoc
    mov r0, #0xB
    strb r0, [r1]
    bx lr

.align 2

.Outcome: .word 0x02023DCC
.Index: .word 0x02023BC4
.Battlers: .word 0x02023D6C
.DisabledAbilityLoc: .word 0x0203C034
.BattleData: .word 0x02023C04
.EndLoc: .word 0x02023BE3
.ParentalByte: .word 0x203C03C

@ Go to your Battle Script command table, search for CD 2C 02 08 and replace it by XX+1 XX XX 08 (We are replacing the 'End' Battle Script Command. Not the case in Emerald)

Basically the 4th Mold Breaker Routine with added logic to clear the Parental Byte.

Bugs

Spoiler:

Does not handle Knock Off, Smelling Salts and Color Change as done in Gen VI. This due to the differences in order between Gen VI and Gen III handling of events during a Move Execution.

Click to expand...

i0Bjhansen0 said:

What script editor is being used for these routines or can XSE use these when compiling?
I would like to make some new abilities for the new types in my hack. What is the routine (or offset so I can reverse engineer) for Overgrow, Swarm, Blaze, and/or Torrent so I can change the type to be one of the new ones.
And finally, after expanding the ability names and descriptions (PGE comes with a tool to do that), how would I get the game to know to use the routines? What offset would I need to change to make it work?

Thanks in advance.

Click to expand...

DizzyEgg said:

I was confused about this at first too. I'll try to explain how abilities or rather ability's effect work in battle. Pokemon ability is stored in a certain battle struct and is always retrieved from there. Each ability has an ID, a byte in order in the abilities names table. There are no routines for each specific ability. Mostly there are three places where abilities are checked, first being damage calc, second being accuracy checker and most important being giant ability_battle_effects function. So swarm for example works like this:
damage calculator code...
if (attacker_ability == SWARM and move_type == BUG and has less than 31 % of max hp)
{
damage = damage * 1.5;
}
rest of the code...
As you can see, abilities are checked at run time. Now, I suggest you take a copy of FR or EM IDA, look at offset locations in this thread and see how battle functions work.
So to answer, if you expand the ability and want the game to recognize it, you just have to do something like this in your code:
if (pokes_ability == ID_of_new_ability)
do something;
And again, some of the abilities are placed at many places, like there are checks for white smoke and clear smog in stat lowering function or there's a wonder guard check in the type damage calc.

Also, I think this thread becomes more and more unusable. There are about 100 new abilities in gens IV-VI and they all have to be hooked somewhere. I'm not even talking about the time to assemble and insert every routine that's here but also about how the hook locations may contradict each other and how changes to it become more difficult. The solution would be a partial rewrite of the battle engine compiled dynamically(preferably done in C), something that FBI's doing but to a much smaller degree.

Click to expand...

EdgeZard X said:

So I have Mr DS's ROM base, and know how to insert the ASM for the abilities, but how would I go about adding the names and descriptions?

Also, how would one go about creating Poison Touch for Fire Red?

Click to expand...