joexv said:

And also (no offense to knizz) the skip into thats been made sucks. I tested it yesterday and It dosesnt support save files, which for a lot of people really sucks because they dont use save states.
So a new one would be great.

Click to expand...

LocksmithArmy said:

I did not think about that...
lol

Click to expand...

FBI agent said:

You're completely right, it skips all the way till the overworld. Actually just skipping the intro will probably not be as easy as I want it to be. I remember editing out the rival naming and freezing the game right after. I'll look into it, but no promises :P

EDIT: Nvm he has an option to remove just the oak + tutorial rather than intro +titlescreen as well. Unless you've tried all combinations ;x

Click to expand...

FBI agent said:

What are you trying to achieve here? It's much easier to calculate average level of Player's party, then set the storage Pokemon's levels to the calculated amount. Would you like me to make a routine for that?

Click to expand...

joexv said:

Ive tried it. removing the oak pat is what screws it up.

Click to expand...

Knight of Duty said:

Where is the search party pokemon code? I was unable to find it.

Click to expand...

longlostsoldier said:

If you would like to. I was planning to grab the average level for the party compare level, tho'. (I see I wasn't clear enough in my comments) What I was doing was, if one level (base party average over stored pokemon) was bigger, get exp worth the difference of the two levels and add it, simply enough. I think my method will work. XD Now I feel like a goof. I read somewhere the EXP location moves around, and that different pokemon have different EXP to level rates, so I thought it would be a pain altering it, but you wrote a routine altering it so obviously you feel comfortable doing that.

My other thought was altering the levels directly without altering the EXP as well would not work / result in bugs, which was why I did not think to try, but you'd be more of an expert on that than me.

I admit I am not used to having help, so it often doesn't occur to me to ask for much.... even though this thread requests routines for you to write. I know that's goofy.

Click to expand...

Set static party level

.text
.align 2
.thumb
.thumb_func

main:
	push {r0-r7, lr}
	mov r7, #0x0

loop:
	ldr r6, =(0x2024029)
	ldrb r6, [r6]
	cmp r7, r6
	beq end
	ldr r0, =(0x2024284)
	mov r1, #0x64
	mul r1, r1, r7
	push {r7}
	add r0, r0, r1@addr
	mov r4, r0

set_level:
	mov r1, #0xB
	push {r4}
	ldr r3, = (0x803FBE8 +1) @get species
	bl linker
	pop {r4}
	mov r2, r0
	ldr r6, =(0x8253AE4)
	ldr r1, =(0x8254784)
	lsl r0, r2, #0x3
	sub r0, r0, r2
	lsl r0, r0, #0x2
	add r1, r1, r0
	ldrb r0, [r1, #0x13]
	mov r5, #0xCA
	lsl r5, r5, #0x1
	mul r0, r0, r5
	add r0, r0, r6
	ldr r1, .VAR
	ldrb r1, [r1]
	mov r3, #0x4
	mul r1, r1, r3
	add r1, r1, r0
	ldr r1, [r1]
	ldr r2, = (0x20370D0)
	str r1, [r2]
	mov r0, r4
	push {r4}
	mov r1, #0x19
	ldr r3, =(0x804037C +1)
	bl linker
	pop {r4}
	mov r0, r4
	ldr r3, =(0x803E47C +1)
	bl linker
		
next:
	pop {r7}
	add r7, r7, #0x1
	b loop	

end:
	pop {r0-r7, pc}
	
linker:
	bx r3
	

.align 2

.VAR:
	.word 0x020270B8 + (0x8000 *2)

FF B5 00 27 1A 4E 36 78 B7 42 2D D0 19 48 64 21 79 43 80 B4 40 18 04 1C 0B 21 10 B4 16 4B 00 F0 24 F8 10 BC 02 1C 15 4E 15 49 D0 00 80 1A 80 00 09 18 C8 7C CA 25 6D 00 68 43 80 19 0B 49 09 78 04 23 59 43 09 18 09 68 0E 4A 11 60 20 1C 10 B4 19 21 0D 4B 00 F0 09 F8 10 BC 20 1C 0B 4B 00 F0 04 F8 80 BC 01 37 CD E7 FF BD 18 47 B8 70 03 02 29 40 02 02 84 42 02 02 E9 FB 03 08 E4 3A 25 08 84 47 25 08 D0 70 03 02 7D 03 04 08 7D E4 03 08

FBI agent said:

Np, Touched and Bela have done this for Pokemon Rose. I'll consult the sensei :P


First post has an index to all of my other routines. The search party pokemon one is called "party checker".




You're about 50% right. You can't just set level, as it's derived from EXP. You need to increment the exp sufficiently by a percentage of current EXP to increase the level. I did this in the silent evolution method to keep the Player's pokemon in the same level. It was often the case that from going from something like a magikarp to gyarados would decrease the level by 1-2 due to the experience required to achieve said level.

Anyways, inorder for you to achieve this you'd need 4 routine calls, or 1 really long one.
1) get average lvl of party
2) swap party and storage
3) adjust current party's level to match number from 1)
4) swap party and storage

Thankfully 1, 2, and 4 are already done. Here's 3:

Set static party level

First of all, I need to mention that this routine works off percentage increases and decreases. So if you're planning to go from level 1 to 100 all in one go for 6 Pokemon it will take around 5 seconds to increment about 35 million experience points. The reason for the percentage increase is so that we don't go over. This was a pain to test, as in some occasions the percentage between levels 1-2 would be enough to set negative exp, and sometimes the levels 99 -100 would set exp over 100...it was just a huge pain.

How to insert:

Compile and insert into free space the following routine:

Spoiler:

Code:

.text
.align 2
.thumb
.thumb_func

main:
    push {r0-r7, lr}
    ldr r6, =(0x2024029)
    ldrb r6, [r6]
    mov r5, #0x0

loop:
    cmp r5, r6
    beq end
    ldr r0, =(0x2024284)
    mov r1, #0x64
    mul r1, r1, r5
    add r0, r0, r1@addr
    mov r4, r0 @save current poke
    mov r1, #0x19
    push {r4-r6}
    ldr r3, =(0x803FBE8 +1)@get current exp
    bl linker
    pop {r4-r6}
    mov r7, r0
    mov r0, r4
    mov r1, #0x38
    push {r4-r6}
    ldr r3, =(0x803FBE8 +1) @currentLevel
    bl linker
    pop {r4}
    ldr r1, .VAR
    ldrb r1, [r1]
    cmp r0, r1 @should we add or subtract exp?
    bhi subExp
    cmp r2, r1
    beq next

addExp:
    mov r0, r7
    cmp r0, #0x10
    bhi standardAdd
    lsl r0, r0, #0x1 @ exp = exp * 2
    b contAdd

standardAdd:
    lsr r0, r0, #0x4 @ exp = exp + (exp/16)

contAdd:
    add r0, r0, r7 @exp to set
    b setExp
    

subExp:
    mov r0, r7
    cmp r0, #0x10
    bhi standardSub
    lsr r0, r0, #0x1 @exp = exp - (exp/2)
    b contSub

standardSub:
    lsr r0, r0, #0x3 @exp = exp - (exp/8)

contSub:
    sub r0, r7, r0

setExp:
    mov r7, r0
    ldr r2, =(0x20370D0)
    str r0, [r2]
    mov r0, r4
    mov r1, #0x19
    push {r4}
    ldr r3, =(0x804037C +1) @set exp
    bl linker
    pop {r4}
    mov r0, r4
    push {r4}
    ldr r3, =(0x803E47C +1)
    bl linker
    pop {r4}
    mov r0, r4
    push {r4}
    mov r1, #0x38
    ldr r3, =(0x803FBE8 +1)
    bl linker
    pop {r4}
    ldr r2, .VAR
    ldrb r2, [r2]
    cmp r2, r0
    beq next
    cmp r2, r0
    bhi addExp
    b subExp
    
next:
    pop {r5-r6}
    add r5, r5, #0x1
    b loop    

end:
    pop {r0-r7, pc}
    
linker:
    bx r3
    

.align 2

.VAR:
    .word 0x020270B8 + (0x8000 *2)

Here is a compiled version:

Code:

FF B5 2A 4E 36 78 00 25 B5 42 48 D0 28 48 64 21 69 43 40 18 04 1C 19 21 70 B4 26 4B 00 F0 40 F8 70 BC 07 1C 20 1C 38 21 70 B4 22 4B 00 F0 38 F8 10 BC 1C 49 09 78 88 42 09 D8 8A 42 2C D0 38 1C 10 28 01 D8 40 00 00 E0 00 09 C0 19 06 E0 38 1C 10 28 01 D8 40 08 00 E0 C0 08 38 1A 07 1C 16 4A 10 60 20 1C 19 21 10 B4 14 4B 00 F0 19 F8 10 BC 20 1C 10 B4 12 4B 00 F0 13 F8 10 BC 20 1C 10 B4 38 21 0C 4B 00 F0 0C F8 10 BC 06 4A 12 78 82 42 02 D0 82 42 D3 D8 DA E7 60 BC 01 35 B4 E7 FF BD 18 47 C0 46 B8 70 03 02 BA 70 03 02 29 40 02 02 84 42 02 02 E9 FB 03 08 D0 70 03 02 7D 03 04 08 7D E4 03 08

Usage:
setvar 0x8000 0x[Level you want Pokemon to be set to (in hex)]
callasm 0x[this routine +1]

That's it. I should mention, you should apply this as often as possible to speed up the computation time for next time.

Click to expand...

longlostsoldier said:

Ahhh, okay, I thought it was something like that. And wow, you're fast.

This function is pretty useful! Decreases as well as increases? Off the top of my head, it could be used for depowered pokemon events where you're hit by a machine and all your pokemon go down, and then after the event go back up again, or getting a new team all leveled the same as your old one, or a fake mega-rare candy item that boosts by several levels instead of one, or an event where temporarily all your pokemon are level 100, or crazier things like that.

Just one question, if it takes 5 seconds to go from 1 to 100, what's the ideal range for a quick increase/decrease? Under 10 levels?

Click to expand...

Team Fail said:

Compiled for your pleasure:

Code:

00 DF 00 00

Click to expand...

FBI agent said:

Forced Evolution (silently):

(with animation to come at a later date).

How to insert:
Compile and insert into free space the following routine:

Spoiler:

Code:

.text
.align 2
.thumb
.thumb_func

main:
	push {r0-r7, lr}
	ldr r0, .SLOT @calculate address of Pokemon we want to evolve
	ldrh r0, [r0]
	mov r1, #0x64
	mul r0, r0, r1
	ldr r1, =(0x2024284)
	add r0, r0, r1
	mov r7, r0
	mov r1, #0xB 
	ldr r3, =(0x803FBE8 +1) @get current species, prior to evolving
	bl linker
	mov r5, r0
	bl getEvolvedForm @check what species it evolves into
	mov r6, r0
	mov r0, r7
	mov r1, #0x38
	ldr r3, =(0x803FBE8 +1) @save level before evolution
	bl linker
	mov r4, r0

SetEvolve:
	mov r0, r7 @evolve it
	ldr r2, .VAR
	mov r1, r6
	strh r1, [r2]
	mov r1, #0xB
	ldr r3, =(0x804037C +1)
	bl linker
	mov r0, r7
	ldr r3, =(0x803E47C +1) @recalculate stats
	bl linker

AddToDex:
	mov r0, r6
	ldr r3, =(0x8043298 +1) @get dex index of species
	bl linker
	mov r0, r6
	mov r1, #0x2
	ldr r3, =(0x8088E74 +1) @normal dex
	bl linker
	mov r0, r6
	mov r1, #0x3
	ldr r3, =(0x8088E74 +1) @national
	bl linker

FinishCalc:
	mov r0, r7 @check current level (after evolving)
	mov r1, #0x38
	ldr r3, =(0x803FBE8 +1)
	bl linker
	cmp r0, r4 @exp curves skewed level
	bne AdjustLvl
	b Nickname

getEvolvedForm:
	mov r1, #0x4 @calculate the evolution of a species
	mul r1, r1, r0
	add r0, r0, r1
	lsl r0, r0, #0x03
	ldr r3, = (0x8259754)
	add r1, r0, r3
	ldrh r0, [r1, #0x2] @evolution 2 i.e Pidgeot
	ldrh r2, [r1, #0x4] @evolution 1 i.e Pidgeotto
	cmp r0, r2
	bgt setter
	bx lr

setter:
	mov r0, r2 @give next evolved form
	bx lr

Nickname:
	mov r0, r7
	ldr r1, =(0x2021CD0) @store current nickname here
	mov r2, r1
	mov r1, #0x2
	ldr r3, =(0x803FBE8 +1)
	bl linker
	ldr r0, =(0x8245EE0)@calculate species default name
	mov r1, #0xB
	mul r1, r1, r5
	add r1, r1, r0
	mov r5, r1
	ldr r1, =(0x2021CD0)
	mov r4, r1
	mov r0, #0x0
	
checkEqual:
	cmp r0, #0xA            @While nickname has char
	beq setName
	add r5, r5, #0x1        @get next char of species name
	ldrb r1, [r5]
	add r4, r4, #0x1        @get next char of nickname
	ldrb r2, [r4]
	cmp r2, r1                @if x != y ==> has nickname
	bne end
	cmp r2, #0xFF          @strings are 0xFF terminated
	beq checkOne
	b contLoop

checkOne:
	cmp r1, #0xFF
	beq setName
	b end

contLoop:
	add r0, r0, #0x1 @loop counter ++
	b checkEqual

setName:
	ldr r2, =(0x8245EE0) @set nickname as species name
	mov r0, #0xB
	mul r6, r6, r0
	add r6, r6, r2
	mov r0, r7
	mov r2, r6
	mov r1, #0x2
	ldr r3, =(0x804037C +1)
	bl linker
	b end
	
	
AdjustLvl:
	cmp r0, r4
	beq Nickname
	mov r2, r0
	mov r0, r7
	mov r1, #0x19
	ldr r3, =(0x803FBE8 +1) @x = currentExp * 1.1
	bl linker
	mov r1, r0
	lsr r0, #0x4
	cmp r2, r4           @if current lvl < old lvl; currentExp -= x
	bls subtract
	add r1, r1, r0 
	b updateExp
	
subtract:
	sub r1, r1, r0       @else currentExp += x

updateExp:
	ldr r2, .VAR
	str r1, [r2]
	mov r1, #0x19
	mov r0, r7
	ldr r3, =(0x804037C +1)
	bl linker
	mov r0, r7
	ldr r3, =(0x803E47C +1)
	bl linker
	mov r0, r7
	mov r1, #0x38
	ldr r3, =(0x803FBE8 +1)
	bl linker
	b AdjustLvl


end:
	pop {r0-r7, pc}
	
 
linker:
	bx r3
	

.align 2

.VAR:
	.word 0x20270B8 + (0x8000 *2) @change to any 2 byte free space in RAM
.SLOT:
	.word 0x20270B8 + (0x8001 *2) @slot of Pokemon to evolve

Here's a compiled version:

Code:

FF B5 49 48 00 88 64 21 48 43 48 49 40 18 07 1C 0B 21 47 4B 00 F0 84 F8 05 1C 00 F0 29 F8 06 1C 38 1C 38 21 42 4B 00 F0 7B F8 04 1C 38 1C 3D 4A 31 1C 11 80 0B 21 3F 4B 00 F0 72 F8 38 1C 3E 4B 00 F0 6E F8 30 1C 3D 4B 00 F0 6A F8 30 1C 02 21 3B 4B 00 F0 65 F8 30 1C 03 21 39 4B 00 F0 60 F8 38 1C 38 21 32 4B 00 F0 5B F8 A0 42 37 D1 0C E0 04 21 41 43 40 18 C0 00 32 4B C1 18 48 88 8A 88 90 42 00 DC 70 47 10 1C 70 47 38 1C 2E 49 0A 1C 02 21 27 4B 00 F0 44 F8 2C 48 0B 21 69 43 09 18 0D 1C 29 49 0C 1C 00 20 0A 28 0D D0 01 35 29 78 01 34 22 78 8A 42 32 D1 FF 2A 00 D0 02 E0 FF 29 02 D0 2C E0 01 30 EF E7 20 4A 0B 20 46 43 B6 18 38 1C 32 1C 02 21 17 4B 00 F0 22 F8 1F E0 A0 42 D3 D0 02 1C 38 1C 19 21 11 4B 00 F0 19 F8 01 1C 00 09 A2 42 01 D9 09 18 00 E0 09 1A 09 4A 11 60 19 21 38 1C 0B 4B 00 F0 0B F8 38 1C 0A 4B 00 F0 07 F8 38 1C 38 21 06 4B 00 F0 02 F8 DF E7 FF BD 18 47 C0 46 B8 70 03 02 BA 70 03 02 84 42 02 02 E9 FB 03 08 7D 03 04 08 7D E4 03 08 99 32 04 08 75 8E 08 08 54 97 25 08 D0 1C 02 02 E0 5E 24 08

Usage:

Set the slot of the Pokemon you want to evolve in var 0x8001 (0x0 to 0x5). Then callasm to this routine and the rest is done automagically.

You can use this routine in conjunction with the checkItem routine to make a Pokemon evolve if it's holding an Item. Or if you wanted an evolution scene inside the Overworld this is useful too.
Like I said, an animated version will come out later once I figure out a way to fix some bugs. No promises on the date, it's very complicated :P

Click to expand...

Team Fail said:

Just take the compiled code and paste it at those offsets as-is. No need to flip it or anything.

Click to expand...

Team Fail said:

No. At the two offsets in my post, take the bytes that I put there and put them exactly as is at those offsets. You do not have to repoint anything or make a script to call it.

Click to expand...

Lance32497 said:

Manaphy Egg
A routine that lets you have more than 1 egg but only for a certain pokemon.

and about Manaphy's breeding style, I didnt get an answer if it was accepted or not.

Click to expand...

Lance32497 said:

I test it and IT AWESOMELY WORKS!!!!!!!!

Click to expand...

Touched-sensei said:

HEX EDIT

0x12EB54: 45 66 05 08
0x054A68: 3C 4C
0x054A6A: 20 68
0x054A6C: 00 49
0x054A6E: 01 E0
0x054A7E: 34 4E
0x054B3A: 00 00
0x054B3C: 00 00
0x054A70: REVERSED POINTER TO TEXT CONTAINING YOUR DEFAULT NAME (max 8 chars, last char must be 0)

Click to expand...

FBI agent said:

I don't think anyone really cares about Manaphy breeding, lol. It's not a very featured Pokemon in many people's hacks. Current FR has a breeding strat for it implemented as is, iirc.

Click to expand...

FBI agent said:

What do you mean by routine that lets you have more than 1 egg? You can already have more than 1 egg :P

Click to expand...

FBI agent said:

Pokemon Storage (outside the PC)

Basically, in it's current state, this is effectively a storage system. It stores Pokemon and can be interacted with by the player to withdraw or deposit Pokemon. It's standalone from the PC storage system and is also much smaller (I've limited it to 6, but it can go upto 47). Some things that you will be able to do with this routine (and conjunction with some smaller ones) include:
- Extra Pokemon storage, you can possibly get a little over 1 box worth
- Flash back battles (complete swap between stored Pokemon and party Pokemon with capabilities to swap back)
- Carry a party of greater than 6 Pokemon (you can use the 2nd party for HM slaves, or whatever)
- Trade evolver guy! He will take your Pokemon and then when you come back it can be evolved! (silent evolution ftw!)
- Separate Daycare holding larger amount of Pokemon at once

I've tested it thoroughly and there doesn't seem to be any problems. I will be adding more and more features into this because I believe that it has the potential to become a very useful feature.
Currently planning to add:
- Party swap completely all in one go (this will actually be in the very near future..maybe today even :P)
- Partial swapping (believe it or not, this is hard because there's no graphical support)
- Suggest me more :D

How to insert:

Compile into free space the following routine:

Spoiler:

Code:

.text
.align 2
.thumb
.thumb_func

main:
	push {r0, r4, lr}
	ldr r0, .FROM
	ldr r1, [r0]
	cmp r1, #0x0 @party
	beq addParty

addStorage:
	ldr r0, .STORAGE
	sub r0, r0, #0x1
	ldrb r1, [r0]
	cmp r1, #0x6 @limit of storage. Change depending on your space situation
	beq end
	add r0, r0, #0x1
	mov r2, #0x50
	cmp r1, #0x0
	beq skipline
	sub r1, r1, #0x1
	mul r1, r1, r2
	add r0, r0, r1 @destination
	ldr r1, =(0x20370C0)
	ldrb r1, [r1]
	ldr r2, .PARTY
	mov r3, #0x64
	mul r1, r1, r3
	add r1, r1, r2 @source
	mov r2, #0x50 @size
	ldr r3, =(0x8040B08 +1) @func
	bl linker
	@need to fix up Player's party slots
	ldr r1, =(0x20370C0)
	ldrb r1, [r1]
	cmp r1, #0x5
	beq writeLastZero
	mov r2, #0x5
	sub r2, r2, r1
	mov r3, #0x64
	mul r2, r2, r3 @size
	ldr r0, .PARTY
	mul r1, r1, r3
	add r0, r0, r1 @dest
	add r3, r3, r0
	mov r1, r3      @src
	ldr r3, =(0x8040B08 +1) @func
	bl linker
	

writeLastZero:
	ldr r0, =(0x2024478)
	mov r1, #0x0
	mov r2, #0x64
	ldr r3, =(0x81E5ED8 +1)
	bl linker

correctCounters:
	ldr r0, .STORAGE
	sub r0, r0, #0x1
	ldrb r2, [r0]  @pks in storage counter
	ldr r1, =(0x2024029)
	ldrb r3, [r1] @pks in party
	add r2, r2, #0x1
	strb r2, [r0]
	sub r3, r3, #0x1
	strb r3, [r1]
	b end
	


addParty:
	ldr r0, =(0x2024029)
	ldrb r0, [r0]
	cmp r0, #0x6
	beq end
	ldr r1, .PARTY
	mov r2, #0x64
	mul r0, r0, r2
	add r0, r0, r1 @destination
	mov r4, r0
	ldr r3, .STORAGE
	ldr r1, =(0x20370C0) @var 0x8004 determines which slot of storage to take from
	ldrb r1, [r1]
	mov r2, #0x50 @size
	mul r1, r1, r2
	add r1, r1, r3 @source
	ldr r3, =(0x8040B08 +1) @func
	bl linker
	@update stats 
	mov r0, r4
	ldr r3, =(0x803E47C +1)
	bl linker
	@adjust the storage
	ldr r0, =(0x20370C0)
	ldrb r0, [r0]
	cmp r0, #0x5 @storage limit minus 1
	beq writeZero
	mov r2, #0x5
	sub r2, r2, r0
	mov r3, #0x50
	mul r2, r2, r3 @size
	ldr r1, .STORAGE
	mul r0, r0, r3
	add r0, r0, r1 @dest
	add r3, r3, r0
	mov r1, r3      @src
	ldr r3, =(0x8040B08 +1) @func
	bl linker

writeZero:
	ldr r0, .STORAGE
	mov r1, #0xC8
	lsl r1, r1, #0x1
	add r0, r0, r1
	mov r1, #0x0
	mov r2, #0x50
	ldr r3, =(0x81E5ED8 +1)
	bl linker

updateCounters:
	ldr r0, .STORAGE
	sub r0, r0, #0x1
	ldrb r2, [r0]
	ldr r1, =(0x2024029)
	ldrb r3, [r1]
	sub r2, r2, #0x1
	strb r2, [r0]
	add r3, r3, #0x1
	strb r3, [r1]

end:
	pop {r0-r4, pc}	

linker:
	bx r3	
	
.align 2

.FROM:
	.word 0x20270B8 + (0x8000 *2)

.STORAGE:
	.word 0x203C001 @storage location

.PARTY:
	.word 0x2024284 @player's party

Here's a compiled version:

Code:

11 B5 38 48 01 68 00 29 32 D0 37 48 01 38 01 78 06 29 65 D0 01 30 50 22 51 43 40 18 34 49 09 78 32 4A 64 23 59 43 89 18 50 22 32 4B 00 F0 59 F8 2F 49 09 78 05 29 0B D0 05 22 52 1A 64 23 5A 43 2A 48 59 43 40 18 1B 18 19 1C 2A 4B 00 F0 49 F8 29 48 00 21 64 22 29 4B 00 F0 43 F8 22 48 01 38 02 78 27 49 0B 78 01 32 02 70 01 3B 0B 70 37 E0 23 48 00 78 06 28 33 D0 1C 49 64 22 50 43 40 18 04 1C 19 4B 1A 49 09 78 50 22 51 43 C9 18 19 4B 00 F0 27 F8 20 1C 1B 4B 00 F0 23 F8 14 48 00 78 05 28 0B D0 05 22 12 1A 50 23 5A 43 0E 49 58 43 40 18 1B 18 19 1C 0F 4B 00 F0 13 F8 0A 48 C8 21 49 00 40 18 00 21 50 22 0C 4B 00 F0 0A F8 06 48 01 38 02 78 0A 49 0B 78 01 3A 02 70 01 33 0B 70 1F BD 18 47 B8 70 03 02 01 C0 03 02 84 42 02 02 C0 70 03 02 09 0B 04 08 78 44 02 02 D9 5E 1E 08 29 40 02 02 7D E4 03 08

Usage:

The routine itself manages party storage and storage extraction. What you need to do is determine which one it performs.
If you want to remove a Pokemon from the party and into storage, setvar 0x8000 anything but zero
if you want to remove a Pokemon from storage, setvar 0x8000 0x0
Which variable you used can be changed, as always, by editing the pointer at the bottom of the routine.
The next thing is variable 0x8004. I use this variable to determine the slot of extraction for both the Party and the Storage system.
If I wanted to take the 3rd Pokemon in the party and put it in storage:
setvar 0x8004 0x2
setvar 0x8000 0x1
callasm 0x[routine] +1

The reason for this is to support easy use of special 0x9F. Though you can use copyvar, I suppose.

Finally, the routine writes to RAM a counter, which keeps track of how many Pokemon are in the storage.
This is written at 0x203C000, and can be retrieved by using the "copybyte" scripting command. For example:
copybyte 0x20370D0 0x203C000 'puts the storage counter into variable 0x800D (lastresult).

I tried to keep it simple, and do the work inside the routine, hopefully that paid off.
Here's a very poor sample script. Poor because it handles all the cases, but it doesn't display the system's full potential :P

Spoiler:

PKSV script.

Code:

#dyn 0x740000
#org @start
lock
faceplayer
copybyte 0x20370D0 0x203C000 ' storage count into last result
compare LASTRESULT 0x0
if == jump @putOnly
msgbox @add
callstd MSG_YESNO 'want to take?
compare LASTRESULT 0x1
if == jump @addParty
jump @putOnly

#org @putOnly
countpokemon
copyvar 0x8000 0x800D
compare 0x8000 0x1
if <= jump @greetings
msgbox @put
callstd MSG_YESNO 'want to put?
compare LASTRESULT 0x1
if == jump @addStorage
msgbox @exit
callstd MSG_NORMAL
release
end

#org @addStorage
setvar 0x8000 0x1
special 0x9F
waitspecial
countpokemon
compare LASTRESULT 0x8004
if < jump @noSelection
callasm 0x[routine +1]
msgbox @gave
callstd MSG_NORMAL
release
end


#org @addParty
setvar 0x8000 0x0
countpokemon
compare LASTRESULT 0x6
if == jump @fullP
msgbox @store
callstd MSG_NORMAL
setvar 0x8004 0x0 'gotta rework this to work a better way
callasm 0x[routine +1]
fanfare 0x101
msgbox @complete
callstd MSG_NORMAL
release
end

#org @greetings
msgbox @hello
callstd MSG_NORMAL
release
end

#org @fullP
msgbox @full
callstd MSG_NORMAL
release
end

#org @noSelection
msgbox @exit
callstd MSG_NORMAL
release
end

#org @full
= You're party is full!

#org @hello
= Hi, I can't do anything\nyour slots are full or empty\lor mine are full while yours are\lfull[.]

#org @complete
= I gave it back.

#org @store
= Alright, I'll give it to you.

#org @gave
= Thanks for giving me this.

#org @exit
= Alright, next time then.

#org @add
= Want your Pokemon back?

#org @put
= Want to give me a pokemon?

That's it for now. Keep an eye out for "addons" for this routine in the future :)
Sorry for the double post. I like seperate posts for my routines to keep the first post's links neat :x

Click to expand...

Lance32497 said:

Aww, It really cares for me because I am creating a rom that the title "Pokemon Sea Temple" and it talkes about manaphy.

Click to expand...

Lance32497 said:

Aww, It really cares for me because I am creating a rom that the title "Pokemon Sea Temple" and it talkes about manaphy.
I mean The Regular Egg and Manaphy Egg

Click to expand...

I successfully compiled the routine but it always loads

Everytime I click the pokemon I want to give to him, he always says that.

Click to expand...

joexv said:

I wouldnt ind seeing this. I would love to have more than one egg design . I know its graphical but it would oonly need to copy the original routine for showing images and just change the offset.

Click to expand...

Lance32497 said:

Porting Pokemon Emerald Tag-team Battle
I dont think if it requires graphics editing but Ill try,
can you port Emerald Tagteam battle?
Like Steven in Mossdeep

Click to expand...

MrDollSteak said:

Hey FBI, finally posting in here.
Love all the routines, the Snag Ball is great and thanks for beating me there.

Click to expand...

One possible thing I'd like to see is a Trainer Back Sprite swap akin to JPan's one, although his
didn't work 100% correctly AFAIK.

Maybe setting a var which changes which back sprite you load, ie. The Dude, Old Man trainer catch,
etc. based off the Trainer Back Sprite table.

Click to expand...

Also I know you mainly hack Fire Red, but I'll have a go at porting these to Emerald and giving you the code, just so people can have more options.

Click to expand...

FBI agent said:

You didn't even start on the snag ball did you :P?


I'll look into that, np.



If you want to convert to Emerald, go ahead, these routines can be used in whichever way you'd like. Sadly, idc about any ROM that's not FR, so I won't ever be converting them myself. I'm still trying to wrap my head around why people hack non-FR ROMs when doing 3rd generation Pokemon hacking. Fire Red has more research done on it, more routines available for it, and imo, it's got the prettiest default graphics. You might argue that Emerald has more base features on it, but most of these features have been ported already, and we have more routines by hackers for FR. Fire Red master race, long live Fire Red.

Click to expand...

Team Fail said:

Reset game after loss of a battle

So, wanting to do something similar to older Final Fantasy games, in which the game goes back to the title screen after your party falls, I dove into knizz's IDB and used a lot of trial and error to create this little feature. Let it be my first contribution to ASM hacking.

Use the following ASM:

Code:

.text
.align 2
.thumb
.thumb_func

main:
	SWI 0;

.align 2

Compiled for your pleasure:

Code:

00 DF 00 00

at offsets 0x7F5B6 and 0x7F5D0 to reset the game after displaying the "...player scurried <home/PC>" text.

Credits to FBI for the ASM, shinyquagsire for explaining what this is to me in layman's terms, as well as an improvement, and to knizz for his amazing IDB that helped me find these offsets.

This can be useful for nuzlocke hackers that wish to implement a Savegame delete function when a battle is lost, by simply making a different function, namely, a delete savefile function, and putting a pointer at those offsets instead of my reset code. It can also be useful as a way to create a "GAME OVER" screen of sorts (Just edit the text as necessary). I put those offsets as is because there's enough room for either a very small ASM routine, or a pointer to a location for a different routine in case you want to do more things.

Also, the reason there's two pointers for this is because there's two different cases I have to handle: One for heading back home after losing, and one for heading to the Pokémon Center. That should cover virtually all cases of loss, but I might have missed a few. If I did, let me know, and I'll find and edit in the additional offsets to modify.

Click to expand...

MrDollSteak said:

Well you sure did get that right ahaha!

Awesome thanks!
..other text about ROM bases...

Click to expand...

Lance32497 said:

When I use to pokemon the Item that has an effect of calling regular script, the game restarts.
I used Darthartrons routine and reverse the script pointer and put the compiled routine+1 in Field Script.. If you have an alternate routine, please let me know.
How to make it Game Over instead The player scurried blah blah blah

Click to expand...

Player Backsprite swapping

.text
.align 2
.thumb
.thumb_func

main:
	push {r0-r2, lr}
	ldr r0, .Player
	ldr r0, [r0]
	add r0, r0, #0x8
	ldrb r1, [r0]
	ldr r2, .Save
	strb r1, [r2]
	ldr r1, .Var
	ldrb r1, [r1]
	strb r1, [r0]	
	pop {r0-r2, pc}


.align 2
.Player:
	.word 0x300500C
.Var:
	.word 0x20370B8 @0x8000
.Save:
	.word 0x203C231 @save location for current value

07 B5 05 48 00 68 08 30 01 78 05 4A 11 70 03 49 09 78 01 70 07 BD C0 46 0C 50 00 03 B8 70 03 02 31 C2 03 02

0x0 - Male Hero
0x1 - Female Hero
0x2 - Brendon
0x3 - May
0x4 - Teachy TV guy
0x5 - Old man
Greater than 0x5 - game crash :3

copybyte 0x20370B8 0x203C231 '@will put the player's old gender byte in 0x8000
callasm 0x[routine +1]