Code: ASM Resource Thread

[Wesley FG]

Color Stats Based on Nature
someone know the values of the offsets of this routine for EMERALD ?
or can do it for EMERALD, it is very usefull.

 

[Lance32497]

My request is an ASM that will let you give or take on your current amount of money using var..
For example

callasm 0xDEADBEEF
setvar 0x8000 0x500

then 500 will be given or deducted on you, it will be useful for banks and stuffs

 

[thedarkdragon11]

Is it possible to disable access to the menu (not sure with the term, but the menu which has Pokédex, Bag, Save, Option, etc.) in a specific map name?

Just wondering because I'm imagining the mechanics of a fake Eon Flute/Soaring in the Sky for GBA games...

 

[AkameTheBulbasaur]

Is there a way to disable using the bag during a battle (like in the Battle Fronteir) in Fire Red? I know it's possible in Emerald but I don't remember if Fire Red ever has a battle type like that.

 

[DoesntKnowHowToPlay]

Link battles disable it. My machine with all of my notes is not currently behaving so I have no offsets for you, but try putting a breakpoint on the battle type (0x02022b4c) before opening the bag in battle.

 

[Spherical Ice]

Is there a way to disable using the bag during a battle (like in the Battle Fronteir) in Fire Red? I know it's possible in Emerald but I don't remember if Fire Red ever has a battle type like that.

Link battles disable it. My machine with all of my notes is not currently behaving so I have no offsets for you, but try putting a breakpoint on the battle type (0x02022b4c) before opening the bag in battle.

http://pastebin.com/bHmFB5SX This routine lets you disable the bag when a flag is set. I didn't write it, though, I think it was daniilS. You just assemble it and insert it at x143D4.

 

[DizzyEgg]

Color Stats Based on Nature
someone know the values of the offsets of this routine for EMERALD ?
or can do it for EMERALD, it is very usefull.

FR has different stat summary screen display from Emerald, so you can't really change offsets. You're in luck though, as I wrote a routine that does that in EM.
LeftStats color change:

Spoiler:

.text
.thumb
.thumb_func
.align 2

main:
    push {r5}
    sub sp, sp, #0x20
    ldr r0, [r4] @pokemon summary pointer
    add r0, #0xA3 @poke nature
    ldrb r1, [r0]
    ldr r0, nature_stat_table
    lsl r2, r1, #2
    add r2, r1, r2 @multiply by 5
    add r2, r2, r0 @r2 contains nature info
    ldr r3, left_stats_string
    mov r1, sp
    mov r5, #0
    
handle_hp:
    ldrb r0, [r3, r5]
    strb r0, [r1, r5]
    add r5, #1
    cmp r5, #6
    bne handle_hp
    add r3, #6
    add r1, #6
    mov r5, #0
    
handle_atk:
    ldrb r0, [r2]
    cmp r0, #1
    beq red_font_atk
    cmp r0, #0xFF
    bne copy_atk
    bl blue_font
    b copy_atk
    
red_font_atk:
    bl red_font
    
copy_atk:
    ldrb r0, [r3, r5]
    strb r0, [r1, r5]
    add r5, #1
    cmp r5, #3
    bne copy_atk
    add r3, #3
    add r1, #3
    mov r5, #0
    
handle_def:
    add r2, #1
    ldrb r0, [r2]
    cmp r0, #1
    beq red_font_def
    cmp r0, #0xFF
    beq blue_font_def
    bl default_font
    b copy_def
    
red_font_def:
    bl red_font
    b copy_def
    
blue_font_def:
    bl blue_font
    
copy_def:
    ldrb r0, [r3, r5]
    strb r0, [r1, r5]
    add r5, #1
    cmp r5, #3
    bne copy_def
    
copy_string:
    ldr r0, displayed_string
    mov r1, sp
    ldr r2, special_f7_string_fct
    bl callvia_r2
    
return:
    mov r0, r9
    add sp, sp, #0x20
    pop {r5}
    ldr r2, =(0x081C37A8 + 1)
    b callvia_r2
    
blue_font: @FC 01 07
    mov r0, #0xFC
    strb r0, [r1]
    add r1, #1
    mov r0, #1
    strb r0, [r1]
    add r1, #1
    mov r0, #7 @color of the lowered stat
    strb r0, [r1]
    add r1, #1
    bx lr
    
red_font: @FC 01 05
    mov r0, #0xFC
    strb r0, [r1]
    add r1, #1
    mov r0, #1
    strb r0, [r1]
    add r1, #1
    mov r0, #5 @color of the raised stat
    strb r0, [r1]
    add r1, #1
    bx lr
    
default_font: @FC 01 01
    mov r0, #0xFC
    strb r0, [r1]
    add r1, #1
    mov r0, #1
    strb r0, [r1]
    add r1, #1
    strb r0, [r1]
    add r1, #1
    bx lr
    
callvia_r2:
    bx r2
    
.align 2

nature_stat_table: .word 0x0831E818
left_stats_string: .word 0x0861CE82
displayed_string: .word 0x02021FC4
special_f7_string_fct: .word 0x081AFC29

@at 0x1C379E insert: 00 00 00 4A 10 47 XX+1 XX XX 08 where XX is the address of the inserted routine

RightStats color change:

Spoiler:

.text
.thumb
.thumb_func
.align 2

main:
    push {r5}
    sub sp, sp, #0x20
    ldr r0, [r4] @pokemon summary pointer
    add r0, #0xA3 @poke nature
    ldrb r1, [r0]
    ldr r0, nature_stat_table
    lsl r2, r1, #2
    add r2, r1, r2 @multiply by 5
    add r2, r2, r0 @r2 contains nature info
    add r2, #3 @r2 contains beg of spatk stat
    ldr r3, right_stats_string
    mov r1, sp
    mov r5, #0

handle_spatk:
    ldrb r0, [r2]
    cmp r0, #1
    beq red_font_spatk
    cmp r0, #0xFF
    bne copy_spatk
    bl blue_font
    b copy_spatk
    
red_font_spatk:
    bl red_font
    
copy_spatk:
    ldrb r0, [r3, r5]
    strb r0, [r1, r5]
    add r5, #1
    cmp r5, #3
    bne copy_spatk
    add r3, #3
    add r1, #3
    mov r5, #0
    
handle_spdef:
    add r2, #1
    ldrb r0, [r2]
    cmp r0, #1
    beq red_font_spdef
    cmp r0, #0xFF
    beq blue_font_spdef
    bl default_font
    b copy_spdef
    
red_font_spdef:
    bl red_font
    b copy_spdef
    
blue_font_spdef:
    bl blue_font
    
copy_spdef:
    ldrb r0, [r3, r5]
    strb r0, [r1, r5]
    add r5, #1
    cmp r5, #3
    bne copy_spdef
    add r3, #3
    add r1, #3
    mov r5, #0
    
handle_spd:
    sub r2, #2
    ldrb r0, [r2]
    cmp r0, #1
    beq red_font_spd
    cmp r0, #0xFF
    beq blue_font_spd
    bl default_font
    b copy_spd
    
red_font_spd:
    bl red_font
    b copy_spd
    
blue_font_spd:
    bl blue_font
    
copy_spd:
    ldrb r0, [r3, r5]
    strb r0, [r1, r5]
    add r5, #1
    cmp r5, #3
    bne copy_spd
    add r3, #3
    add r1, #3
    
return:
    ldr r0, displayed_string
    mov r1, sp
    ldr r2, special_f7_string_fct
    bl callvia_r2
    add sp, sp, #0x20
    pop {r5}
    ldr r2, =(0x081C386C + 1)
    bx r2
    
blue_font: @FC 01 07
    mov r0, #0xFC
    strb r0, [r1]
    add r1, #1
    mov r0, #1
    strb r0, [r1]
    add r1, #1
    mov r0, #7 @color of the lowered stat
    strb r0, [r1]
    add r1, #1
    bx lr
    
red_font: @FC 01 05
    mov r0, #0xFC
    strb r0, [r1]
    add r1, #1
    mov r0, #1
    strb r0, [r1]
    add r1, #1
    mov r0, #5 @color of the raised stat
    strb r0, [r1]
    add r1, #1
    bx lr
    
default_font: @FC 01 01
    mov r0, #0xFC
    strb r0, [r1]
    add r1, #1
    mov r0, #1
    strb r0, [r1]
    add r1, #1
    strb r0, [r1]
    add r1, #1
    bx lr
    
callvia_r2:
    bx r2    
    
.align 2

nature_stat_table: .word 0x0831E818
right_stats_string: .word 0x0861CE8E
displayed_string: .word 0x02021FC4
special_f7_string_fct: .word 0x081AFC29

@at 0x1C3864 insert 00 4A 10 47 XX+1 XX XX 08

Image:

Spoiler:

Also, for anyone hacking Emerald. If there's an ASM feature that you'd like to have in your hack but is not present here, let me know. I've got some time, so who knows, I may help.

 

[STikER]

Okay, I made animated Pokémon sprites in FireRed using a method from this thread: http://www.pokecommunity.com/showthread.php?t=320333
Now I want to disable animation for certain Pokémon (Castform). Is there any way to do this with ASM?

 

[azurile13]

I don't know if anyone's been working on this lately, but I've been itching to share this.

FireRed lacks a system that uses a Region Dex order seperate from the National Dex. If you were to have a Region Dex and a National Dex, your National Dex would look unprofessional. What I'm putting here is my work towards a Region Dex system for FireRed. I would like to stress however that it is both unoptimized and unfinished, but I really wanted to release this.

The current routines

Spoiler:

Loading the right species

Spoiler:

.text
.align 2
.thumb
.thumb_func

main:
mov r4, r8
lsl r0, r4, #0x10
lsr r5, r0, #0x10
add r4, #0x1
ldr r0, .HoennDex
lsl r5, r5, #0x1
add r0, r0, r5
ldrh r0, [r0]
mov r5, r0
ldr r0, .return
bx r0

.align 2

.HoennDex: .word 0x08252216
.nationaltoindex: .word 0x08043200+1
.return: .word 0x08103574+1

Insert 00 48 00 47 xx xx xx 08 at 0x10356C

Correct numbering

Spoiler:

.text
.align 2
.thumb
.thumb_func

lsr r4, r4, #0x18
lsl r6, r6, #0x18
lsr r6, r6, #0x18
ldr r1, .indextonatdex
bl Linker
mov r2, r0
ldr r1, .dexarea
add r1, r1, #0xa
ldrb r1, [r1]
cmp r1, #0x1
beq regionnumber
mov r0, r2
b GoBack

Linker:
bx r1

GoBack:
ldr r2, .return
bx r2

regionnumber:
mov r0, #0x0
ldr r1, .HoennDex

Loop:
mov r0, r3
lsl r3, r3, #0x1
add r1, r1, r3
ldrh r3, [r1]
add r0, r0, #0x1
cmp r1, r2
bne Loop
b GoBack

.align 2

.HoennDex: .word 0x08252324
.indextonatdex: .word 0x08043298+1
.flagcheck: .word 0x0806e6d0+1
.return: .word 0x08104a6a+1

Insert 00 4A 10 47 xx xx xx 08 at 0x104A60

Fixing the end of the region dex

Spoiler:

.text
.align 2
.thumb
.thumb_func

main:
push {r2}
mov r2, #0x0
ldr r1, .HoennDex

loop:
lsl r0, r2, #0x1
add r0, r0, r1
ldrh r0, [r0]
add r2, #0x1
cmp r0, r5
bne loop

lastpart:
ldr r1, =0x100 /*Put the length of your Region Dex here, this supports beyond 256*/
mov r10, r2
pop {r2}
str r2, [r3, #4]
mov r8, r9
mov r0, r8
cmp r0, r1
ble jump
ldr r1, .return2
bx r1

jump:
ldr r1, .return
bx r1

.align 2

.HoennDex: .word 0x08252324
.return: .word 0x0810356c+1
.return2: .word 0x08103906+1

Insert 00 49 08 47 xx xx xx 08 at 0x1035F0

To-Do list
Fix counting the Region Dex for things like the start screen and talking to the Professor
Displaying the Region Dex number when you don't have the National Dex on the summary screen
Making searches and habitat lists use Region Dex numbers before the National Dex

Send me a PM if you're interested in fixing up what's left.

This post motivated me to create an actual regional dex instead of just giving a national dex at the start, so thanks :D I've added some extra routines to do things like display the correct regional dex number in summary screens, displaying dex info on capture, and having the proper regional dex count. New hooks:

.thumb
.align

.equ number_of_mons_in_regional_dex,	300	//or however long you wanted your regional dex to be
.equ number_of_mons_in_national_dex,	721





data_on_capture_hook:	//0x08106B84 via r1
	bl species_to_regional_dex_number
	cmp r0, #0x0
	bne capture_display_return
	ldr r0, add_task_no_capture_display
	bx r0

capture_display_return:
	ldr r0, add_task_capture_display
	bx r0





habitat_dex_regional_limit_hook:	//0x08106810 via r1
	push {r4, lr}
	mov r4, r0
	bl haz_national_dex_bool
	cmp r0, #0x1
	beq habitat_dex_regional_limit_return	//valid
	mov r0, r4
	bl species_to_regional_dex_number
	cmp r0, #0x0
	beq habitat_dex_regional_limit_return	//not in regional dex, return 0
	mov r0, #0x1

habitat_dex_regional_limit_return:
	pop {r4}
	pop {r1}
	bx r1





dex_seeable_mon_hook:	//0x08043F90 via r1
	push {r4, lr}
	mov r4, r0
	bl haz_national_dex_bool
	cmp r0, #0x0
	beq only_regional_numbered
//national
	mov r0, r4
	bl species_to_national_dex_number_1
	b dex_seeable_mon_check_valid_species

only_regional_numbered:
	mov r0, r4
	bl species_to_regional_dex_number

dex_seeable_mon_check_valid_species:
	cmp r0, #0x0
	bne dex_seeable_mon_return
	ldr r0, full_halfword

dex_seeable_mon_return:
	pop {r4}
	pop {r1}
	bx r1
.align
full_halfword:	.word 0xFFFF





dex_evolution_fix_hook:	//0x080CE91A via r1
	bl species_to_regional_dex_number
	cmp r0, #0x0	//not in regional dex, invalid
	beq dex_evolution_failure
	ldr r0, dex_evolution_success_return
	bx r0

dex_evolution_failure:
	mov r0, #0x11
	strh r0, [r5, #0x8]
	mov r2, #0x1
	ldr r1, dex_evolution_failure_return
	bx r1





dex_display_counts_hook:	//0x08104BBC via r2
	//r0: mode
	push {lr}
	cmp r1, #0x0
	beq call_regional_count
	bl national_pokedex_count
	b dex_display_counts_return

call_regional_count:
	bl dex_regional_count_hook

dex_display_counts_return:
	pop {pc}





dex_regional_count_hook:	//0x08088EDC via r1
	push {r4-r6, lr}
	mov r6, r0	//mode
	mov r4, #0x1	//loop
	mov r5, #0x0	//counter

dex_regional_count_loop:
	lsl r0, r4, #0x1	//loop times 2
	adr r1, regional_dex_order
	ldrh r0, [r1, r0]	//req species
	mov r1, r6	//mode
	mov r2, #0x1	//input is SPECIES
	bl dex_flag_check
	add r5, r5, r0
	add r4, #0x1
	ldr r0, regional_dex_limit
	cmp r4, r0
	blo dex_regional_count_loop
	mov r0, r5
	pop {r4-r6, pc}





dex_display_hook:	//0x0810352C via r1
	ldr r1, regional_dex_limit
	cmp r0, #0x0
	beq store_dex_limit_and_return
	ldr r1, national_dex_limit

store_dex_limit_and_return:
	str r1, [sp, #0x0]
	ldr r0, regional_dex_limit_return
	bx r0





regional_dex_hook:	//0x0810356C via r0
	mov r4, r8
	add r4, #0x1
	lsl r0, r4, #0x1	//index times 2
	adr r1, regional_dex_order
	ldrh r0, [r1, r0]
	bl species_to_national_dex_number_1
	mov r5, r0
	mov r1, #0x0
	ldr r2, regional_dex_hook_return
	bx r2





store_last_dex_seen_hook:	//0x081035B4 via r1
	str r0, [r2]
	mov r10, r4
	mov r4, r3
	ldr r0, def_store_string_dex_number
	bx r0





lazy_regional_dex_end_hook:	//0x081035F4 via r0
	mov r0, r8
	ldr r1, regional_dex_limit
	cmp r0, r1
	blo regional_dex_hook
	ldr r0, end_dex_display_return
	bx r0





display_regional_num_hook:	//0x08104A66 via r1
	mov r5, r0	//save species
	bl haz_national_dex_bool
	cmp r0, #0x0
	beq use_regional_dex_ordering
	ldr r1, dex_malloc_ptr
	ldr r1, [r1]
	add r1, #0x42
	ldrb r1, [r1]
	cmp r1, #0x0	//check if looking at regional dex
	beq use_regional_dex_ordering
	mov r0, r5
	bl species_to_national_dex_number_1
	b display_dex_number_return

use_regional_dex_ordering:
	mov r0, r5
	bl species_to_regional_dex_number	

display_dex_number_return:
	mov r5, r0
	ldr r0, dex_number_display_return
	bx r0





species_to_regional_dex_number:
	adr r3, regional_dex_order
	mov r2, r0	//req species
	mov r0, #0x0	//loop counter
find_regional_number_loop:
	lsl r1, r0, #0x1
	ldrh r1, [r3, r1]
	cmp r1, r2
	beq species_to_regional_dex_return
	add r0, #0x1
	ldr r1, regional_dex_limit
	cmp r0, r1
	bls find_regional_number_loop
	mov r0, #0x0	//not in dex: set number to 0
species_to_regional_dex_return:
	bx lr



species_to_national_dex_number_1:
	ldr r1, f_species_to_nat_dex
	bx r1
.align
f_species_to_nat_dex:	.word 0x08043298 + 1

haz_national_dex_bool:
	ldr r0, f_haz_national_check
	bx r0
.align
f_haz_national_check:	.word 0x0806E25C + 1

dex_flag_check:
	ldr r3, f_dex_flag_check
	bx r3
.align
f_dex_flag_check:	.word 0x08104AB0 + 1

national_pokedex_count:
	ldr r1, f_national_pokedex_count
	bx r1
.align
f_national_pokedex_count:	.word 0x08088E8C + 1



.align
add_task_no_capture_display:	.word 0x08106B90 + 1
add_task_capture_display:	.word 0x08106BA4 + 1
dex_evolution_success_return:	.word 0x080CE948 + 1
dex_evolution_failure_return:	.word 0x080CE924 + 1
regional_dex_limit:	.word number_of_mons_in_regional_dex
national_dex_limit:	.word number_of_mons_in_national_dex
regional_dex_limit_return:	.word 0x0810353a + 1
regional_dex_hook_return:	.word 0x08103578 + 1
def_store_string_dex_number:	.word 0x081035D6 + 1
end_dex_display_return:	.word 0x08103906 + 1
dex_malloc_ptr:			.word 0x0203ACF0
dex_number_display_return:	.word 0x08104A70 + 1

regional_dex_order:
.short 0x0000
.short CHIKORITA
.short BAYLEEF
.short MEGANIUM
etc

For anyone using Touched's scripts/ASMAGIX:

data_on_capture_hook		08106B84	1
dex_seeable_mon_hook		08043F90	1
dex_evolution_fix_hook		080CE91A	1
dex_display_counts_hook		08104BBC	2
dex_regional_count_hook		08088EDC	1
dex_display_hook		0810352C	1
regional_dex_hook		0810356C	0
store_last_dex_seen_hook	081035B4	1
lazy_regional_dex_end_hook	081035F4	0
display_regional_num_hook	08104A66	1
habitat_dex_regional_limit_hook	08106810	1

 

[STikER]

.thumb
.align

.equ number_of_mons_in_regional_dex,	300	//or however long you wanted your regional dex to be
.equ number_of_mons_in_national_dex,	721





data_on_capture_hook:	//0x08106B84 via r1
	bl species_to_regional_dex_number
	cmp r0, #0x0
	bne capture_display_return
	ldr r0, add_task_no_capture_display
	bx r0

capture_display_return:
	ldr r0, add_task_capture_display
	bx r0





habitat_dex_regional_limit_hook:	//0x08106810 via r1
	push {r4, lr}
	mov r4, r0
	bl haz_national_dex_bool
	cmp r0, #0x1
	beq habitat_dex_regional_limit_return	//valid
	mov r0, r4
	bl species_to_regional_dex_number
	cmp r0, #0x0
	beq habitat_dex_regional_limit_return	//not in regional dex, return 0
	mov r0, #0x1

habitat_dex_regional_limit_return:
	pop {r4}
	pop {r1}
	bx r1





dex_seeable_mon_hook:	//0x08043F90 via r1
	push {r4, lr}
	mov r4, r0
	bl haz_national_dex_bool
	cmp r0, #0x0
	beq only_regional_numbered
//national
	mov r0, r4
	bl species_to_national_dex_number_1
	b dex_seeable_mon_check_valid_species

only_regional_numbered:
	mov r0, r4
	bl species_to_regional_dex_number

dex_seeable_mon_check_valid_species:
	cmp r0, #0x0
	bne dex_seeable_mon_return
	ldr r0, full_halfword

dex_seeable_mon_return:
	pop {r4}
	pop {r1}
	bx r1
.align
full_halfword:	.word 0xFFFF





dex_evolution_fix_hook:	//0x080CE91A via r1
	bl species_to_regional_dex_number
	cmp r0, #0x0	//not in regional dex, invalid
	beq dex_evolution_failure
	ldr r0, dex_evolution_success_return
	bx r0

dex_evolution_failure:
	mov r0, #0x11
	strh r0, [r5, #0x8]
	mov r2, #0x1
	ldr r1, dex_evolution_failure_return
	bx r1





dex_display_counts_hook:	//0x08104BBC via r2
	//r0: mode
	push {lr}
	cmp r1, #0x0
	beq call_regional_count
	bl national_pokedex_count
	b dex_display_counts_return

call_regional_count:
	bl dex_regional_count_hook

dex_display_counts_return:
	pop {pc}





dex_regional_count_hook:	//0x08088EDC via r1
	push {r4-r6, lr}
	mov r6, r0	//mode
	mov r4, #0x1	//loop
	mov r5, #0x0	//counter

dex_regional_count_loop:
	lsl r0, r4, #0x1	//loop times 2
	adr r1, regional_dex_order
	ldrh r0, [r1, r0]	//req species
	mov r1, r6	//mode
	mov r2, #0x1	//input is SPECIES
	bl dex_flag_check
	add r5, r5, r0
	add r4, #0x1
	ldr r0, regional_dex_limit
	cmp r4, r0
	blo dex_regional_count_loop
	mov r0, r5
	pop {r4-r6, pc}





dex_display_hook:	//0x0810352C via r1
	ldr r1, regional_dex_limit
	cmp r0, #0x0
	beq store_dex_limit_and_return
	ldr r1, national_dex_limit

store_dex_limit_and_return:
	str r1, [sp, #0x0]
	ldr r0, regional_dex_limit_return
	bx r0





regional_dex_hook:	//0x0810356C via r0
	mov r4, r8
	add r4, #0x1
	lsl r0, r4, #0x1	//index times 2
	adr r1, regional_dex_order
	ldrh r0, [r1, r0]
	bl species_to_national_dex_number_1
	mov r5, r0
	mov r1, #0x0
	ldr r2, regional_dex_hook_return
	bx r2





store_last_dex_seen_hook:	//0x081035B4 via r1
	str r0, [r2]
	mov r10, r4
	mov r4, r3
	ldr r0, def_store_string_dex_number
	bx r0





lazy_regional_dex_end_hook:	//0x081035F4 via r0
	mov r0, r8
	ldr r1, regional_dex_limit
	cmp r0, r1
	blo regional_dex_hook
	ldr r0, end_dex_display_return
	bx r0





display_regional_num_hook:	//0x08104A66 via r1
	mov r5, r0	//save species
	bl haz_national_dex_bool
	cmp r0, #0x0
	beq use_regional_dex_ordering
	ldr r1, dex_malloc_ptr
	ldr r1, [r1]
	add r1, #0x42
	ldrb r1, [r1]
	cmp r1, #0x0	//check if looking at regional dex
	beq use_regional_dex_ordering
	mov r0, r5
	bl species_to_national_dex_number_1
	b display_dex_number_return

use_regional_dex_ordering:
	mov r0, r5
	bl species_to_regional_dex_number	

display_dex_number_return:
	mov r5, r0
	ldr r0, dex_number_display_return
	bx r0





species_to_regional_dex_number:
	adr r3, regional_dex_order
	mov r2, r0	//req species
	mov r0, #0x0	//loop counter
find_regional_number_loop:
	lsl r1, r0, #0x1
	ldrh r1, [r3, r1]
	cmp r1, r2
	beq species_to_regional_dex_return
	add r0, #0x1
	ldr r1, regional_dex_limit
	cmp r0, r1
	bls find_regional_number_loop
	mov r0, #0x0	//not in dex: set number to 0
species_to_regional_dex_return:
	bx lr



species_to_national_dex_number_1:
	ldr r1, f_species_to_nat_dex
	bx r1
.align
f_species_to_nat_dex:	.word 0x08043298 + 1

haz_national_dex_bool:
	ldr r0, f_haz_national_check
	bx r0
.align
f_haz_national_check:	.word 0x0806E25C + 1

dex_flag_check:
	ldr r3, f_dex_flag_check
	bx r3
.align
f_dex_flag_check:	.word 0x08104AB0 + 1

national_pokedex_count:
	ldr r1, f_national_pokedex_count
	bx r1
.align
f_national_pokedex_count:	.word 0x08088E8C + 1



.align
add_task_no_capture_display:	.word 0x08106B90 + 1
add_task_capture_display:	.word 0x08106BA4 + 1
dex_evolution_success_return:	.word 0x080CE948 + 1
dex_evolution_failure_return:	.word 0x080CE924 + 1
regional_dex_limit:	.word number_of_mons_in_regional_dex
national_dex_limit:	.word number_of_mons_in_national_dex
regional_dex_limit_return:	.word 0x0810353a + 1
regional_dex_hook_return:	.word 0x08103578 + 1
def_store_string_dex_number:	.word 0x081035D6 + 1
end_dex_display_return:	.word 0x08103906 + 1
dex_malloc_ptr:			.word 0x0203ACF0
dex_number_display_return:	.word 0x08104A70 + 1

regional_dex_order:
.short 0x0000
.short CHIKORITA
.short BAYLEEF
.short MEGANIUM
etc

Is a pointer needed for this? Or is it should be inserted on certain offset?

Correct numbering

Spoiler:

.text
.align 2
.thumb
.thumb_func

lsr r4, r4, #0x18
lsl r6, r6, #0x18
lsr r6, r6, #0x18
ldr r1, .indextonatdex
bl Linker
mov r2, r0
ldr r1, .dexarea
add r1, r1, #0xa
ldrb r1, [r1]
cmp r1, #0x1
beq regionnumber
mov r0, r2
b GoBack

Linker:
bx r1

GoBack:
ldr r2, .return
bx r2

regionnumber:
mov r0, #0x0
ldr r1, .HoennDex

Loop:
mov r0, r3
lsl r3, r3, #0x1
add r1, r1, r3
ldrh r3, [r1]
add r0, r0, #0x1
cmp r1, r2
bne Loop
b GoBack

.align 2

.HoennDex: .word 0x08252324
.indextonatdex: .word 0x08043298+1
.flagcheck: .word 0x0806e6d0+1
.return: .word 0x08104a6a+1

Insert 00 4A 10 47 xx xx xx 08 at 0x104A60

I cannot compile your routine "Correct numbering". It says there is an error in line 12: invalid offset, value too big (0xFFFFFFFC)
Maybe there should be an offset for .dexarea?

 

[azurile13]

Is a pointer needed for this? Or is it should be inserted on certain offset?



I cannot compile your routine "Correct numbering". It says there is an error in line 12: invalid offset, value too big (0xFFFFFFFC)
Maybe there should be an offset for .dexarea?

Whoa, the notifications I got for this post. There are eleven pointers needed for this :D ctrl + F for "via" and for each of those routines, you need to create a hook.
For example, with data_on_capture_hook, the comment after the label means to insert

ldr r1, =(wherever in free space the routine is + 1)
bx r1
.align

at 0x106B84

 

[STikER]

Whoa, the notifications I got for this post. There are eleven pointers needed for this :D ctrl + F for "via" and for each of those routines, you need to create a hook.
For example, with data_on_capture_hook, the comment after the label means to insert

ldr r1, =(wherever in free space the routine is + 1)
bx r1
.align

at 0x106B84

Oh, now I get it. It's so simple! Thanks, your routine is great!
So, if it says "via r2" I need to insert this:
ldr r2, =(offset + 2)
bx r2
.align

Right?

 

[DizzyEgg]

Pokemon Emerald Multichoice Scrolling Box

So, the mechanic for that is already implemented, we just have to repoint some tables. So let's get down to work.
First, there's a table at 0x085B2CF0. Each entry is a pointer to text to be displayed in the box. One set consist of 16 options. This is important. Anyway, repoint to free space and change pointers to this table. It ends at 0x085B3030.

Now, there's a jumptable at 0x0813A168. It ends at 0x0813A19C. It has 12 entries, repoint it to free space. Now for every new set of options you want to add, you have to add a routine like this:

Spoiler:

.text
.thumb
.thumb_func
.align 2

main:
    mov r0, #5
    strh r0, [r3, #8] @how many are displayed
    mov r0, #8
    strh r0, [r3, #0xA] @how many are in total
    mov r0, #1
    strh r0, [r3, #0xC] @X coordinate
    mov r0, #1
    strh r0, [r3, #0xE] @Y coordinate
    mov r0, #9
    strh r0, [r3, #0x10] @unkown
    mov r0, #0xA 
    strh r0, [r3, #0x12] @box height, should be displayed * 2
    mov r0, #0
    strh r0, [r3, #0x14] @unkown 
    strh r4, [r3, #0x26] @task id, don't change it
    pop {r4}
    pop {r0}
    bx r0

Note that you can change parameters in those routines. Play with them and see which ones look the best for you. Now, every routine like that above, goes at the end of the repointed jumptable. There are 12-in game sets, so you'll start with 13. Change the byte at 0x813A148 to the amount of all sets.

One more thing, even though the table of pointers to text can only hold 16 pointers, it doesn't mean you're limited to only that many options. You can go to 126 max, because 127 is treated as hitting B. How? Well, in the routine above set how many in total to the amount you want and ignore occupied slots. For example if you want your set to have 50 options, divide it by 16, so you get 3 and some remainder. That means this set occupies 4 places in the jumptable, like this:
XX XX XX 08 00 00 00 00 00 00 00 00 00 00 00 00 NEW SET GOES HERE

Using it in a script is easy, just do this:
setvar 0x8004 slot in the jumptable (starts at 13, since 12 are already occupied in-game)
special 0x1BE
waitstate
Result is stored in the 0x800D. First option chosen is 0, second is 1, and so on. Hitting B be is 0x7F.
compare 0x800D 0x0
if 0x1 goto @first_option
....
compare 0x800D 0x7F
if 0x1 goto @chose_cancel

I hope everything's understandable. :)

 

[Splash]

Sitrus Berry Update:

Spoiler:

Restore 25% of maximum HP.

Emerald:-

Spoiler:

Item Use Effect:

.text
.align 2
.thumb
.thumb_func
.global sitrusoverworld

Main:

  ldr r1, [sp, #0xC]   @ItemIndex
  cmp r1, #0x8E @Sirtus
  bne Skip
  lsr r0, r0, #0x1   @HP to Restore

Skip:  
  cmp r0, #0x0
  bne Exit
  mov r0, #0x1

Exit:
  ldr r1, =0x806C610+1
  bx r1

@@At x31E54D: FE
@@At x6C600: 00 49 08 47 XX+1 XX XX 08

Hold Item Effect:

.text
.align 2
.thumb
.thumb_func
.global sitruspinch

Main:

  ldrh r1, [r2, #0x2E]   @ItemIndex
  ldrh r3, [r2, #0x28]
  mov r5, r9
  cmp r1, #0x8E @Sitrus
  bne NotZero
  ldrh r0, [r2, #0x2C]
  lsr r5, r0, #0x2   @HP to Restore
  cmp r5, #0x0
  bne NotZero
  mov r5, #0x1

NotZero:
  str r5, [r4]
  ldr r1, =0x804478C+1
  bx r1

@At 08044784: 00 49 08 47 XX+1 XX XX 08

Berry Activation Update:

Spoiler:

Activates consumable berries as soon as possible (end move or a certain multi-hit strike) after the required consumption condition is met, consistent to later generations, rather than activating on End Turn.

Emerald:-

Spoiler:

.text
.align 2
.thumb
.thumb_func
.global endmoveberries

.include "T:/asdS/thumb/bsmacros.asm"
@@http://www.pokecommunity.com/showpost.php?p=9062722&postcount=332
@@ Paste all the content from the 'BS Macro & Defines' Spoiler in this link to a new blank ASM file and include its path.

.equ RomAreaOffset, 0x8000000
.equ BerryLoc, 0xE10000
.equ ContraryID, 0x7F
.equ GluttonyID, 0x53
.equ BattleData, 0x2024084
.equ Sitrus, 0x8E
.equ Return, 0x08045674+1
.equ Return2, 0x0804582A+1
.equ ItemBuffer, 0x2024208
.equ ScriptPointer, 0x2024214
.equ ScriptPusher, 0x803FAFC+1
.equ MiscBufferCountersArea, 0x2024474
.equ Bank_F, 0x202420F
.equ ActiveBank, 0x2024064
.equ Damage, 0x20241F0
.equ NoOfBattlers, 0x202406C
.equ UserBank, 0x202420B
.equ TargetPartner, 0x202420E
.equ BattleOutcome, 0x2022F58
.equ Divider, 0x82e7540+1
.equ ConfuseAccToNature, 0x806e880+1
.equ RNG, 0x806F5CC+1
.equ DivMod, 0x82E7Be0+1
.equ OranHealBSLoc, OranHealBS+RomAreaOffset
.equ HealAndConfuseBSLoc, HealAndConfuseBS+RomAreaOffset
.equ FocusBerryBSLoc, FocusBerryBS+RomAreaOffset
.equ StatRaiseBSLoc, StatRaiseBS+RomAreaOffset 

.org 0x45280
    mov r7, #0x0
    ldr r0, =NoOfBattlers
    ldrb r0, [r0]
    cmp r7, r0
    bcc CheckBankHP
    b 0x4582A

CheckBankHP:
    ldr r1, =BattleData
    mov r8, r1
    mov r0, #0x58
    mul r0, r7
    add r0, r0, r1
    ldrh r2, [r0, #0x28]
    cmp r2, #0x0
    bne HasHP
    b 0x45674

HasHP:
    ldr r4, =ItemBuffer
    ldrh r0, [r0, #0x2E] 
    strh r0, [r4]
    bl 0xD74DC
    lsl r0, r0, #0x18
    lsr r5, r0, #0x18
    sub r0, r5, #1
    cmp r0, #0x1B
    bls LoadBerryTable
    b 0x45674

LoadBerryTable:
    lsl r0, r0, #2
    ldr r1, BerryTableLoc
    add r0, r0, r1
    ldr r3, [r0]
    ldrh r0, [r4]
    bl 0xD7500
    lsl r0, r0, #0x18
    lsr r0, r0, #0x18
    mov r9, r0
    mov pc, r3
    
.align 2
BerryTableLoc: .word BerryLoc+RomAreaOffset

.align 2
.pool


.org BerryLoc
.word HPRestoreBerry+RomAreaOffset @Oran, Sitrus, Berry Juice 
.word 0x8045354  @Cheri Berry
.word 0x8045444  @Chesto Berry
.word 0x8045390  @Pecha Berry
.word 0x80453CC  @Rawst Berry
.word 0x8045408  @Aspear Berry
.word 0x8045674       @Leppa Berry
.word 0x804548C  @Persim Berry
.word 0x8045520  @Lum Berry
.word HPRestoreConfuseBerry+RomAreaOffset @Figy
.word HPRestoreConfuseBerry+RomAreaOffset @Wiki
.word HPRestoreConfuseBerry+RomAreaOffset @Mago
.word HPRestoreConfuseBerry+RomAreaOffset @Aguav
.word HPRestoreConfuseBerry+RomAreaOffset @Iapapa
.word StatRaiseBerry+RomAreaOffset @Leichi
.word StatRaiseBerry+RomAreaOffset @Ganlon
.word StatRaiseBerry+RomAreaOffset @Salac
.word StatRaiseBerry+RomAreaOffset @Petaya
.word StatRaiseBerry+RomAreaOffset @Apicot
.word LansatBerry+RomAreaOffset @Lansat
.word StarfBerry+RomAreaOffset @Starf
.word 0x8045674
.word 0x8045614 @White Herb
.word 0x8045674
.word 0x8045674
.word 0x8045674
.word 0x8045674
.word 0x80454C8 @Mental Herb

@@@@@@@@@@@@@@@Oran


.align 2
HPRestoreBerry:
    mov r1, r8
    mov r0, #0x58
    mul r0, r7
    add r2, r0, r1
    ldrh r1, [r2, #0x2C]
    ldrh r3, [r2, #0x28]
    lsr r0, r1, #1
    cmp r3, r0
    bls RestoreHP
    b Quit

RestoreHP:
    ldrh r0, [r4]
    ldr r4, =Damage
    mov r5, r9
    cmp r0, #Sitrus  @Sitrus
    bne NotZero
    ldrh r0, [r2, #0x2C]
    lsr r5, r0, #0x2
    cmp r5, #0x0
    bne NotZero
    mov r5, #0x1

NotZero:
    add r0, r3, r5
    cmp r0, r1
    ble NegDamage
    sub r5, r1, r3

NegDamage:
    neg r5, r5
    str r5, [r4]
    ldr r6, =ScriptPusher
    bl Linker
    ldr r1, =ScriptPointer
    ldr r0, =OranHealBSLoc
    str r0, [r1]
    mov r0, #0x1
    str r0, [sp, #0xC]
    b SetupBuffersAndExit

.align 2
.pool


@@@@@@@@@@@@@@@@@@@@@@@@@@
HPRestoreConfuseBerry:
    mov r0, r5
    sub r0, #0xA
    mov r10, r0
    mov r0, #0x58
    mov r1, r7
    mul r1, r0
    str r1, [sp, #0x18]
    mov r4, r1
    add r4, r8
    ldrh r0, [r4, #0x2C]
    ldrh r1, [r4, #0x28]
    lsr r0, r0, #0x1
    cmp r1, r0
    bls RestoreHPAttemptConfuse
    b Quit

RestoreHPAttemptConfuse:
    ldr r1, =BattleOutcome
    mov r0, #0xFD
    strb r0, [r1]
    mov r0, #0x8
    strb r0, [r1, #0x1]
    mov r0, r10
    strb r0, [r1, #0x2]
    mov r0, #0xFF
    strb r0, [r1, #0x3]
    ldr r5, =Damage
    ldrh r0, [r4, #0x2C]
    mov r1, r9
    ldr r6, =Divider
    bl Linker
    str r0, [r5]
    cmp r0, #0x0
    bne NotZeroWiki
    mov r0, #0x1
    str r0, [r5]

NotZeroWiki:
    ldrh r2, [r4, #0x28]
    ldr r0, [r5]
    add r0, r2, r0
    ldrh r1, [r4, #0x2C]
    cmp r0, r1
    ble CheckConfusion
    sub r0, r1, r2
    str r0, [r5]

CheckConfusion:
    ldr r0, [r5]
    neg r0, r0
    str r0, [r5]
    mov r0, r8
    add r0, #0x48
    ldr r2, [sp, #0x18]
    add r0, r2, r0
    ldr r0, [r0]
    mov r1, r10
    ldr r6, =ConfuseAccToNature
    bl Linker
    lsl r0, r0, #0x10
    blt BerryConfuse
    ldr r6, =ScriptPusher
    bl Linker
    ldr r1, =ScriptPointer
    ldr r0, =OranHealBSLoc
    str r0, [r1]
    mov r0, #0x1
    str r0, [sp, #0xC]
    b SetupBuffersAndExit

BerryConfuse:
    ldr r6, =ScriptPusher
    bl Linker
    ldr r1, =ScriptPointer
    ldr r0, =HealAndConfuseBSLoc
    str r0, [r1]
    mov r0, #0x1
    str r0, [sp, #0xC]
    b SetupBuffersAndExit
.align 2
.pool


@@@@@@@@@@@@@@@@@@
StatRaiseBerry:
    mov r0, r5
    sub r0, #0xF
    mov r10, r0
    mov r0, #0x58
    mul r0, r7
    mov r3, r8
    add r5, r0, r3
    ldrh r4, [r5, #0x28]
    ldrh r0, [r5, #0x2C]

GluttonyCheck:
    mov r2, #0x20
    add r2, r2, r5
    ldrb r2, [r2]
    cmp r2, #GluttonyID
    bne CheckPinchActivation
    lsl r0, r0, #0x1

CheckPinchActivation:
    mov r1, r9
    ldr r6, =Divider
    bl Linker
    cmp r4, r0
    bls CheckForContrary
    b Quit

CheckForContrary:
    mov r6, #0xC
    cmp r2, #ContraryID
    bne NoContrary_Re
    mov r6, #0x0

NoContrary_Re:
    mov r0, r10
    add r0, #0x19
    add r0, r0, r5
    ldrb r0, [r0]
    cmp r0, r6
    bne BoostStat
    b Quit

BoostStat:
    ldr r1, =BattleOutcome
    mov r2, #0xFD
    strb r2, [r1]
    mov r0, #5
    strb r0, [r1, #0x1]
    mov r0, r10
    add r0, #0x1
    strb r0, [r1, #0x2]
    mov r0, #0xFF
    strb r0, [r1, #0x3]
    ldr r0, =TargetPartner
    strb r7, [r0]
    ldr r1, =MiscBufferCountersArea
    mov r0, r10
    add r0, #0x11
    strb r0, [r1, #0x1A]
    sub r0, r0, #0x2
    strb r0, [r1, #0x10]
    mov r0, #0x0
    strb r0, [r1, #0x11]    
    ldr r6, =ScriptPusher
    bl Linker
    ldr r1, =ScriptPointer
    ldr r0, =StatRaiseBSLoc
    str r0, [r1]
    mov r0, #0x1
    str r0, [sp, #0xC]
    b SetupBuffersAndExit
.align 2
.pool

@@@@@@@@@@@@@Lansat Berry:
LansatBerry:
    mov r0, #0x58
    mul r0, r7
    mov r3, r8
    add r5, r0, r3
    ldrh r4, [r5, #0x28]
    ldrh r0, [r5, #0x2C]

GluttonyCheck_Lansat:
    mov r2, #0x20
    add r2, r2, r5
    ldrb r2, [r2]
    cmp r2, #GluttonyID
    bne CheckPinchActivation_Lansat
    lsl r0, r0, #0x1

CheckPinchActivation_Lansat:
    mov r1, r9
    ldr r6, =Divider
    bl Linker
    cmp r4, r0
    bls CheckFocus
    b Quit   

CheckFocus:
    ldr r2, [r5, #0x50]
    mov r3, #0x80
    lsl r3, r3, #0xD
    mov r0, r2
    and r0, r3
    cmp r0, #0x0
    beq SetFocus
    b Quit    

SetFocus:
    orr r2, r3
    str r2, [r5, #0x50]
    ldr r6, =ScriptPusher
    bl Linker
    ldr r1, =ScriptPointer
    ldr r0, =FocusBerryBSLoc
    str r0, [r1]
    mov r0, #0x1
    str r0, [sp, #0xC]
    b SetupBuffersAndExit
.align 2
.pool

@@@@@@@@@@@@@@@
StarfBerry:
    mov r0, #0x58
    mul r0, r7
    mov r3, r8
    add r5, r0, r3
    ldrh r4, [r5, #0x28]
    ldrh r0, [r5, #0x2C]

GluttonyCheck_Starf:
    mov r2, #0x20
    add r2, r2, r5
    ldrb r2, [r2]
    cmp r2, #GluttonyID
    bne CheckPinchActivation_Starf
    lsl r0, r0, #0x1

CheckPinchActivation_Starf:
    mov r1, r9
    ldr r6, =Divider
    bl Linker
    cmp r4, r0
    bgt Quit

CheckStats:
    mov r6, #0xC
    cmp r2, #ContraryID
    bne NoContrary
    mov r6, #0x0

NoContrary:
    mov r0, #0x0
    mov r10, r0
    add r0, r5, #0x1
    mov r1, r8
    add r1, #0x18
    add r0, r0, r1
    ldrb r0, [r1]
    lsl r0, r0, #0x18
    asr r0, r0, #0x18
    cmp r0, r6
    bne RaisableStat
    mov r0, r8
    add r0, #0x19
    add r1, r5, r0

Loop:
    add r1, #1
    add r2, #1
    add r10, r2
    mov r3, r10
    cmp r3, #0x4
    bgt Quit
    ldrb r0, [r1]
    cmp r0, r6
    beq Loop

RaisableStat:
    mov r0, #0x58
    mov r0, r7
    add r4, r0, r7
    ldr r5, =0x202409C
    mov r9, r6

StatSelect:    
    ldr r6, =RNG
    bl Linker
    lsl r0, r0, #0x10
    lsr r0, r0, #0x10
    mov r1, #0x5
    ldr r6, =DivMod
    bl Linker
    lsl r0, r0, #0x10
    lsr r0, r0, #0x10
    mov r10, r0
    add r0, r0, r4
    add r0, r0, r5
    ldrb r0, [r0] 
    lsl r0, r0, #0x18
    asr r0, r0, #0x18
    mov r6, r9
    cmp r0, r6
    beq StatSelect

BoostRandomStat:
    ldr r1, =BattleOutcome
    mov r2, #0xFD
    strb r2, [r1]
    mov r0, #5
    strb r0, [r1, #0x1]
    mov r0, r10
    add r0, #0x1
    strb r0, [r1, #0x2]
    mov r0, #0xFF
    strb r0, [r1, #0x3]
    ldr r0, =TargetPartner
    strb r7, [r0]
    ldr r1, =MiscBufferCountersArea
    mov r0, r10
    add r0, #0x21
    strb r0, [r1, #0x1A]
    add r0, #6
    strb r0, [r1, #0x10]
    mov r0, #0x0
    strb r0, [r1, #0x11]    
    ldr r6, =ScriptPusher
    bl Linker
    ldr r1, =ScriptPointer
    ldr r0, =StatRaiseBSLoc
    str r0, [r1]
    mov r0, #0x1
    str r0, [sp, #0xC]


SetupBuffersAndExit:
    ldr r0, =MiscBufferCountersArea
    strb r7, [r0, #0x17]
    ldr r0, =Bank_F
    strb r7, [r0]
    ldr r4, =ActiveBank
    strb r7, [r4]

Quit2:
    ldr r1, =Return2
    bx r1

Quit:
    ldr r1, =Return
    bx r1

Linker:
     bx r6

.align 2
.pool

SwapBanks:
    ldr r1, =UserBank
    ldrb r0, [r1]
    ldr r3, =Bank_F
    ldrb r2, [r3]
    strb r0, [r3]
    strb r2, [r1]
    bx lr
.align 2
.pool

@@@@OranBerryBS:
OranHealBS:
playanimation 0xA 0x7 0x0

printstring 0x12A

waitmessage 0x40

orword 0x2024280 0x100

graphicalhpupdate 0xA

datahpupdate 0xA

removeitem 0xA
return
.align 2

@@@@
HealAndConfuseBS:
playanimation 0xA 0x7 0x0

printstring 0x12A

waitmessage 0x40

orword 0x2024280 0x100

graphicalhpupdate 0xA

datahpupdate 0xA

printstring 0x144
waitmessage 0x40

callasm SwapBanks+RomAreaOffset+1
setbyte 0x2024335 0x47
seteffecttarget
callasm SwapBanks+RomAreaOffset+1
removeitem 0xA
return

@@@@
FocusBerryBS:
playanimation 0xA 0x7 0x0

printstring 0x146

waitmessage 0x40

removeitem 0xA
return

.align 2
@@@@@@@
StatRaiseBS:
playanimation 0xA 0x7 0x0
callasm SwapBanks+RomAreaOffset+1
statbuffchange 0x41 StatRaiseAnimation+RomAreaOffset

StatRaiseAnimation:
callasm SwapBanks+RomAreaOffset+1
setbyte 0x2024337 0x4
playanimation 0x2 0x1 0x2024484

printfromtable 0x85CC89C

waitmessage 0x40
removeitem 0xA
return

Any chance of a firered port?

 

[Trainer 781]

Any chance of a firered port?

Can do, if there is a need.

 

[jirachiwishmaker]

Can do, if there is a need.

The Item Use Effect routine of Sitrus Berry Updates does not working anymore. Could you fix it, please?

 

[Trainer 781]

The Item Use Effect routine of Sitrus Berry Updates does not working anymore. Could you fix it, please?

I have updated it yesterday. Check the latest version.

 

[jirachiwishmaker]

I have updated it yesterday. Check the latest version.

Thank you very much{:3}

 

[leyn09]

Battle End Move Target Held Items (FR):-

Loader Routine:

Spoiler:

.text
.align 2
.thumb
.thumb_func
.global targetitemloader

CheckOutcome:
       ldr r1, .Outcome
       ldrb r0, [r1]
       mov r1, #0x29
       and r0, r1
       cmp r0, #0x0
       bne NoEffect

GetTargetItemEffect:
       ldr r1, .BattleData
       ldr r0, .TargetBank
       ldrb r2, [r0, #0x0]
       mov r0, #0x58
       mul r0, r2
       add r6, r0, r1 /*save Target Data in r6 for quick access*/
       ldrh r0, [r6, #0x2E]
       mov r7, r0     /*save Item Buffer in r7 for quick access*/
       bl EffectGetter

CheckTable:
       ldr r3, .TableLoc
Loop:       
       ldrb r2, [r3, #0x0]
       cmp r2, #0xFF
       beq NoEffect
       cmp r2, r0
       beq EntryFound
       add r3, #0x8
       b Loop

EntryFound:
       ldr r0, [r3, #0x4]
       bx r0

NoEffect:
       ldr r0, .Return
       bx r0

EffectGetter:
       ldr r2, =0x809A924+1
       bx r2

.align 2
.Outcome: .word 0x02023DCC
.BattleData: .word 0x02023BE4
.TargetBank: .word 0x02023D6C
[B].TableLoc: .word 0x08730060[/B]
.Return: .word 0x080237C8+1

Table at x730060 should contain 8 byte entries in the format: [Held Item Effect (byte)] 0 0 0 [HeldItem ASM Pointer + 1 in litte endian format](4 bytes) and must be terminated by a FF

Table at xTTTTTT:

C4 33 02 08 A0 34 02 08 5C 35 02 08 80 35 02 08 98 35 02 08 C0 35 02 08 E4 35 02 08 8C 36 02 08 02 37 02 08 38 37 02 08 D8 37 02 08 [B]XX+1 XX XX 08[/B] CC 36 02 08 EC 36 02 08 1C 38 02 08 60 38 02 08 40 3A 02 08 28 3B 02 08 B4 3B 02 08

where 0xXXXXXX is the pointer to the loader routine.

At x23378: insert pointer to 0x8TTTTTT
At x23366, x23BC0, x23bd6, x23be0 & x23bec: insert 0x12 (i.e. New No. Of End Move Table Entries)
At x1d6ABC, x1d6ad7, x1d6d48, x1d7661, x1d7b76, x1d7b8e, x1d7cd8, x1d839a, x1d94e6, x1d9500 & x1d9517: insert 49 02 11 (No. Of Entries - 1).
In custom battle scripts for Rototiller, Flower Shield etc. and the updated Multi-target moves like Surf, Discharge etc. replace each occurence of cmd49 0x2 0x10 with cmd49 0x2 0x11.

Rocky Helmet:-

Spoiler:

Routine:

Spoiler:

.text
.align 2
.thumb
.thumb_func
.global rockyhelmet

CheckMagicGuard:
      ldr r1, .BattleStruct
      ldr r0, .UserBank
      ldrb r2, [r0, #0x0]
      mov r0, #0x58
      mul r0, r2
      add r3, r0, r1
      ldrb r0, [r3]
      cmp r0, #0x73 /*Magic Guard*/
      beq NoRocky

HPCheck:
      ldrh r0, [r3, #0x8]
      cmp r0, #0x0
      beq NoRocky

CheckDamage:
      ldr r2, .DamageStruct
      ldr r0, .UserBank
      add r0, #0x1
      ldrb r1, [r0, #0x0]
      lsl r0, r1, #0x2
      add r0, r0, r1
      lsl r1, r0, #0x2
      add r0, r2, #0x4
      add r0, r1, r0
      ldr r1, [r0, #0x0]
      cmp r1, #0x0
      beq NoRocky

CheckContactMove:
      ldr r1, .CurrMove
      ldr r2, .MoveData
      ldrh r1, [r1]
      lsl r0, r1, #1
      add r0, r0, r1
      lsl r0, r0, #2
      add r0, r0, r2
      ldrb r0, [r0, #0x8]
      lsl r0, r0, #0x1F
      cmp r0, #0x0
      beq NoRocky

SetRecoilDamageAndScript:
      ldrh r0, [r3, #0xC]
      mov r1, #0x6 
      ldr r2, .Divider
      bl SubRoutCall
      cmp r0, #0x0
      bne NoZero
      mov r0, #0x1

NoZero:
      ldr r1, .Damage
      strh r0, [r1]       
      ldr r2, .ScriptPusher
      bl SubRoutCall
      ldr r1, .ScriptPointer
      ldr r0, .RockyHelmetBS
      str r0, [r1]
      ldr r1, .StringArguement 
      ldr r0, .StringOffset
      str r0, [r1]
      ldr r1, .ItemBuffer
      strh r7, [r1]
      ldr r2, .ReturnPass
      bx r2

SubRoutCall:
      mov pc, r2

NoRocky:
      ldr r2, .ReturnFail
      bx r2

.align 2
.Damage: .word 0x2023D50
.DamageStruct: .word 0x02023ECC
.CurrMove: .word 0x02023D4A
.BattleStruct: .word 0x02023C04
.UserBank: .word 0x02023D6B
.ScriptPointer: .word 0x02023D74
.StringArguement: .word 0x0203C020
.ItemBuffer: .word 0x02023D68
[B].StringOffset: .word 0x8DDDDDD
.RockyHelmetBS: .word 0x08AAAAAA[/B]
.ScriptPusher: .word 0x8017544+1
.Divider: .word 0x081E4018+1
.ReturnPass: .word 0x080236FC+1
.ReturnFail: .word 0x080237C8+1
[B].MoveData: .word 0x08250C04[/B]

Battle Script at AAAAAA:

Spoiler:

35 D0 3D 02 02 00 01 10 00 0B 01 0C 01 10 84 01 12 40 00 19 01 00 00 00 00 00 3C

Battle String at DDDDDD:

FD 10 B4 E7 00 FD 16 FE DC E9 E6 E8 00 FD 0F AB FF

Weakness Policy:-

Spoiler:

Routine:

Spoiler:

.text
.align 2
.thumb
.thumb_func
.global weaknesspolicy

CheckSuperEffectiveness:
      ldr r1, .Outcome
      ldrb r0, [r1]
      mov r2, #0x2
      and r0, r2
      cmp r0, #0x0
      beq NoPolicy

CheckDamage:
      ldr r2, .DamageStruct
      ldr r0, .UserBank
      add r0, #0x1
      ldrb r1, [r0, #0x0]
      lsl r0, r1, #0x2
      add r0, r0, r1
      lsl r1, r0, #0x2
      add r0, r2, #0x4
      add r0, r1, r0
      ldr r1, [r0, #0x0]
      cmp r1, #0x0
      beq NoPolicy

CheckTargetHP:
      ldrh r0, [r6, #0x28]
      cmp r0, #0x0
      beq NoPolicy

CheckTargetSubstitute:
      ldr r0, [r6, #0x50]
      mov r1, #0x1
      lsl r1, r1, #0x18
      and r0, r1
      cmp r0, #0x0
      bne NoPolicy

SetPolicyScript:
      ldr r2, .ScriptPusher
      bl SubRoutCall
      ldr r1, .ScriptPointer
      ldr r0, .WeaknessPolicyBS
      str r0, [r1]
      ldr r1, .ItemBuffer
      strh r7, [r1]
      ldr r2, .ReturnPass

SubRoutCall:
      mov pc, r2

NoPolicy:
      ldr r2, .ReturnFail
      bx r2

.align 2
.Outcome: .word 0x02023DCC
.DamageStruct: .word 0x02023ECC
.BattleStruct: .word 0x02023BE4
.UserBank: .word 0x02023D6B
.ScriptPointer: .word 0x02023D74
.ItemBuffer: .word 0x02023D68
[B].WeaknessPolicyBS: .word 0x08AAAAAA[/B]
.ScriptPusher: .word 0x8017544+1
.ReturnPass: .word 0x080236FC+1
.ReturnFail: .word 0x080237C8+1

Battle Script at AAAAAA:

Spoiler:

#dynamic 0x730400
#freespacebyte 0xFF

#org @start
jumpifstat 0x0 0x3 0x1 0xC @attack2
jumpifstat 0x0 0x0 0x4 0xC @ret

#org @attack2
removeitem 0x0
setbyte 0x2023FDF 0x0
playstatchangeanimation 0x0 0x12 0x0
setbyte 0x2023FDE 0x21
statbuffchange 0x0 false @spatk2
jumpifbyte 0x0 0x2023E87 0x2 @spatk2
[B]setword 0x2023C020 0x8DDDDDD[/B]
printstring 0x184
waitmessage 0x40

#org @spatk2
setbyte 0x2023FDE 0x24
statbuffchange 0x0 false @ret
jumpifbyte 0x0 0x2023E87 0x2 @ret
[B]setword 0x2023C020 0x8DDDDDD[/B]
printstring 0x184
waitmessage 0x40

#org @ret
return

Battle String at DDDDDD:

FD 10 B4 E7 00 FD 16 00 E7 DC D5 E6 E4 E0 ED FE E6 D5 DD E7 D9 D8 00 DD E8 E7 00 FD 00 AB FF

Knock Off Ban-list Hook:-

Spoiler:

Good place to put logic to prevent removal of specific Mega Stone on a Mega-evolving mon, or Plates on a Multitype mon.
Also prevents loss of Weakness Policy due to a Super-Effective Knock Off.

.text
.align 2
.thumb
.thumb_func
.global knockoffbanlist

CheckStickyHold:
      add r0, #0x20
      ldrb r2, [r0]
      cmp r2, #0x3C
      beq Sticky

CheckItem:
      ldrh r0, [r1, #0x2E]
      cmp r0, #0x0
      beq NoItem

BanList:
      push {r3-r4,r7}
      mov r3, r0

CheckOutcome:
      ldr r1, .Outcome
      ldrb r0, [r1]
      mov r2, #0x2
      and r0, r2
      cmp r0, #0x0
      beq CheckOthers

CheckWeaknessPolicy:
      mov r0, r3
      bl GetEffect
      cmp r0, #[U][B]0xKK[/B][/U]
      beq PopBeforeFail

CheckOthers:
     /* Write you code here for Non-Removable Mega Stones,  etc.*/
RemovableItem:
      pop {r3-r4,r7}
      ldr r0, =0x0802105E+1
      bx r0

PopBeforeFail:
      pop {r3-r4,r7}

NoItem:
      ldr r0, =0x080210EC+1
      bx r0

Sticky:
      ldr r0, =0x08021030+1
      bx r0

GetEffect:
      ldr r1, =0x0809A924+1
      bx r1

.align 2
.Outcome: .word 0x02023DCC
/*KK is the effect byte of Weakness Policy*/
/*At x21028: 00 4A 10 47 XX+1 XX XX 08*/

What would be the consequence if I didn't edit those custom battle script moves?

Also, it seems that BSP is not recognizing "removeitem" command as valid. Tried to remove it but the Weakness Policy doesn't seem to work properly

 

[Trainer 781]

What would be the consequence if I didn't edit those custom battle script moves?

Also, it seems that BSP is not recognizing "removeitem" command as valid. Tried to remove it but the Weakness Policy doesn't seem to work properly

Most probably, things like Conversion and Mirror Move will fail on those custom battle script moves.
For removeitem, check the Natural Gift move implementation in move resource thread.