Code: ASM Resource Thread

[Greow7]

Day/Night Switching of Textbox Palettes (FireRed)

So this is one of my few successful ASM hacks. What it does is swap the palettes used by the textbox depending on whether it is day or night (based on Prime Dialga's D/N system). Some of you older users may remember such a feature being implemented by Shiny Quagsire for Pokémon Grey (iirc).

So the first thing you need to do is go to 0x471DEC and copy 0xA0 bytes there, and then paste them into freespace somewhere. Be sure to note the offset. These are the five palettes used by the textboxes. You can use this copy as the base for your new night palettes.

Next, assemble and insert the following routine into freespace, once again noting the offset. Be sure to replace the ZZZZZZ with the offset of your new night palettes.

.text
.align 2
.thumb
.thumb_func

main:
  @ get the time
  ldr r1, =(0x300553C) @ if your RTC uses a different location for the time, change this
  ldrb r1, [r1, #0x6]

  @ check the time
  @ if <= 6 AM or >= 6 PM
  @   load night palette
  @ else
  @   load day palette
  cmp r1, #0x6 @ 6 AM
  ble set_night
  cmp r1, #0x12 @ 6 PM
  bge set_night

set_day:
  ldr r1, day_palette
  b return

set_night:
  ldr r1, night_palette

return:
  @ this uses the end of the original function
  @ so there should be no problems
  add r0, r0, r1
  pop {r1}
  bx r1

.align 2

day_palette:
  .word 0x08471DEC

night_palette:
  .word 0x08ZZZZZZ @ change this to your night palette

Now finally, navigate to 0x150448 and place this (the hook):

00 49 08 47 XX XX XX 08 00 00 00 00

Where XX XX XX 08 is the pointer to the location you inserted the ASM + 1.

I know it's a bit of a silly hack, but I hope someone makes use of it! :)

Is there something like this but for the battle background?

Meaning instead of the text box the battle backgrounds looks like a night palette.

 

[StardustSpectre]

Updated light ball to raise Pikachu's attack:

Spoiler:

At 3F020: 00 49 08 47 XX XX XX 08 00 00 00 00 00 00 00 00 00 00

.text
.align 2
.thumb
.thumb_func

mov r3, r10
cmp r3, #0x2d
beq ball
cmp r3, #0x41
bne noboost

ldrh r0, [r6, #0x0]
sub r0, #0x68
lsl r0, r0, #0x10
lsr r0, r0, #0x10
cmp r0, #0x1
bhi noboost
ldr r1, return1
bx r1

ball:
ldrh r0, [r6, #0x0]
cmp r0, #0x19
bne noboost
ldr r1, return1
bx r1

noboost:
ldr r1, return2
bx r1

.align 2
return1: .word 0x0803F033
return2: .word 0x0803F037

Do we know where the Light Ball's effect is stored in Emerald?

 

[jmynes]

Checking HM Compatibility
Hey guys, I've got a fun one for you. If you're like me and hate wasting move slots on HMs, this hack will make that a thing of the past. This hack checks whether the player's team contains a Pokemon that can learn an HM you specify. It doesn't check if they actually HAVE it, only whether they CAN learn it. Used correctly, the player can simply walk up to a tree and cut it immediately if they have a Pokémon that can cut. This is for Fire Red but porting it should be simple if you know the equivalent offsets in Emerald (and I don't, if someone does, let me know and I'll update this post)

Compile and insert to free space:

Spoiler:

.align 2
.thumb

start:
push {r0-r5, lr}
mov r5, #0x0

loopback:
ldr r0, =(0x2024284) /* Player's party in RAM */
mov r2, #0x64
mov r1, r5
mul r1, r1, r2
add r0, r0, r1
mov r1, #0xB
ldr r3, =(0x803FBE8 +1) /* Pokemon decrypter */
bl linker

ldr r3, =(0x8252BD0) /* TM Compatibility table */
lsl r0, r0, #0x3
add r3, r0, r3
add r3, r3, #0x6
ldrb r2, [r3]
ldr r1, =(0x20370D0) /* Var 0x800D in RAM */
ldrb r0, [r1]
mov r3, r0
and r3, r2, r3
cmp r0, r3
beq end

ldr r3, =(0x2024029) /* Player's team size */
ldrb r3, [r3]
add r5, r5, #0x1
cmp r5, r3
beq endfail
b loopback

end:
strb r5, [r1]
pop {r0-r5, pc}

endfail:
mov r5, #0x6
strb r5, [r1]
pop {r0-r5, pc}

linker:
bx r3

NOTE: Before you compile, direct your attention to the line highlighted in blue. The offset here is the offset of the table that determines TM/HM compatibility. If you have expanded the number of Pokémon in your hack, be sure to change this offset to whatever the new offset is.

Now, using this ASM is simple. In whatever script you're writing, first set variable 0x800D (aka LASTRESULT) to one of the following values based on the HM you are checking:

Spoiler:

0x4 - Cut
0x8 - Fly
0x10 - Surf
0x20 - Strength
0x40 - Flash
0x80 - Rock Smash

Then, call the ASM using Callasm. After the ASM runs, variable 0x800D will be set to the party slot containing the Pokémon who can learn whatever move you checked for, or 0x6 if no Pokémon was found.

The only issue is, Fly and Flash aren't used in scripts by the game, and Dive and Waterfall can't be checked. Making items that perform the same functions using other methods, however, is a working substitute.

Here's an example script. Let's say I'm editing the cut tree script. (If you remove the badge check and attack check as I have you can actually overwrite the original script with this, as there's enough space for it)

Spoiler:

#org 0x81BDF13
'-----------------------------------
special INIT_STEPCOUNT
compare LASTRESULT 0x2
if == jump 0x81A7AE0 ' Equal To
lockall
setvar LASTRESULT 0x4
callasm 0x8XXXXXX ' This should be changed to wherever you put the ASM in your ROM
compare LASTRESULT 0x6
if == jump 0x81BDF87 ' This skips the rest of the script if 0x6 is returned
setanimation 0x0 0x800D
storepartypokemon 0x0 0x800D
storeattack 0x1 0xF
msgbox 0x81BDF94 ' This tree looks like...
callstd MSG_YESNO ' Yes/No message
compare LASTRESULT NO
if == jump 0x81BDF91 ' Equal To
msgbox 0x81BDFD7 ' \v\h02 used \v\h03!
callstd MSG_NOCLOSE ' Non-closing message
closemsg
doanimation 0x2
waitspecial
jump 0x81BDF76

Anyways, that's that. I'll be using this in the future, but I do hope others can make use of it too.

Has anyone reimplemented this in HMA?

EDIT:
Now that we got the row bug resolved, I'm going to try to turn this into modern HMA instructions, and include details about how to get this working with each HM