Code: Ability Resource Thread

[kleenexfeu]

Imposter :

Spoiler:

Emerald

Spoiler:

Read me:

Spoiler:

When I say "don't use it if X", it's because it is already covered in X.

The battle script comes first (don't use it if you want to implement Mega evolution):

Spoiler:

#org 0xKKKKKK
transformdataexecution
attackanimation
waitanimation
printfromtable 0x85CC8D4
waitmessage 0x40
end3

Switch in Check (remove the bolded lines if you don't have the primal/mega weather) (don't use if you want mega evolution):

Spoiler:

.text
.align 2
.thumb
.thumb_func
.global checkswitchin

Start:
ldrb r3, [r5]
cmp r1, r3
blo CheckIfSwitchInAbility
mov r0, r10
strb r0, [r2]
 
CheckIfSwitchInAbility:
ldrb r0, [r7]
cmp r0, #0x2
bne CheckCloudNine

Drizzle:
ldr r2, FreeRam
ldrb r1, [r2]
cmp r1, #0x00
bne NoSwitchInAbility
ldr r1, =(0x08042B78+1)
bx r1

CheckCloudNine:
cmp r0, #0x0D
bne CheckIntimidate
b AirLockCloudNine

CheckIntimidate:
cmp r0, #0x16
bne CheckTrace

Intimidate:
ldr r1, =(0x08042C08+1)
bx r1

CheckTrace:
cmp r0, #0x24
bne CheckSandStream

Trace:
ldr r1, =(0x08042C68+1)
bx r1

CheckSandStream:
cmp r0, #0x2D
bne CheckForecast

SandStream:
ldr r2, FreeRam
ldrb r1, [r2]
cmp r1, #0x00
bne NoSwitchInAbility
ldr r1, =(0x08042BA8+1)
bx r1

CheckForecast:
cmp r0, #0x3B
bne CheckDrought

ForeCast:
ldr r1, =(0x08042C3C+1)
bx r1

CheckDrought:
cmp r0, #0x46
bne CheckAirLock

Drought:
ldr r2, FreeRam
ldrb r1, [r2]
cmp r1, #0x00
bne NoSwitchInAbility
ldr r1, =(0x08042BD8+1)
bx r1

CheckAirLock:
cmp r0, #0x4D
bne CheckDelta

AirLockCloudNine:
ldr r2, FreeRam
ldrb r1, [r2]
cmp r1, #0x00
bne NoSwitchInAbility
ldr r1, =(0x08042CA4+1)
bx r1

[b]CheckDelta:
cmp r0, #0xC0	/*Number of your ability Delta Stream*/
bne CheckDeso

UpdateStrongWind:
ldr r0, CurrentWeather
mov r1, #0
strb r1, [r0]
ldr r0, FreeRam
ldrb r1, [r0]
cmp r1, #0xC0	/*Number of your ability Delta Stream*/
beq NoSwitchInAbility
mov r1, #0xC0	/*Number of your ability Delta Stream*/
strb r1, [r0]
ldr r0, BattleScript
bl ExecuteScript
ldr r1, =(0x08042A72+1)
bx r1

CheckDeso:
cmp r0, #0xBF	/*Number of your ability Desolate Land*/
bne CheckPrimo

UpdateDesolate:
ldr r2, FreeRam
mov r0, #0xBF	/*Number of your ability Desolate Land*/
strb r0, [r2]
ldr r2, =(0x08042BD8+1)
bx r2

CheckPrimo:
cmp r0, #0xBE	/*Number of your ability Primordial Sea*/
bne CheckImposter

UpdatePrimordial:
ldr r2, FreeRam
mov r0, #0xBE	/*Number of your ability Primordial Sea*/
strb r0, [r2]
ldr r2, =(0x08042B78+1)
bx r2[/b]

CheckImposter:
cmp r0, #0x97	/*Number of your ability Imposter*/
beq Imposter

NoSwitchInAbility:
ldr r1, =(0x08042A7E+1)
bx r1

ExecuteScript:
ldr r1, =(0x08042BEE+1)
bx r1

Imposter:
mov r0, r10
ldr r1, BankUser
b CheckTargetAndStore

Store:
ldr r0, BankTarget
strb r4, [r0]
pop {r0-r4}
mov r0, r10
strb r0, [r1]

Next:
ldr r0, CurrentMove
mov r1, #0x90	/*Index number of Transform move*/
strh r1, [r0]
ldr r0, CurrentMove2
strh r1, [r0]
ldr r0, BattleScriptImposter
bl ExecuteScript
ldr r1, =(0x08042A72+1)
bx r1

PopNoSwitch:
pop {r0-r4}
b NoSwitchInAbility

CheckTargetAndStore:
push {r0, r1}
ldr r0, NPokeOnField
ldrb r1, [r0]
cmp r1, #2
beq Simple
pop {r0, r1}
cmp r0, #0
beq ThreeTarget
cmp r0, #2
beq OneTarget
cmp r0, #1
beq TwoTarget
mov r0, #0
b CheckTarget

ThreeTarget:
mov r0, #3
b CheckTarget

TwoTarget:
mov r0, #2
b CheckTarget

OneTarget:
mov r0, #1
b CheckTarget

Simple:
pop {r0, r1}
cmp r0, #0
beq OneTarget
mov r0, #0

CheckTarget:
push {r0-r4}
ldr r1, BattleData
mov r2, #0x58
mov r4, r0
mul r0, r2
add r0, r1
add r0, #0x28
ldrh r3, [r0]
cmp r3, #0
beq PopNoSwitch
add r0, #0x28
ldr r3, [r0]
ldr r2, TransformSubStatut
and r3, r2
cmp r3, #0
bne PopNoSwitch
ldr r2, InvulnStatut
mov r0, r4
ldr r3, CheckInvulnerableStatut
lsl r0, #2
add r0, r3
ldr r3, [r0]
and r3, r2
cmp r3, #0
bne PopNoSwitch
b Store

.align 2
InvulnStatut: .word 0x400C0
TransformSubStatut: .word 0x1200000
NPokeOnField: .word 0x0202406C
BattleData: .word 0x02024084
BankUser: .word 0x0202420B
CurrentMove: .word 0x020241EA
CurrentMove2: .word 0x020241EC
BankTarget: .word 0x0202420C
BattleScript: .word 0x08A21E80
CurrentWeather: .word 0x020243CC
FreeRam: .word 0x0203E331
ActiveBSPointer: .word 0x02024214
BattleScriptImposter: .word 0x08KKKKKK	/*BattleScript imposter*/
CheckInvulnerableStatut: .word 0x020242AC

/*00 4B 18 47 xx+1 xx xx 08  at 08042A20*/

Transform doesn't work on a substitute:

Spoiler:

.text
.align 2
.thumb
.thumb_func
.global altertransform2

Start:
mov r5, r7
add r5, #0x50
add r0, r0, r5
ldr r0, [r0]
ldr r4, TransformSubStatut
and r4, r0
cmp r4, #0
bne Fail
ldr r2, Return
bx r2

Fail:
ldr r2, ReturnFail
bx r2

.align 2
TransformSubStatut: .word 0x1200000
Return: .word 0x08052088+1
ReturnFail: .word 0x080520A2+1

/*00 4D 28 47 xx+1 xx xx 08 at 08052080*/

Perhaps it's not the better way to do it, any suggestion is welcome.

3. New Switch-in Ability System

Shouldn't we edit the transform command too ? In the case you get intimidate or something

 

[Trainer 781]

Perhaps it's not the better way to do it, any suggestion is welcome.

Shouldn't we edit the transform command too ? In the case you get intimidate or something

I tried doing it myself before with the switch-in system but it froze. Maybe because of the fact that it is not a move execution script. The transform command did not froze but the attackanimation froze that script.

 

[kleenexfeu]

I tried doing it myself before with the switch-in system but it froze. Maybe because of the fact that it is not a move execution script. The transform command did not froze but the attackanimation froze that script.

Yeah, that´s why I used a little trick : I stored the index number of tranform in the current move location 0x020241EA
That way the engine believe we're executing the move transform, which is almost the case. So the animation of tranform is automatically played (this is the animation itself that allow the sprite to be updated)
Alternatively we could use playanimation and expand the table as I did for Delta Stream but my main problem was to load the good target/user and make the ability fail when it had to, so I did not take time to update with a cleaner way

EDIT : The alternative doesn't works for some reason, everything is copied (stats, buff stats, attacks etc..) but the target's sprite. The palette is indeed clearer than the target, but the sprite remains the same

 

[javacola2.0]

Imposter :

Spoiler:

Emerald

Spoiler:

The battle script comes first :

Spoiler:

[spoiler]
[code]
.text
.align 2
.thumb
.thumb_func
.global checkswitchin

Start:
ldrb r3, [r5]
cmp r1, r3
blo CheckIfSwitchInAbility
mov r0, r10
strb r0, [r2]
 
CheckIfSwitchInAbility:
ldrb r0, [r7]
cmp r0, #0x2
bne CheckCloudNine

Drizzle:
ldr r2, FreeRam
ldrb r1, [r2]
cmp r1, #0x00
bne NoSwitchInAbility
ldr r1, =(0x08042B78+1)
bx r1

CheckCloudNine:
cmp r0, #0x0D
bne CheckIntimidate
b AirLockCloudNine

CheckIntimidate:
cmp r0, #0x16
bne CheckTrace

Intimidate:
ldr r1, =(0x08042C08+1)
bx r1

CheckTrace:
cmp r0, #0x24
bne CheckSandStream

Trace:
ldr r1, =(0x08042C68+1)
bx r1

CheckSandStream:
cmp r0, #0x2D
bne CheckForecast

SandStream:
ldr r2, FreeRam
ldrb r1, [r2]
cmp r1, #0x00
bne NoSwitchInAbility
ldr r1, =(0x08042BA8+1)
bx r1

CheckForecast:
cmp r0, #0x3B
bne CheckDrought

ForeCast:
ldr r1, =(0x08042C3C+1)
bx r1

CheckDrought:
cmp r0, #0x46
bne CheckAirLock

Drought:
ldr r2, FreeRam
ldrb r1, [r2]
cmp r1, #0x00
bne NoSwitchInAbility
ldr r1, =(0x08042BD8+1)
bx r1

CheckAirLock:
cmp r0, #0x4D
bne CheckDelta

AirLockCloudNine:
ldr r2, FreeRam
ldrb r1, [r2]
cmp r1, #0x00
bne NoSwitchInAbility
ldr r1, =(0x08042CA4+1)
bx r1

[b]CheckDelta:
cmp r0, #0xC0	/*Number of your ability Delta Stream*/
bne CheckDeso

UpdateStrongWind:
ldr r0, CurrentWeather
mov r1, #0
strb r1, [r0]
ldr r0, FreeRam
ldrb r1, [r0]
cmp r1, #0xC0	/*Number of your ability Delta Stream*/
beq NoSwitchInAbility
mov r1, #0xC0	/*Number of your ability Delta Stream*/
strb r1, [r0]
ldr r0, BattleScript
bl ExecuteScript
ldr r1, =(0x08042A72+1)
bx r1

CheckDeso:
cmp r0, #0xBF	/*Number of your ability Desolate Land*/
bne CheckPrimo

UpdateDesolate:
ldr r2, FreeRam
mov r0, #0xBF	/*Number of your ability Desolate Land*/
strb r0, [r2]
ldr r2, =(0x08042BD8+1)
bx r2

CheckPrimo:
cmp r0, #0xBE	/*Number of your ability Primordial Sea*/
bne CheckImposter

UpdatePrimordial:
ldr r2, FreeRam
mov r0, #0xBE	/*Number of your ability Primordial Sea*/
strb r0, [r2]
ldr r2, =(0x08042B78+1)
bx r2[/b]

CheckImposter:
cmp r0, #0x97	/*Number of your ability Imposter*/
beq Imposter

NoSwitchInAbility:
ldr r1, =(0x08042A7E+1)
bx r1

ExecuteScript:
ldr r1, =(0x08042BEE+1)
bx r1

Imposter:
ldr r0, BattleData
ldr r1, BankUser
push {r7}
ldr r7, FreeRam2
ldr r7, [r7]
sub r7, r0
cmp r7, #0x20
beq Zero
cmp r7, #0x78
beq One
cmp r7, #0xD0
beq Two
mov r0, #3
b CheckTargetAndStore

Store:
pop {r0-r3}
mov r0, r7
pop {r7}
strb r0, [r1]

Next:
ldr r0, CurrentMove
mov r1, #0x90	/*Index number of Transform move*/
strh r1, [r0]
ldr r0, CurrentMove2
strh r1, [r0]
ldr r0, BattleScriptImposter
bl ExecuteScript
ldr r1, =(0x08042A72+1)
bx r1

Zero:
mov r0, #0
b CheckTargetAndStore

PopNoSwitch:
pop {r0-r3}
pop {r7}
b NoSwitchInAbility

One:
mov r0, #1
b CheckTargetAndStore

Two:
mov r0, #2
b CheckTargetAndStore

CheckTargetAndStore:
mov r7, r0
push {r0, r1}
ldr r0, BattleFlag
ldr r0, [r0]
mov r1, #1
lsl r1, #0xB
add r1, #1
and r0, r1
cmp r0, #0
beq Simple
pop {r0, r1}
cmp r0, #0
beq ThreeTarget
cmp r0, #2
beq OneTarget
cmp r0, #1
beq TwoTarget
mov r0, #0
b CheckTarget

ThreeTarget:
mov r0, #3
b CheckTarget

TwoTarget:
mov r0, #2
b CheckTarget

OneTarget:
mov r0, #1
b CheckTarget

Simple:
pop {r0, r1}
cmp r0, #0
beq OneTarget
mov r0, #0

CheckTarget:
push {r0-r3}
ldr r1, BattleData
mov r2, #0x58
mul r0, r2
add r0, r1
add r0, #0x28
ldrh r3, [r0]
cmp r3, #0
beq PopNoSwitch
add r0, #0x28
ldr r3, [r0]
mov r2, #1
lsl r2, #0x15
and r3, r2
cmp r3, #0
bne PopNoSwitch
b Store


.align 2
BattleFlag: .word 0x02022FEC
FreeRam2: .word 0x0203E338
BattleData: .word 0x02024084
BankUser: .word 0x0202420B
CurrentMove: .word 0x020241EA
CurrentMove2: .word 0x020241EC
BattleScript: .word 0x08A21E80
CurrentWeather: .word 0x020243CC
FreeRam: .word 0x0203E331
ActiveBSPointer: .word 0x02024214
BattleScriptImposter: .word 0x08KKKKKK	/*BattleScript imposter*/

/*00 4B 18 47 xx+1 xx xx 08  at 08042A20*/

Dealing with the target:

Spoiler:

.text
.align 2
.thumb
.thumb_func
.global transformmodif

Start:
ldr r0, BankTarget
ldr r1, BankUser
mov r12, r0
ldr r6, CurrentMove
ldr r6, [r6]
push {r0}
ldr r0, TransformBS
cmp r6, r0
beq PopR0Back
pop {r0}
ldrb r6, [r1]
push {r0, r1}
ldr r0, BattleFlag
ldr r0, [r0]
mov r1, #1
lsl r1, #0xB
add r1, #1
and r0, r1
cmp r0, #0
beq Simple
pop {r0, r1}
cmp r6, #0
beq Three
cmp r6, #2
beq One
cmp r6, #1
beq Two
mov r6, #0
b End

Simple:
pop {r0, r1}
cmp r6, #0
beq One
mov r6, #0
b End

Two:
mov r6, #2
b CheckAndBack

Three:
mov r6, #3
b CheckAndBack

One:
mov r6, #1

PopAndBack:
pop {r0-r2}

Back:
mov r6, #0x58
ldr r0, Return
bx r0

PopR0Back:
pop {r0}
ldrb r1, [r0]
b Back

End:
mov r1, r6
strb r6, [r0]
b Back

.align 2
BattleFlag: .word 0x02022FEC
CurrentMove: .word 0x02024214
TransformBS: .word 0x082D9249+4 	/*BattleScript of Transform +4*/
BankTarget: .word 0x0202420C
BankUser: .word 0x0202420B
Return: .word 0x0805207C+1
BattleData: .word 0x02024084

/*00 48 00 47 xx+1 xx xx 08 at 08052074 */

Keeping the ability:

Spoiler:

.text
.align 2
.thumb
.thumb_func
.global transformmodif

Start:
ldr r2, =0x0202420A
mul r5, r0
mov r0, r5
add r0, r0, r1
add r0, #0x20
ldr r5, FreeRam2
str r0, [r5]
ldrb r0, [r0]
ldr r5, Return
bx r5

.align 2
Return: .word 0x0804296A+1
FreeRam2: .word 0x0203E338

/*00 4A 10 47 xx+1 xx xx 08 at 08042960*/
/*You need 4 byte of free space word aligned for FreeRam2*/

Notes :

Spoiler:

-I'll update the ability as well as the transform command. Those are not supposed to work if the target is behind a substitute.

Bugs :

Spoiler:

-For some reason, if wild poke other than ditto has imposter, sometimes it doesn't copy correctly the moves of your poke.

Perhaps it's not the better way to do it, any suggestion is welcome.



Shouldn't we edit the transform command too ? In the case you get intimidate or something

You're the man. I was giving up hope.

Edit: Ah crap I just realized it's for Emerald. Oh well, at least it'll be in the next FR base.

 

[kleenexfeu]

You're the man. I was giving up hope.

Edit: Ah crap I just realized it's for Emerald. Oh well, at least it'll be in the next FR base.

It is easily portable to FR, I'll update soon. It's just I never use FR so every time I do a routine I'm too lazy to seek for FR offset. But if someone ask I guess I can make an effort

I have also the -ate abilities done :

Spoiler:

Emerald :

Spoiler:

.text
.align 2
.thumb
.thumb_func
.global ateabilities

Start:
push {r0-r4}
mov r0, r10
cmp r0, #0	/*Normal type*/
beq AteCheck

PopAndClassic:
pop {r0-r4}

Classic:
ldrh r0, [r6, #0x2E]
cmp r0, #0xAF
bne Back
ldr r1, SomeLoc
ldr r2, Return
mov pc, r2

Back:
ldr r0, Return1
mov pc, r0

AteCheck:
mov r4, #0x20
ldrb r4, [r6, r4]
cmp r4, #0xB7	/*Index number Pixilate*/
beq Pixi
cmp r4, #0xB9	/*Index number Aerilate*/
beq Aeri
cmp r4, #0xAF	/*Index number Refrigerate*/
beq Refri
b PopAndClassic

Pixi:
mov r0, #0x17	/*Index number of your Fairy type*/
b StoreAndBoost

Aeri:
mov r0, #2	/*Index number of your Flying type*/
b StoreAndBoost

Refri:
mov r0, #0xF	/*Index number of your Ice type*/

StoreAndBoost:
Store:
ldr r1, ChangeTypeLoc
ldr r1, [r1]
add r1, #0x13
ldrb r2, [r1]
cmp r2, #0
bne PopAndClassic
strb r0, [r1]
mov r2, r0
mov r10, r0

Boost:
mov r0, r8
mov r3, #0xA7
mul r0, r3
lsr r0, #7
mov r8, r0
mul r7, r3
lsr r7, #7
b PopAndClassic



.align 2
Return: .word 0x0806961C+1
Return1: .word 0x08069634+1
ChangeTypeLoc: .word 0x0202449C
SomeLoc: .word 0x02024404

/*00 48 00 47 xx+1 xx xx 08 at 08069614*/

 

[Aruaruu]

Imposter :

Think I found some bugs/oversights.

When an enemy is digging (and also assume flying, diving, bouncing) and you switch in with Imposter Pokemon it will loop "But it Failed" Endlessly.

I may be wrong but even with Choice Scarf item held i cannot go before the opponent most times even though I have maxed speed for the Imposter Pokemon. I'm still playing with this so its probably just some stupid mistake I'm making.

Also in the asm for switch in check should it be like this if I don't use the mega weather?

CheckAirLock:
cmp r0, #0x4D
bne CheckImposter

 

[kleenexfeu]

Think I found some bugs/oversights.

When an enemy is digging (and also assume flying, diving, bouncing) and you switch in with Imposter Pokemon it will loop "But it Failed" Endlessly. Thanks for that, I stupidly forgot to check some other statuts

I may be wrong but even with Choice Scarf item held i cannot go before the opponent most times even though I have maxed speed for the Imposter Pokemon. I'm still playing with this so its probably just some stupid mistake I'm making. Did you test your scarf seperatly ? Perhaps it's the scarf routine that doesn't work

Also in the asm for switch in check should it be like this if I don't use the mega weather?

CheckAirLock:
cmp r0, #0x4D
bne CheckImposter

Yeah, I actually rewrote a part of the check switch-in system, it was not necessary but I found it just more readable, this part check for Air Lock, which is an existing ability in gen3 games.

Responses in bold, I'll look into fix the flying/bouncing/digging bug firstly.

EDIT: Fixed, including for the substitute thing. And the choice scarf works for me, I tried around 100 attack, with higher or lower level, I go first every time.

 

[Aruaruu]

Responses in bold, I'll look into fix the flying/bouncing/digging bug firstly.

EDIT: Fixed, including for the substitute thing. And the choice scarf works for me, I tried around 100 attack, with higher or lower level, I go first every time.

Awesome, and yeah, I think I was doing something wrong when testing Choice Scarf w/Impsoter since I tested it again and it works like it should.

 

[kleenexfeu]

Multitype + Mega/Primal keep their stone + Giratina/Griseous and such:

Spoiler:

Overworld:

Spoiler:

See this post

In battle(only emerald):

Spoiler:

Actually the only thing we have to do is prevent the plates from being stole if the pokemon is one of the form of Arceus, so we don't check the ability here (because of transform, worry seed, etc).

You should read the red bolded comments.
The check routine:

Spoiler:

.thumb
.thumb_func

[B][COLOR="red"].equ Myloc, 0x_______	@ Place you want to have the routine, without the 08 prefix, it'll be like 0xA00000
@ It must be the same in the three routines.

.equ NumberEvoPerPoke, 0x5  @@ Change that number to your number evo per poke.
.equ EvolutionPointerLocation, 0x806D140

.equ MegaEvolutionIndex, 0xFE	@ I choose to do as Touched here. 0xFE = Mega evolution
.equ PrimalReversionIndex, 0xFD	@ 0xFD = Primal

@@@@ Look at the bottom for the tables[/COLOR][/B]

.equ SizeRom, 0x8000000

.org Myloc


push {lr}
mov r4, #0
ldrh r1, [r0]
ldr r2, ArceusTable

LoopLoad:
ldrh r3, [r2]
cmp r3, r4
beq CheckMegPrim
cmp r3, r1
beq CheckItem
add r2, #2
b LoopLoad

CheckItem:
add r0, #0x2E
ldrh r1, [r0]
ldr r2, PlateTable

LoopLoad2:
ldrh r3, [r2]
cmp r3, r4
beq CheckMegPrim
cmp r3, r1
beq KeepingItem
add r2, #2
b LoopLoad2

KeepingItem:
mov r0 , #1
b Return

CheckMegPrim:
mov r2, #NumberEvoPerPoke
mov r3, #8
mul r2, r3
mul r2, r1
ldr r3, EvoPointer
ldr r3, [r3]
add r2, r3  @
mov r3, #0
sub r3, #1	@ r3 counter
sub r2, #8	@ r2 evolution data of the poke

LoopMegaPrim:
add r3, #1	@ buff loop
add r2, #8	@ buff loop
cmp r3, #NumberEvoPerPoke
beq CheckSpecific
ldrh r4, [r2]
cmp r4, #MegaEvolutionIndex
beq CheckStoneOrb
cmp r4, #PrimalReversionIndex
beq CheckStoneOrb
b LoopMegaPrim

CheckStoneOrb:
ldrh r4, [r2, #2]
ldrh r1, [r0, #0x2E]
cmp r1, r4
beq KeepingItem
cmp r4, #0
beq KeepingItem
b LoopMegaPrim

CheckSpecific:
ldrh r1, [r0]
ldrh r2, [r0, #0x2E]
ldr r3, SpecificTable
sub r3, #4

LoopSpecific:
add r3, #4
ldrh r4, [r3]
cmp r4, #0
beq NotKeeping
cmp r4, r1
beq CheckItemMatch
b LoopSpecific

CheckItemMatch:
ldrh r4, [r3, #2]
cmp r4, r2
beq KeepingItem
b LoopSpecific

NotKeeping:
mov r0, #0

Return:
pop {pc}

.align 2
EvoPointer: .word EvolutionPointerLocation
PlateTable: .word PlateTableLocation+SizeRom
ArceusTable: .word ArceusTableLocation+SizeRom
SpecificTable: .word SpecificTableLocation+SizeRom

[B][COLOR="Red"]@@@@ The three tables must end with 0x0, 0x0, the numbers I used are just EXAMPLE

.align 2
PlateTableLocation: @@@ Index number of your plates
.hword 0xEB, 0xEC, 0xED, 0xEE, 0xEF, 0xF0, 0xF1, 0xF2, 0xF3, 0xF4, 0xF5, 0xF6, 0xF7, 0xF8, 0xF9, 0xFA, 0xEA, 0x0, 0x0
.align 2
ArceusTableLocation: @@@ Index number of your Arceus
.hword 0x101, 0x102, 0x103, 0x104, 0x105, 0x106, 0x107, 0x108, 0x109, 0x10a, 0x10b, 0x10c, 0x10d, 0x10e, 0x10f, 0x110, 0x111, 0x199, 0x0, 0x0
.align 2
SpecificTableLocation: @@@ Index specific poke + index specific item
.hword 0x112, 0xE4, 0x0, 0x0[/COLOR][/B]

First hook:

Spoiler:

.thumb
.thumb_func

[B][COLOR="red"].equ SizeRom, 0x8000000
.equ Myloc, 0x______

@@@@ 00 48 00 47 xx+1 xx xx 08 at 0x80495EC[/COLOR][/B]

mov r0, r4
push {r0-r4}
bl CheckIfKeep
cmp r0, #0
bne PopKeepItem
pop {r0-r4}
add r0, #0x20
ldrb r0, [r0]
cmp r0, #0x3C
beq KeepItem
ldr r0, Back
bx r0

CheckIfKeep:
ldr r4, CheckRoutine
bx r4

PopKeepItem:
pop {r0-r4}
ldr r0, KeepingMeg
bx r0

KeepItem:
ldr r0, Keeping
bx r0

.align 2
Keeping: .word 0x080495F4+1
Back: .word 0x0804963C+1
CheckRoutine: Myloc+SizeRom+1
KeepingMeg: .word 0x80499B2+1

Second hook:

Spoiler:

.thumb
.thumb_func

[B][COLOR="red"].equ SizeRom, 0x8000000
.equ Myloc, 0x______

@@@@ 00 48 00 47 xx+1 xx xx 08 at 0x80498D0[/COLOR][/B]

mov r0, r1
push {r0-r4}
bl CheckIfKeep
cmp r0, #0
bne PopKeepItem
pop {r0-r4}
add r0, #0x20
ldrb r2, [r0]
cmp r2, #0x3C
beq KeepItem
ldr r0, Back
bx r0

CheckIfKeep:
ldr r4, CheckRoutine
bx r4

PopKeepItem:
pop {r0-r4}
ldr r0, KeepingMeg
bx r0

KeepItem:
ldr r0, Keeping
bx r0

.align 2
Keeping: .word 0x080498D8+1
Back: .word 0x08049900+1
CheckRoutine: Myloc+SizeRom+1
KeepingMeg: .word 0x80499B2+1

Third hook:

Spoiler:

.thumb
.thumb_func

[B][COLOR="red"].equ SizeRom, 0x8000000
.equ Myloc, 0x______

@@@@ 00 48 00 47 xx+1 xx xx 08 at 0x8054FDC[/COLOR][/B]
mov r0, r1
push {r0-r4}
bl CheckIfKeep
cmp r0, #0
bne PopKeepItem
pop {r0-r4}
add r0, #0x20
ldrb r2, [r0]
cmp r2, #0x3C
beq KeepItem
ldr r0, Back
bx r0

CheckIfKeep:
ldr r4, CheckRoutine
bx r4

PopKeepItem:
pop {r0-r4}
ldr r0, KeepingMeg
bx r0

KeepItem:
ldr r0, Keeping
bx r0

.align 2
Keeping: .word 0x08054FE6+1
Back: .word 0x08055010+1
CheckRoutine: Myloc+SizeRom+1
KeepingMeg: .word 0x8054F9A+1

 

[kleenexfeu]

Prankster in my rombase is glitched, but I've made a new bug free routine.



Interesting! Thanks for that feedback, I do actually know EXACTLY what the problem is. It's in the section add r1, r1, r3 in Natural Cure, however I was unsure about actually putting it in for Regenerator as I thought it was just a double index check, but it's actually making sure that you can get the second Pokemon in your double battle fixed.

I've updated that post, so it should be all fixed.

No Guard

Spoiler:

Fire Red

Spoiler:

.text
.align 2
.thumb
.thumb_func
.global noguard
 
AbilityBufferUser:
	push {r0}
	ldr r0, .Bank
	ldrb r0, [r0]
	mov r1, #0x58
	ldr r2, .BattleData
	mul r0, r1
	add r0, r0, r2
	ldrb r0, [r0]
NoGuardCheckUser:
	cmp r0, #0x7E
	beq AutoHit
AbilityBufferTarget:
	ldr r0, .Bank
	add r0, #0x1
	ldrb r0, [r0]
	mul r0, r1
	add r0, r0, r2
	ldrb r0, [r0]
NoGuardCheckTarget:
	cmp r0, #0x7E
	beq AutoHit
ToxicCheck:
	ldr r0, .MoveLoc
	ldrh r0, [r0]
	cmp r0, #0x5C
	bne InvulnerableCheck
PoisonCheck:
	ldr r0, .Bank
	ldr r0, [r0]
	mov r1, #0x58
	ldr r2, .BattleData
	mul r0, r1
	add r2, r0, r2
	[b]ldrb r1, [r0, #1]
	ldrb r0, [r0, #2][/b]
	cmp r0, #0x3
	beq AutoHit
	cmp r1, #0x3
	beq AutoHit
InvulnerableCheck:
	pop {r0}
	bl Method
	lsl r0, r0, #0x18
	cmp r0, #0x0
	bne Miss
Return:
	ldr r1, .Return
	bx r1
AutoHit:
	pop {r0}
	ldr r1, .Return2
	bx r1
Miss:
	ldr r1, .Return3
	bx r1
Method:
	ldr r1, .MethodLoc
	bx r1


.align 2

.Bank: .word 0x02023D6B
.BattleData: .word 0x02023C04
.MoveLoc: .word 0x02023D4A
.Return: .word 0x0801DF51
.Return2: .word 0x0801E1BB
.Return3: .word 0x0801E1C3
.MethodLoc: .word 0x0801DC11

#insert 00 49 08 47 xx xx xx 08 00 00 at 01DF44

Emerald

Spoiler:

.text
.align 2
.thumb
.thumb_func
.global noguard
 
AbilityBufferUser:
	push {r0}
	ldr r0, .Bank
	ldr r0, [r0]
	mov r1, #0x58
	ldr r2, .BattleData
	mul r0, r1
	add r0, r0, r2
	ldrb r0, [r0]
NoGuardCheckUser:
	cmp r0, #0x7E
	beq AutoHit
AbilityBufferTarget:
	ldr r0, .Bank
	add r0, #0x1
	ldrb r0, [r0]
	mul r0, r1
	add r0, r0, r2
	ldrb r0, [r0]
NoGuardCheckTarget:
	cmp r0, #0x7E
	beq AutoHit
ToxicCheck:
	ldr r0, .MoveLoc
	ldrh r0, [r0]
	cmp r0, #0x5C
	bne InvulnerableCheck
PoisonCheck:
	ldr r0, .Bank
	ldr r0, [r0]
	mov r1, #0x58
	ldr r2, .BattleData
	mul r0, r1
	add r2, r0, r2
	[b]ldrb r1, [r0, #1]
	ldrb r0, [r0, #2][/b]
	cmp r0, #0x3
	beq AutoHit
	cmp r1, #0x3
	beq AutoHit
InvulnerableCheck:
	pop {r0}
	bl Method
	lsl r0, r0, #0x18
	cmp r0, #0x0
	bne Miss
Return:
	ldr r1, .Return
	bx r1
AutoHit:
	pop {r0}
	ldr r1, .Return2
	bx r1
Miss:
	ldr r1, .Return3
	bx r1
Method:
	ldr r1, .MethodLoc
	bx r1


.align 2

.Bank: .word 0x0202420B
.BattleData: .word 0x020240A4
.MoveLoc: .word 0x020241EA
.Return: .word 0x08046761
.Return2: .word 0x080469CB
.Return3: .word 0x080469D3
.MethodLoc: .word 0x080464AD

#insert 00 49 08 47 xx xx xx 08 00 00 at 046754

Fixes in bold. Also, the ability should be 0x64, not 0x7E

I think that post should be linked in the OP : http://www.pokecommunity.com/showpost.php?p=8712926&postcount=30 It contains the setword command, afaik there's no other place in the forum you can find it

 

[SBird]

Sometimes it seems that abilities posted in this thread were not even tested (like once) because when I tried to compile (tangled feet) I got compile time errors. Not that it would be hard to fix, but, uh, did you really not test this stuff?^^

.text
.align 2
.thumb
.global tangled_feet

tangled_feet:
    mov r0, r2
    mul r0, r7
    mov r3, r9
    add r1, r0, r3
    add r0, r1, #0x20 @out of range
    ldrb r0, [r0]
TangledFeetCheck:
    cmp r0, #ABILITY_TANGLED_FEET
    bne Return
    add r0, r1, #0x50 @like hell of a what totally out of range
    ldr r0, [r0]
    cmp r0, #0x0
    beq Return
EvasionBoost:
    lsl r0, r4, #0x2
    add r0, r0, r4
    lsl r0, r0, #0x4
    mov r1, #0x64
    bl Divide
    lsl r0, r0, #0x10
    lsr r4, r0, #0x10
Return:
    ldr r0, .Return
    bx r0
Divide:
    ldr r2, .DivideBL
    
.align 2

.Return: .word 0x0801E0E5
.DivideBL: .word 0x081E4019

~SBird

 

[kleenexfeu]

Sometimes it seems that abilities posted in this thread were not even tested (like once) because when I tried to compile (tangled feet) I got compile time errors. Not that it would be hard to fix, but, uh, did you really not test this stuff?^^

.text
.align 2
.thumb
.global tangled_feet

tangled_feet:
    mov r0, r2
    mul r0, r7
    mov r3, r9
    add r1, r0, r3
    add r0, r1, #0x20 @out of range
    ldrb r0, [r0]
TangledFeetCheck:
    cmp r0, #ABILITY_TANGLED_FEET
    bne Return
    add r0, r1, #0x50 @like hell of a what totally out of range
    ldr r0, [r0]
    cmp r0, #0x0
    beq Return
EvasionBoost:
    lsl r0, r4, #0x2
    add r0, r0, r4
    lsl r0, r0, #0x4
    mov r1, #0x64
    bl Divide
    lsl r0, r0, #0x10
    lsr r4, r0, #0x10
Return:
    ldr r0, .Return
    bx r0
Divide:
    ldr r2, .DivideBL
    
.align 2

.Return: .word 0x0801E0E5
.DivideBL: .word 0x081E4019

~SBird

That's the whole point of the thread : everyone can help/contribute. Of course the thread shouldn't be filled with buggy routines.
But I do think most of the routines work.
Also, you have to understand that MrDS is working on a base which is quite time-consuming. Since there's isn't many people that helps, it's the minority that does all the work. This can bring some mistake.

Also, thanks for the report, I'm sure it'll be fixed ASAP.

Finally, I saw you did pretty good hack (like the emerald expansion), feel free to contribute here !

 

[MrDollSteak]

Sometimes it seems that abilities posted in this thread were not even tested (like once) because when I tried to compile (tangled feet) I got compile time errors. Not that it would be hard to fix, but, uh, did you really not test this stuff?^^

.text
.align 2
.thumb
.global tangled_feet

tangled_feet:
    mov r0, r2
    mul r0, r7
    mov r3, r9
    add r1, r0, r3
    add r0, r1, #0x20 @out of range
    ldrb r0, [r0]
TangledFeetCheck:
    cmp r0, #ABILITY_TANGLED_FEET
    bne Return
    add r0, r1, #0x50 @like hell of a what totally out of range
    ldr r0, [r0]
    cmp r0, #0x0
    beq Return
EvasionBoost:
    lsl r0, r4, #0x2
    add r0, r0, r4
    lsl r0, r0, #0x4
    mov r1, #0x64
    bl Divide
    lsl r0, r0, #0x10
    lsr r4, r0, #0x10
Return:
    ldr r0, .Return
    bx r0
Divide:
    ldr r2, .DivideBL
    
.align 2

.Return: .word 0x0801E0E5
.DivideBL: .word 0x081E4019

~SBird

Thank you for identifying this problem in a constructive and polite manner.

You are completely right, I never test any of my routines because I deliberately wanted to inconvenience you specifically.

But in all seriousness, I didn't test this routine because I rewrote the existing code from my rombase and to my mind was optimising it, but looking at it now I made a mistake. Being rude doesn't make me fix the errors any more easily.

I look forward to you contributing your own abilities in the future, because currently there's only three of us working on all 100+ and you can clearly do ASM better than all of us.

 

[Deokishisu]

Thank you for identifying this problem in a constructive and polite manner.

You are completely right, I never test any of my routines because I deliberately wanted to inconvenience you specifically.

Way to overreact to what is clearly playful prodding.

I look forward to you contributing your own abilities in the future, because currently there's only three of us working on all 100+ and you can clearly do ASM better than all of us.

Unnecessary. We all, as a community, appreciate the work that you three are putting into this (and damn, it's definitely hard work!), but that doesn't give you the right to be so hostile. The routine was broken, Sbird pointed it out with a little teasing on the side.

On a more on topic note, I hear that expanding the Pokedex breaks Forecast/Castform in some way. I was wondering if anyone had taken a look into Forecast and see if it's the ability itself that's breaking?

 

[MrDollSteak]

Way to overreact to what is clearly playful prodding.

Unnecessary. We all, as a community, appreciate the work that you three are putting into this (and damn, it's definitely hard work!), but that doesn't give you the right to be so hostile. The routine was broken, Sbird pointed it out with a little teasing on the side.

On a more on topic note, I hear that expanding the Pokedex breaks Forecast/Castform in some way. I was wondering if anyone had taken a look into Forecast and see if it's the ability itself that's breaking?

I was just being playful too. Sure it looks a bit grumpy, but the initial teasing wasn't necessary in the first place, so I'm just responding to it in the same manner.
I do actually want more help from people, and my last statement was meant in a genuine way even with some additional banter.

Forecast is just a total mess of code, it's really confusing to look at and its spread over quite a few locations. I wish I could help more with it.

I'm also going to take the time to reserve this post for the end of turn abilities. I have a lot of them stored up.

 

[SBird]

Hey no need in getting offensive in any matter, it was not my purpose to provoke anyone here I just wanted to point out a thingy that could probably / or most likely be a problem for hackers who are not that confident with ASM hacking...

It is not that I want to insult someone personally, or shame his work, but exactly that.

And yes, of course I will contribute some stuff, spite I don't have any, I came here to look for abilities which were already implemented and working in order to have less work in the first place and I came here to look for some ideas for future abilities which I can then implement and of course I will post them here, once I am finished...

Yeah, so that, if anyone felt insulted it was not my purpose, still I see a problem in posting untested code you have to admit that this might not be the wisest choice. (I had to correct some logical errors too, like the common ARM != THUMB stuff, you know that stuff that happens a lot, at least to me...)

Also be sure that I will, once I am finished, post working snippets of code with reference to the original, once I am finished with my work, I am not a prick...

~SBird

EDIT: For the forecast / castform stuff: I think there is an hardcoded index in the rom, 0x00000181 - when expanding the pokedex just make sure not to change the castform entries for that (You have to change those thingies because they also represent the number of pokémon I suppose at least in HOEEN) - I do not know if I really fixed this bug once when I did the emerald expansion, but if I did it should be somewhere in Chaos Rush's tutorial, for BPRE you just want to do the same, either by research or trial n' error, there are only ten orwhat entries for that index.

 

[kleenexfeu]

Sturdy

For sturdy, the problem is the same than for defiant/competitive : display a message.
Display that message stop the multi hit move, and somehow makes the pokémon unbeatable for that turn, even if you don't use the 0x0202427C location

So I used the same way than protean to display the message :

Sturdy

Spoiler:

Emerald

Spoiler:

Handle damage:

Spoiler:

.text
.align 2
.thumb
.thumb_func
.global sturdyupdate
 
Sturdy:
	ldrb r0, [r3]
	mov r1, #0x58
	mul r0, r1
	add r0, r0, r2
	add r0, #0x20
	ldrb r1, [r0]
	cmp r1, #0x5
	bne FalseSwipeCheck
CheckHP:
	ldrh r1, [r0, #0xC]
	ldrh r0, [r0, #0x8]
	cmp r0, r1
	beq SturdySuccess
FalseSwipeCheck:
	ldr r0, MoveLoc
	ldrh r1, [r0]
	lsl r0, r1, #0x1
	add r0, r0, r1
	ldr r2, Return1
	bx r2
SturdySuccess:
	ldrb r0, [r3]
	mov r4, #0x58
	mul r0, r4
	add r0, r0, r5
	ldrh r1, [r0, #0x28]
	ldr r2, StoreDamage
	ldr r0, [r2]
	cmp r1, r0
	bgt Back
	sub r0, r1, #1
	str r0, [r2]
	ldr r0, Bank
	ldrb r1, [r0, #1]
	ldr r0, Flags
	lsl r1, #2
	add r1, r0
	ldr r2, [r1]
	ldr r0, SturdyStatut
	orr r0, r2
	str r0, [r1]
	
Back:
	ldr r1, Return3
	mov pc, r1

Jump:
	mov pc, r2

.align 2

MoveLoc: .word 0x020241EA
Return1: .word 0x080479DD
StoreDamage: .word 0x020241F0
Return3: .word 0x8047A84+1
Bank: .word 0x0202420B
Flags: .word 0x020242AC
SturdyStatut: .word 0x1000000

#insert 01 48 00 47 00 00 xx xx xx 08 1A 4A at 0479D2

Handle fix damage (dragon rage, seismic toss, etc) :

Spoiler:

.text
.align 2
.thumb
.thumb_func
.global sturdyupdate
 
Sturdy:
	ldrb r0, [r3]
	mov r1, #0x58
	mul r0, r1
	add r0, r0, r2
	add r0, #0x20
	ldrb r1, [r0]
	cmp r1, #0x5
	bne FalseSwipeCheck
CheckHP:
	ldrh r1, [r0, #0xC]
	ldrh r0, [r0, #0x8]
	cmp r0, r1
	beq SturdySuccess
FalseSwipeCheck:
	ldr r0, MoveLoc
	ldrh r1, [r0]
	lsl r0, r1, #0x1
	add r0, r0, r1
	ldr r2, Return1
	bx r2
SturdySuccess:
	ldrb r0, [r3]
	mov r4, #0x58
	mul r0, r4
	add r0, r0, r5
	ldrh r1, [r0, #0x28]
	ldr r2, StoreDamage
	ldr r0, [r2]
	cmp r1, r0
	bgt Back
	sub r0, r1, #1
	str r0, [r2]
	ldr r0, Bank
	ldrb r1, [r0, #1]
	ldr r0, Flags
	lsl r1, #2
	add r1, r0
	ldr r2, [r1]
	ldr r0, SturdyStatut
	orr r0, r2
	str r0, [r1]
	
Back:
	ldr r1, Return3
	mov pc, r1

Jump:
	mov pc, r2

.align 2

MoveLoc: .word 0x020241EA
Return1: .word 0x0804ED90+1
StoreDamage: .word 0x020241F0
Return3: .word 0x804EE38+1
Bank: .word 0x0202420B
Flags: .word 0x020242AC
SturdyStatut: .word 0x1000000

#insert 01 48 00 47 00 00 xx+1 xx xx 08 1A 4A at 04ED86

Display message:

Spoiler:

.thumb

Start:
push {lr}
ldr r0, Bank
ldrb r1, [r0, #1]
ldr r0, Flags
lsl r1, #2
add r1, r0
ldr r2, [r1]
ldr r0, SturdyStatut
and r0, r2
cmp r0, #0
beq Back
ldr r0, SturdyStatut
bic r2, r0
str r2, [r1]
ldr r0, Bank
ldrb r1, [r0, #1]
mov r0, #0x99
ldr r2, std_message
bl Jump

Back:
ldr r0, SomeLoc
ldr r0, [r0]
cmp r0, #0
bne Back2
ldr r2, Return

Jump:
mov pc, r2

Back2:
pop {r0}
bx r0

.align 2
Flags: .word 0x020242AC
SturdyStatut: .word 0x1000000
Bank: .word 0x0202420B
std_message: .word 0x0803F964+1
Return: .word 0x080482C6+1
SomeLoc: .word 0x02024068

/*00 48 00 47 xx+1 xx xx 08 at 080482BC*/

Notes:

Spoiler:

-I used one of the unused statuts of the 0x020242AC location, if you think it is actually used, please tell me !

 

[Hbreathat]

Does anyone have a link to this tool it is desperately needed and i cant find a link.

 

[kleenexfeu]

UPDATE : 100% working afaik, here is :

Stance Change:

Spoiler:

Emerald :

Spoiler:

Read Me:

Spoiler:

When I say, don't use it if X, it is because it is already covered in X.

The battle scripts come first :

Spoiler:

BladeBS:

Spoiler:

#org 0xSomeLoc
nop3
nop3
setword 0x203E320 0x8PPPPPP
printstring 0x184
waitmessage 0x40
playanimation 0x1 0x20 0x0 //The green bold byte must be an animation similar to transform, see the mega weathers to expand the table
waitanimation
setword 0x203E320 0x8StringBlade
printstring 0x184
waitmessage 0x40
goto 0x8XXXXXX

StringBlade:

FD 0F 00 DD E7 00 E2 E3 EB 00 DD E2 00 DD E8 E7 00 D6 E0 D5 D8 D9 00 DA E3 E6 E1 AB FF FF

ShieldBS:

Spoiler:

#org 0xSomeLoc
nop3
nop3
setword 0x203E320 0x8PPPPPP
printstring 0x184
waitmessage 0x40
playanimation 0x1 0x20 0x0 //The green bold byte must be an animation similar to transform, see the mega weathers to expand the table
waitanimation
setword 0x203E320 0x8StringShield
printstring 0x184
waitmessage 0x40
goto 0x8XXXXXX

StringShield:

FD 0F 00 DD E7 00 E2 E3 EB 00 DD E2 00 DD E8 E7 00 E7 DC DD D9 E0 D8 00 DA E3 E6 E1 AB FF FF

At XX XX XX :

Spoiler:

2E 8B 44 02 02 00 E7 2F 8B 44 02 02 01 2D 8B 44 02 02 6C 40 02 02 01 YY YY YY 08 3C

YY YY YY being the address of the red bold byte.

At PP PP PP :

Spoiler:

FD 0D B4 E7 00 CD E8 D5 E2 D7 D9 00 BD DC D5 E2 DB D9 AB FF

At the start of the check Switch-in or Primal Reversion (don't use it if you're using Mega evolution) :

Spoiler:

push {r0, r1}
ldr r0, FreeAegi
mov r1, #0
strb r1, [r0]

with FreeAegi: .word 0x0203E33C

Main routine : (same hook than mold break, we'll see later for compatibility)

Spoiler:

.thumb

Start:
push {r0-r7}
ldr r0, FreeRam
ldrb r1, [r0]
cmp r1, #0
bne Return
ldr r0, Bank
ldrb r0, [r0]
mov r5, r0
mov r1, #1
and r1, r0
cmp r1, #0
beq Player

AI:
ldr r6, AIParty
mov r1, #3
b CheckAegi

Player:
ldr r6, PlayerParty
mov r1, #0

CheckAegi:
ldr r0, MemLoc
ldr r0, [r0]
add r0, #0x60
ldrb r0, [r0, r1]
mov r1, #2
and r1, r5
cmp r1, #0
beq First
mov r1, #0xF
and r0, r1
b Continue

First:
mov r1, #0xF0
and r0, r1
lsr r0, r0, #4

Continue:
mov r1, r6
mov r2, #0x64
mul r0, r2
add r0, r1
mov r1, #0xB
mov r4, r0
ldr r3, getattr
bl Jump
ldr r2, movedata
ldr r3, CurMove
ldrh r6, [r3]
ldr r1, KingShield
cmp r6, r1
beq AegiForms
lsl r1, r6, #1
add r1, r1, r6
lsl r1, r1, #2
add r1, r1, r2
add r1, #10
ldrb r3, [r1]
cmp r3, #2
bne CheckAegiForms2
b Return

AegiForms:
ldr r1, ABlade
cmp r0, r1
beq DoKing
b Return

CheckAegiForms2:
ldr r1, AShield
cmp r0, r1
beq DoBlade

Return:
pop {r0-r7}
Return2:
ldr r3, =0x8041A6C+1
bl Jump
lsl r0, r0, #0x18
lsr r2, r0, #0x18
cmp r2, #0
beq ReturnPos
ldr r0, =0x8046398+1
mov pc, r0

ReturnPos:
ldr r0, =0x8046072+1
mov pc, r0

DoBlade:
bl BData
ldr r1, ABlade
strh r1, [r5]
ldr r2, var8004
mov r7, r1
b ChangePokeParty

DoKing:
bl BData
ldr r1, AShield
strh r1, [r5]
ldr r2, var8004
mov r7, r1

ChangePokeParty:
strh r1, [r2]
mov r0, r4
mov r1, #0xB
ldr r3, setattr
bl Jump
mov r0, r4
ldr r3, calcstats
bl Jump

ChangeBattleStats:
mov r1, #0x54
mov r0, r4
ldr r3, getattr
bl Jump
strh r0, [r5, #2]
mov r1, #0x55
mov r0, r4
ldr r3, getattr
bl Jump
strh r0, [r5, #4]
mov r1, #0x56
mov r0, r4
ldr r3, getattr
bl Jump
strh r0, [r5, #6]
mov r1, #0x57
mov r0, r4
ldr r3, getattr
bl Jump
strh r0, [r5, #8]
mov r1, #0x58
mov r0, r4
ldr r3, getattr
bl Jump
strh r0, [r5, #0xA]

KeepAttackSafe:
ldr r3, ScriptPusher
bl Jump

ldr r1, ABlade
cmp r7, r1
bne ShieldScript

BladeScript:
ldr r2, BladeBS
b Store

ShieldScript:
ldr r2, ShieldBS

Store:
ldr r1, CurBS
str r2, [r1]
ldr r0, FreeRam
mov r1, #1
strb r1, [r0]
pop {r0-r7}
ldr r3, Test

Jump:
mov pc, r3

Jumpr4:
mov pc, r4

BData:
push {lr}
mov r1, #0x58
mul r5, r1
ldr r1, BattleData
add r5, r1
pop {pc}

.align 2
FreeRam: .word 0x0203E33C /*Freeram loc we need for stance change*/
BladeBS: .word 0x08______
ShieldBS: .word 0x08________
BattleData: .word 0x02024084
KingShield: .word 0x190
ABlade: .word 0x113		/*Index number Aegi blade*/
AShield: .word 0x142	/*Aegi shield*/
MemLoc: .word 0x0202449C
getattr: .word 0x0806A518+1
Bank: .word 0x0202420B
PlayerParty: .word 0x020244EC
AIParty: .word 0x02024744
calcstats: .word 0x08068D0C+1
setattr: .word 0x0806ACAC+1
var8004: .word 0x020275D8 + (0x8004*2)
ScriptPusher: .word 0x0803FAFC+1
CurMove: .word 0x020241EA
CurBS: .word 0x02024214
Test: .word 0x08046398+1

/*00 48 00 47 xx+1 xx xx 08 at 08046064. It should be include in Mold breaker*/

Modification of the "end" command :

Spoiler:

.thumb

ldr r0, FreeRam
mov r1, #0
strb r1, [r0]

ldr r0, End
bx r0

.align2
FreeRam: .word 0x0203E33C
End: .word 0x8______ /*old location of your "end" command or the second routine of the life orb if you're using it

Replace your "end" command with that one

Switch out check :

Spoiler:

.text
.align 2
.thumb
.thumb_func
.global regenerator
 
AbilityBuffer:
	push {r0, r1}
	ldr r0, FreeAegi
	mov r1, #1
	strb r1, [r0]
	pop {r0, r1}
	add r0, r1, r3
	add r0, #0x20
	ldrb r0, [r0]

RegeneratorCheck:
	cmp r0, #[B]0x91 [/B]	/*Index number of your ability Regenerator*/
	beq Regenerator

NaturalCureCheck:
	cmp r0, #0x1E
	bne CheckDelta

NaturalCure:
	ldr r0, .Return
	bx r0

CheckAegi:
	push {r0-r7}
	ldr r0, Bank
	ldrb r0, [r0]
	mov r5, r0
	mov r1, #1
	and r1, r0
	cmp r1, #0
	beq Player

AI:
	ldr r7, AIParty
	mov r1, #3
	b CheckAegis

Player:
	ldr r7, PlayerParty
	mov r1, #0

CheckAegis:
	ldr r0, MemLoc
	ldr r0, [r0]
	add r0, #0x60
	ldrb r0, [r0, r1]
	lsr r0, r0, #0x4
	mov r1, r7
	mov r2, #0x64
	mul r0, r2
	add r0, r1
	mov r1, #0xB
	mov r4, r0
	ldr r3, getattr
	bl Jump
	ldr r1, ABlade
	cmp r0, r1
	beq Revert

BackEnd:
	pop {r0-r7}
	
NoAbility:
	ldr r0, .Return2
	bx r0

Revert:
	ldr r1, AShield
	ldr r2, var8004
	strh r1, [r2]
	mov r0, r4
	mov r1, #0xB
	ldr r3, setattr
	bl Jump
	mov r0, r4
	ldr r3, calcstats
	bl Jump
	b BackEnd

Regenerator:
GetHP:
	add r3, #0x28
	add r3, r1, r3
	mov r1, #0x20
	mul r0, r1
	mov r1, #0x60
	push {r3}
	bl Divide
	pop {r3}
	ldrh r1, [r3]
	add r0, r0, r1
	b CheckHP

CheckDelta:
	cmp r0, #[B]0xC0 [/B]	/*Index number of your ability Delta Stream*/
	beq Delta
	b CheckDesolate

CheckHP:
	ldrh r2, [r3, #0x4]
	cmp r0, r2
	ble StoreHP

MaxHP:
	mov r0, r2

StoreHP:
	strh r0, [r3]

BufferHealthChange:
	ldr r2, .CommandTable
	ldrb r1, [r4]
	ldr r0, .RamLoc
	ldr r0, [r0]
	add r0, r1, r0
	add r0, #0x58
	ldrb r0, [r0]
	lsl r0, r0, #0x2
	add r0, r0, r2
	ldrb r2, [r0]
	mov r0, r1
	mul r0, r6
	add r0, r0, r3
	str r0, [sp]
	mov r0, #0x0

HealthChangeIndex:
	mov r1, #0x2A

Success:
	ldr r3, .Return3
	bx r3

Divide:
	ldr r3, .DivideLoc
	bx r3

CheckDesolate:
	cmp r0, #[B]0xBF [/B]	/*Index number of yout ability Desolate Land*/
	beq Desolate

CheckPrimordial:
	cmp r0, #[B]0xBE[/B] 	/*Index number of yout ability Primordial Sea*/
	beq Primordial
	b CheckAegi

NormalWeather:
	push {lr}
	bl ScriptPusher
	ldr r1, ActiveBS
	ldr r2, ScriptNormalWeather
	str r2, [r1]
	pop {pc}

Delta:
	ldr r2, .FreeRam
	ldrb r0, [r2]
	cmp r0, #[B]0xC0 [/B]	/*Index number of your ability Delta Stream*/
	bne NoAbility
	b ClearWeather
	
Desolate:
	ldr r2, .FreeRam
	ldrb r0, [r2]
	cmp r0, #[B]0xBF[/B] 	/*Index number of your ability Desolate Land*/
	bne NoAbility
	b ClearWeather

Primordial:
	ldr r2, .FreeRam
	ldrb r0, [r2]
	cmp r0, #[B]0xBE [/B]	/*Index number of your ability Primordial Sea*/
	bne NoAbility
	
ClearWeather:
	mov r0, #0x00
	strb r0, [r2]
	ldr r2, .CurrentWeather	
	mov r0, #0x00
	strb r0, [r2]
	b NormalWeather

ScriptPusher:
	ldr r0, ScriptPush
	bx r0

Jump:
	mov pc, r3

.align 2
.CurrentWeather: .word 0x020243CC
.FreeRam: .word 0x0203E331
.Return: .word 0x08055A9F
.Return2: .word 0x08055AD3
.CommandTable: .word 0x08A20000
.RamLoc: .word 0x0202449C
.Return3: .word 0x08055AC7
.DivideLoc: .word 0x082E7541
ActiveBS: .word 0x02024214
ScriptNormalWeather: .word 0x08A1FCF0
ScriptPush: .word 0x0803FAFC+1
ScriptPop: .word 0x0803FB24+1
ABlade: .word 0xFD
AShield: .word 0xFE
MemLoc: .word 0x0202449C
getattr: .word 0x0806A518+1
Bank: .word 0x0202420B
PlayerParty: .word 0x020244EC
AIParty: .word 0x02024744
calcstats: .word 0x08068D0C+1
setattr: .word 0x0806ACAC+1
var8004: .word 0x020275D8 + (0x8004*2)

/*Insert 00 48 00 47 XX XX XX 08 00 00 at 0x55A94*/

This includes the check for the Primal weathers

Revert in the end of the battle (don't use it if you're using mega evolution) :

Spoiler:

.thumb

CheckAegi:
push {r0-r7}
mov r5, #0
ldr r7, PlayerParty
mov r1, #0xB

Loop:
cmp r5, #5
beq BackEnd
mov r4, r5
mov r2, #0x64
mul r4, r2
add r4, r7
mov r1, #0xB
mov r0, r4
ldr r3, getattr
bl Jump
ldr r1, ABlade
cmp r0, r1
beq Revert
add r5, #1
b Loop

BackEnd:
pop {r0-r7}
b ClearRam

Revert:
ldr r1, AShield
ldr r2, var8004
strh r1, [r2]
mov r0, r4
mov r1, #0xB
ldr r3, setattr
bl Jump
mov r0, r4
ldr r3, calcstats
bl Jump
b BackEnd

ClearRam:
ldr r0, =0x803DE41
str r0, [r1]
ldr r0, FreeRam
mov r1, #0
strb r1, [r0]
ldr r1, =0x30061E8
ldr r0, =0x8038421
str r0, [r1]
ldr r0, =0x803DE2A
mov pc, r0

Jump:
mov pc, r3

.align 2
FreeRam: .word 0x0203E331
ABlade: .word 0xFD
AShield: .word 0xFE
MemLoc: .word 0x0202449C
getattr: .word 0x0806A518+1
Bank: .word 0x0202420B
PlayerParty: .word 0x020244EC
AIParty: .word 0x02024744
calcstats: .word 0x08068D0C+1
setattr: .word 0x0806ACAC+1
var8004: .word 0x020275D8 + (0x8004*2)

/*00 48 00 47 xx+1 xx xx 08 at 0803DDE4*/

Solve the brightness of Transform anim:

Spoiler:

.thumb

Start:
ldr r0,CurMov
ldrh r0, [r0]
cmp r0, #0x90
bne NOPALFADE

ldr r3, Thing
mov r0, r6
mov r1, #0x10
mov r2, #6
ldr r4, palfade
bl Jump
ldr r1, Return
mov pc, r1

NOPALFADE:
ldr r0, Return2
mov pc, r0

Jump:
mov pc, r4

.align 2
CurMov: .word 0x020241EA
Thing: .word 0x7FFF
palfade: .word 0x806F98C+1
Return: .word 0x0805E716+1
Return2: .word 0x0805E74A+1

/* C0 46 00 48 00 47 xx+1 xx xx 08 at 0x805E70A*/

Note:

Spoiler:

We can alternatively use the 0x1C anim instead of the transform one

-I used a FreeRam location because otherwise aegislash couldn't transform if froze or confused etc. The FreeRam must be the same in both routine (but different than the life orb
if you're using it).

-See my documentation on the battle script commands for the "nop3"

 

[GOLDstandard]

So I have been trying to learn ASM to help out in this thread, and I've been trying to implement the ability Frisk. I think my code is okay so far but I have gotten to the point where I need to store the opponent's held item name as text and the name is 14 bytes long. How can I store this text and then later print it out?

Spoiler:

.text
.align 2
.thumb
.thumb_func
main:
push (r0-r1)

ldr r0, = target.bank

ldrb r0, [r0]

mov r1, #0x58

mul r0, r1

ldr r1, battle.data

add r0, r1, r0 (Now r0 is pointing specifically to the opponent's data)

add r0, r0, #0x2e (Now r0 is pointing specifically to the opponent's held item)

ldrb r0, [r0] (Now r0 contains opponent's held item)

ldr r0 item.table (Load item table location

mov r1, #0x2C (Size of each item entry in table)

mul r1, r0, r1 (multiplies item index by size of entry)

add r0, r0, r1 (correct location of the exact item name that opponent has)

.align 2

target.bank: .word 02023D6C

battle.data: .word 02023BE4

item.table: .word 0x3DB028