Code: ASM Resource Thread

[linobigatti]

I want to know how it would be to create mysterious gifts

 

[ItsFrickenMe]

Roaming Pokemon!

So if I want to use this in Emerald...is it simply a matter of changing offsets? Would the ASM part be the same?

 

[DizzyEgg]

So if I want to use this in Emerald...is it simply a matter of changing offsets? Would the ASM part be the same?

No, you can't just port things from one game to another. Also, roaming mechanics already exist in Emerald.

 

[Squeetz]

I'm practicing ASM and made a fun little routine for Firered (with some help from Spherical Ice) that counts the amount of Rare Candies the player has used.
If you want to punish your players for cheating by hacking in candies, then this might be of use to you.

Spoiler:

.thumb

main:
ldr r4, variable
mov r0, r4
ldr r2, var_load
bl branch_by_r2
lsl r0, #0x10
lsr r0, #0x10
ldr r1, =(0xFFFF) @if var limit reached, goto end
cmp r0, r1
beq end
mov r1, r0
add r1, #0x1
mov r0, r4
ldr r2, var_set
bl branch_by_r2
end:
ldr r1, tasks
mov r2, r8
lsl r0, r2, #0x2
add r0, r8
lsl r0, #0x3
add r0, r0, r1
ldr r1, sub_81264C8
str r1, [r0]
pop {r3}
mov r8, r3
pop {r4-r7}
pop {r0}
bx r0


branch_by_r2:
bx r2

.align 2
variable: .word 0x4050 @change to variable of choice
var_load: .word 0x0806E568 +1
var_set: .word 0x0806E584 +1
tasks: .word 0x03005090
sub_81264C8: .word 0x081264C8 +1

After inserting this in a word-aligned offset, go to 0x1263F6 and place:

01 49 08 47 C0 46 XX XX XX 08

Where XX is the pointer to the routine, +1.

This routine will automatically add 1 to the variable you chose each time the player uses a rare candy.
How you handle the variable in a script is all up to you!

 

[ItsFrickenMe]

Also, roaming mechanics already exist in Emerald.

Roaming mechanics already exist in Firered too, so why is this ASM needed at all?

 

[ItsFrickenMe]

No, you can't just port things from one game to another. Also, roaming mechanics already exist in Emerald.

Answer me. Now.

 

[DizzyEgg]

Answer me. Now.

Answer what?

 

[ItsFrickenMe]

Answer what?

Why is it relevant that roaming mechanics are already in Emerald, when they're also already in FR?

 

[DizzyEgg]

Why is it relevant that roaming mechanics are already in Emerald, when they're also already in FR?

You're right, you could modify or use the already existing system. That's what I would probably do.
I guess FBI made his own to have better control over it and to make it compatible with his swarming system.

 

[mbcn10ww]

There is a way to call a script with ASM? I want to make something like this:
If a flag is set do something, if not set show a message.

What's the command I use on a routine to make it work?

 

[BLAx501!]

There is a way to call a script with ASM? I want to make something like this:
If a flag is set do something, if not set show a message.

What's the command I use on a routine to make it work?

Well, you could manage that by simply using scripts, but if you insist on using ASM:

[PLAIN]
.text
.align 2
.thumb
.thumb_func

main:
	push {r0-r1, lr}
	ldr r0, .SCRIPT_ADDRESS
	ldr r1, =(0x8069AE4 +1)
	bl linkerTwo
	pop {r0-r1, pc}

linkerTwo:
	bx r1
	
	
.align 2

.SCRIPT_ADDRESS:
	.word 0x8[script_location +1]
[/PLAIN]

FBI made this routine as a reply to something I asked some time ago on the ASM Help Thread. You just have to compile it, modifying the code to add your script location, insert the code on an aligned offset (is it said that way? xDD) and then callasm the routine offset + 1 as usual.

Hope this helps :D

 

[mbcn10ww]

Well, you could manage that by simply using scripts, but if you insist on using ASM:

[PLAIN]
.text
.align 2
.thumb
.thumb_func

main:
	push {r0-r1, lr}
	ldr r0, .SCRIPT_ADDRESS
	ldr r1, =(0x8069AE4 +1)
	bl linkerTwo
	pop {r0-r1, pc}

linkerTwo:
	bx r1
	
	
.align 2

.SCRIPT_ADDRESS:
	.word 0x8[script_location +1]
[/PLAIN]

FBI made this routine as a reply to something I asked some time ago on the ASM Help Thread. You just have to compile it, modifying the code to add your script location, insert the code on an aligned offset (is it said that way? xDD) and then callasm the routine offset + 1 as usual.

Hope this helps :D

I know it can be done only with scripts, but it's needed to edit another routine I have, then it looks better than I wanted, thanks for the reply, I will test it soon as possible and I tell if it worked. ^^

EDIT: Haven't worked, I tested running it by another routine, I tested it by running from the START menu, but haven't worked.

 

[tkim]

Pok?mon Ruby and Sapphire introduced a feature where if you bought 10 or more Pok? Balls in the Mart, you would get a free Premier Ball.
Sadly, this feature was removed in FRLG, and so I tried to port it the best I could.

First, insert this text somewhere using XSE or something and write down the offset of where you inserted it:

I'll throw in a Premier Ball, too.

After that, assemble this routine in a word-aligned offset (ends in 0, 4, 8 or C)
(But first, replace the XXXXXX with the offset of where you inserted the Premier Ball message):

Spoiler:

.thumb

main:
push {r4-r7, lr}
lsl r0, r0, #0x18
lsr r5, r0, #0x18
lsl r0, r5, #2
add r0, r0, r5
lsl r0, r0, #3
ldr r1, taskspriv
add r4, r0, r1
mov r0, #4
ldr r7, rboxid_tilemap_update
bl linkr7
ldrh r0, [r4, #0xA] @ItemID
ldrh r1, [r4, #2] @Amount
mov r6, r1
lsl r6, r6, #0x10
add r6, r0
ldr r7, bag_add_item
bl linkr7
lsl r0, r0, #0x18
lsr r0, r0, #0x18
cmp r0, #1
bne fullbag
ldr r1, hereyouare
ldr r2, sub_809BF0C
mov r0, r5
bl displaymsg
mov r0, r5
mov r0, r6
lsl r0, #0x10
lsr r0, #0x10
cmp r0, #0x4 @Pokeball ID
beq boughtball
next:
ldrh r0, [r4, #0xA]
ldrh r1, [r4, #2]
mov r2, #1
ldr r7, sub_809C09C
bl linkr7
b end

boughtball:
lsr r6, #0x10
mov r1, r6
cmp r1, #0x9 @if player bought over 9 pokeballs, attempt to add premierball
bhi tryadding
b next

tryadding:
mov r0, #0xC @premier ball ID
mov r1, #0x1 @amount of premier balls
ldr r7, bag_add_item
bl linkr7
lsl r0, r0, #0x18
lsr r0, r0, #0x18
cmp r0, #1
bne next @if no room for premier ball, skip to next
ldr r1, message
ldr r2, sub_809BF0C
mov r0, r5
bl displaymsg
b next

fullbag:
ldr r1, bagisfull
ldr r2, sub_809BF98
mov r0, r5
bl displaymsg
end:
pop {r4-r7}
pop {r0}
bx r0

displaymsg:
ldr r7, displayadress
linkr7:
bx r7

.align 2
taskspriv: .word 0x03005098
rboxid_tilemap_update: .word 0x08003FA0 +1
bag_add_item: .word 0x0809A084 +1
sub_809BF98: .word 0x0809BF98 +1
sub_809BF0C: .word 0x0809BF0C +1
sub_809C09C: .word 0x0809C09C +1
displayadress: .word 0x0813F75C +1
bagisfull: .word 0x08416861
hereyouare: .word 0x084167E7
message: .word 0x08XXXXXX

After inserting the routine, navigate to 0x3DF0B4 and put the pointer to it, +1. (If I inserted the routine at 0x725030 I would put 31 50 72 08)

And that's it!

Hi. The routine works well but The hereyouare message doesn't seem to appear if I do receive the PREMIER BALL. Instead it goes straight to the 'I'll throw in a PREMIER BALL, too.' I would like to see both messages appear, just as it does in R/S/E. Thanks for the routine!

 

[tkim]

Pok?mon Ruby and Sapphire introduced a feature where if you bought 10 or more Pok? Balls in the Mart, you would get a free Premier Ball.
Sadly, this feature was removed in FRLG, and so I tried to port it the best I could.

First, insert this text somewhere using XSE or something and write down the offset of where you inserted it:

Here you are!\nI'll throw in a Premier Ball, too.

Not what I meant but whatever.

 

[Squeetz]

Not what I meant but whatever.

Sorry then.
I'm still learning.

 

[tkim]

Sorry then.
I'm still learning.

What I meant was, I would like to see the 'I'll throw in...' message following the hereyouare message. Instead of combining the text, I would like to see two separate messages. (without using \p from XSE either)

Something like this.... (I have no knowledge of ASM)

tryadding:
mov r0, #0xC @premier ball ID
mov r1, #0x1 @amount of premier balls
ldr r7, bag_add_item
bl linkr7
lsl r0, r0, #0x18
lsr r0, r0, #0x18
cmp r0, #1
bne next @if no room for premier ball, skip to next
ldr r1, hereyouare
ldr r2, sub_809BF0C
mov r0, r5
bl displaymsg
[B]ldr r1, message
ldr r2, sub_809BF0C
mov r0, r5
bl displaymsg[/B]
b next

 

[linobigatti]

how can i manipulate the mysterious gift system in FR?

 

[MWisBest]

REUSABLE BALLS IN EMERALD
gracias a familiawerneck
routine with byte changes

Spoiler:

.text
.align 2
.thumb

@ FE3AA - 00 21
@ 56818 - 00 48 00 47 XX+1 XX XX XX

main:
	bl deleteball
	mov r9, r4
	mov r10, r5		@ added because emerald
	pop {r4-r7}
	pop {r0}
	bx r0

deleteball:
	ldr r0, var_800E	@ last_used_item_maybe
	ldrh r0, [r0]
	mov r1, #1
	ldr r2, =(0x80D6AA5)
	bx r2
	
.align 2
var_800E: .word 0x0203CE7C

if y'all want to see specific equivalent addresses:

Spoiler:

[bpre]
2D924		- atkF0 - near end
9A1D8		- bag_remove_item
A1E30		- pokeball + 0x24
0203AD30	- var 800E

[bpee]
56818		- atkF0 - near end
D6AA4		- bag_remove_item
FE3AA		- pokeball + 0x26
0203CE7C	- last_used_item_maybe

have a nice day~

I fixed this so it doesn't delete the fishing rod in the safari zone, among other glitches. It'll now verify that the item is a ball of some kind before it deletes it.

The code looks strange. I'm guessing it could be improved somehow, but it works:

.text
.align 2
.thumb

@ FE3AA - 00 21
@ 56818 - 00 48 00 47 XX+1 XX XX XX

main:
	bl delete_item_if_pokeball
	b finish

deleteball:
	@ r0 already contains last_used_item.
	mov r1, #1
	ldr r2, .bag_remove_item
	bx r2

delete_item_if_pokeball:
	ldr r0, .last_used_item
	ldrh r0, [r0]
	@ checks that the item id is premier ball or lower
	cmp r0, #0xC
	bls deleteball
	@ support for custom pokeballs can be added like so:
	@ cmp r0, #CUSTOM_BALL_ID
	@ beq deleteball

finish:
	mov r9, r4
	mov r10, r5
	pop {r4-r7}
	pop {r0}
	bx r0

.align 2
.last_used_item:
	.word 0x0203CE7C
.bag_remove_item:
	.word 0x080D6AA4|1

EDIT: See here for a version that also makes safari balls reusable.

 

[BluRose]

I fixed this so it doesn't delete the fishing rod in the safari zone, among other glitches. It'll now verify that the item is a ball of some kind before it deletes it.

The code looks strange. I'm guessing it could be improved somehow, but it works:

.text
.align 2
.thumb

@ FE3AA - 00 21
@ 56818 - 00 48 00 47 XX+1 XX XX XX

main:
	bl delete_item_if_pokeball
	bl finish

deleteball:
	@ r0 already contains last_used_item.
	mov r1, #1
	ldr r2, .bag_remove_item
	bx r2

delete_item_if_pokeball:
	ldr r0, .last_used_item
	ldrh r0, [r0]
	@ checks that the item id is premier ball or lower
	cmp r0, #0xC
	bls deleteball
	@ support for custom pokeballs can be added like so:
	@ cmp r0, #CUSTOM_BALL_ID
	@ beq deleteball

finish:
	mov r9, r4
	mov r10, r5
	pop {r4-r7}
	pop {r0}
	bx r0

.align 2
.last_used_item:
	.word 0x0203CE7C
.bag_remove_item:
	.word 0x080D6AA4|1

oh xD
i guess i forgot to edit my post with what i had posted here and here
muchas gracias amigo~
i'll edit my old post and direct to your method as well x3

 

[ghoulslash]

I hope this is the right place to ask, but I was wondering if anyone knows how to edit the following routines so that they don't end the script after completion? For example, use callasm 0x8XXXXXX and then continue with a msgbox, etc..

Naming the player from the overworld: callasm 0x809FC91


And Jambo's rival naming script:

.text
.align 2
.thumb
.thumb_func
.global rivalnamingingame

main:
	push {r0-r4,lr}
	ldr r0, place
	str r0, [sp, #0x4]
	ldr r1, ramlocation
	ldr r1, [r1, #0x0]
	ldr r0, standard
	add r1, r1, r0
	mov r0, #0x4
	mov r2, #0x0
	mov r3, #0x0
	bl place2
	ldr r1, ramlocation
	ldr r1, [r1, #0x0]
	ldr r0, standard
	add r1, r1, r0
	ldrb r0, [r1, #0x0]
	cmp r0, #0xFF
	beq failsafe
	cmp r0, #0x0
	beq failsafe
	
return: 
	pop {r0-r4}
	pop {pc}
	
place2: 
	ldr r4, actualroutine
	bx r4
	
failsafe: 
	ldr r0, rivalname

loop: 
	ldrb r2, [r0, #0x0]
	strb r2, [r1, #0x0]
	cmp r2, #0xFF
	beq return
	add r0, #0x1
	add r1, #0x1
	b loop
	
.align 2
place: .word 0x080568E1
ramlocation: .word 0x03005008
standard: .word 0x00003A4C
actualroutine: .word 0x0809D955
rivalname: .word 0x08FFFFFF                    @default name if left blank