Code: ASM Resource Thread

[ShinyTillDawn]

I know this is an old thread, but I tried porting this to Emerald, and I'm stuck.

Spoiler:

.thumb

.equ location, 0xBAC000
.equ rom, (0x08000000 + 1)

.equ ability_name_length, 0x0D
.equ base_stats_length, 0x1C
.equ pokemon_length, 0x64
.equ req_species, 0x0B
.equ req_species2, 0x41
.equ req_ability, 0x2E
.equ ability1, 0x16
.equ ability2, 0x17
.equ egg_species, 0x19C

.org location, 0xFF
ability_capsule:
push {lr}
lsl r0, r0, #0x18
lsr r0, r0, #0x18
ldr r2, item_function_ptr
ldr r1, =(rom + dp05_abilitycapsule)
str r1, [r2]
ldr r3, item_consume_maybe
bl call_via_r3
pop {r3}
bx r3

dp05_abilitycapsule:
push {r4-r7,lr}
mov r6, r1
lsl r0, r0, #0x18
lsr r5, r0, #0x18

get_selected_pokemon:
ldr r0, brm
ldrb r0, [r0, #9]
mov r1, #pokemon_length
mul r0, r1
ldr r1, party_player
add r4, r0, r1

get_species:
mov r0, r4
mov r1, #req_species2
ldr r3, get_attr
bl call_via_r3

egg_check:
ldrh r1, =egg_species
cmp r0, r1
beq fail

compare_abilities:
ldr r1, base_stats_ptr
ldr r1, [r1]
mov r2, #base_stats_length
mul r0, r2
add r1, r0
ldrb r0, [r1, #ability1]
ldrb r1, [r1, #ability2]
cmp r0, r1
beq fail
cmp r0, #0
beq fail
cmp r1, #0
beq fail
mov r4, #0
b continue

fail:
mov r4, #1

continue:
mov r0, #5
ldr r3, audio_play
bl call_via_r3
cmp r4, #0
beq effect

no_effect:
ldr r0, no_effect_str
mov r1, #1
ldr r3, item_menu_string
bl call_via_r3
mov r0, #2
ldr r3, bgid_mark_for_sync
bl call_via_r3
ldr r1, tasks
lsl r0, r5, #2
add r0, r0, r5
lsl r0, r0, #3
add r0, r0, r1
mov r1, r6
str r1, [r0]
b end

effect:
mov r0, r5
ldr r3, item_use_animation
bl call_via_r3
ldr r1, item_function_ptr
ldr r0, =(rom + abilitycapsule_use)
str r0, [r1]
b end

abilitycapsule_use:
push {r4-r7,lr}
lsl r0, r0, #0x18
lsr r5, r0, #0x18

get_selected_pokemon_again:
ldr r0, brm
ldrb r0, [r0, #9]
mov r1, #pokemon_length
mul r0, r1
ldr r1, party_player
add r4, r0, r1

get_ability_id_again:
mov r0, r4
mov r1, #req_ability
ldr r3, get_attr
bl call_via_r3
lsl r0, r0, #0x18
lsr r0, r0, #0x18

invert_ability_id:
mov r1, #1
eor r0, r1
ldr r2, var_800D
strb r0, [r2]

set_new_ability_id:
mov r0, r4
mov r1, #req_ability
ldr r3, set_attr
bl call_via_r3

set_item_effectiveness:
mov r0, #1
ldr r1, item_effectiveness
strb r0, [r1]

remove_item:
ldr r0, var_800E
ldrh r0, [r0]
mov r1, #1
ldr r3, bag_remove_item
bl call_via_r3

buffer_nickname:
mov r0, r4
ldr r1, fcode_buffer2
ldr r3, buffer_pkmn_nick
bl call_via_r3

buffer_ability_name:
mov r0, r4
ldr r1, fcode_buffer3
ldr r3, =(rom + buffer_ability)
bl call_via_r3

construct_string:
ldr r4, displayed_string
mov r0, r4
ldr r1, =(rom + abilitycapsule_str)
ldr r3, fdecoder
bl call_via_r3

print_string:
mov r0, r4
mov r1, #1
ldr r3, item_menu_string
bl call_via_r3

display_box:
mov r0, #2
ldr r3, bgid_mark_for_sync
bl call_via_r3

add_callback_task:
ldr r1, tasks
mov r2, r5
lsl r0, r2, #2
add r0, r0, r5
lsl r0, r0, #3
add r0, r0, r1
ldr r1, item_menu_callback
str r1, [r0]
b end

buffer_ability:
push {r4-r7,lr}
mov r4, r0
mov r5, r1

get_species_again:
mov r1, #req_species2
ldr r3, get_attr
bl call_via_r3
lsl r0, r0, #0x10
lsr r6, r0, #0x10

get_ability_bit:
mov r0, r4
mov r1, #req_ability
ldr r3, get_attr
bl call_via_r3
lsl r0, r0, #0x18
lsr r1, r0, #0x18

get_ability_id:
mov r0, r6
mov r2, #base_stats_length
mul r0, r2
ldr r2, base_stats_ptr
ldr r2, [r2]
add r2, r0
add r2, #ability1
ldrb r0, [r2, r1]

get_ability_name_string:
mov r1, #ability_name_length
mul r0, r1
ldr r1, ability_names_ptr
ldr r1, [r1]
add r1, r0
mov r0, r5
ldr r3, strcpy_xFF_terminated
bl call_via_r3

end:
pop {r4-r7}
pop {r3}

call_via_r3:
bx r3

abilitycapsule_str:
.byte 0x00
.byte 0xFD, 0x02, 0xB4, 0xE7, 0x00, 0xBB, 0xD6, 0xDD, 0xE0, 0xDD, 0xE8, 0xED, 0xFE, 0xD7, 0xDC, 0xD5, 0xE2, 0xDB, 0xD9, 0xD8, 0x00, 0xE8, 0xE3, 0x00, 0xFD, 0x03, 0xAB, 0xFC, 0x09, 0xFF
@ "[PKMN]'s Ability[NEWLINE]changed to [ABILITY]![WAITKEYPRESS]"

.align 2
fcode_buffer2: .word 0x02021CC4
fcode_buffer3: .word 0x02021DC4
displayed_string: .word 0x02021FC4
party_player: .word 0x020244EC
var_800D: .word 0x020375F0
var_800E: .word 0x0203CE7C
brm: .word 0x0203CEC8
item_effectiveness: .word 0x0203CEE8

tasks: .word 0x03005E00
item_function_ptr: .word 0x03006328

base_stats_ptr: .word 0x080001BC
ability_names_ptr: .word 0x080001C0
strcpy_xFF_terminated: .word 0x08008BA0|1
fdecoder: .word 0x08008EE0|1
get_attr: .word 0x0806A518|1
set_attr: .word 0x0806ACAC|1
audio_play: .word 0x080A37A4|1
bag_remove_item: .word 0x080D6AA4|1
(I stopped here.)
item_consume_maybe: .word 0x080A16D0|1
bgid_mark_for_sync: .word 0x080F67A4|1
buffer_pkmn_nick: .word 0x081202E0|1
item_menu_string: .word 0x081202F8|1
item_use_animation: .word 0x08124DC0|1
item_menu_callback: .word 0x081255BC|1
no_effect_str: .word 0x084169DC @ "It won't have any effect."

I can't find the equivalent of "sub_80A16D0" in Emerald.

 

[RuFF]

Button detection in scripts

How to insert:

First compile and insert into free space, the following routine

Spoiler:

.text
.align 2
.thumb
.thumb_func

main:
	ldr r0, =(0x30030F0)
	ldrh r1, [r0, #0x2E] @byte in super state for keypress
	cmp r1, #0x0
	beq cont
	ldr r0, =(0x20370B8) @var 0x8000 location
	strh r1, [r0]
	ldr r4, =(0x806B922 +1)
	bx r4

cont:
	mov r0, #0x1
	and r0, r0, r1
	cmp r0, #0x0
	beq section
	ldr r1, =(0x806B922 +1)
	bx r1
	
section:
	ldr r0, =(0x806B8A6 +1)
	bx r0
	
.align 2

Now navigate to 0x6B89A and do the following byte changes:

 00 00 00 48 00 47 XX XX XX 08

Where XX XX XX is the pointer to wherever you inserted this routine +1

Hello, I trying to convert this to Ruby. How will I find the corresponding offsets mentioned above?

(0x806B922 +1)
(0x806B8A6 +1)

0x6B89A

I already found the corresponding one for (0x30030F0).

 

[Blah]

Hello, I trying to convert this to Ruby. How will I find the corresponding offsets mentioned above?

(0x806B922 +1)
(0x806B8A6 +1)

0x6B89A

I already found the corresponding one for (0x30030F0).

Don't follow this method, it's a poor implementation. Instead, create a task which listens to a key press and use callasm to run it.

 

[RuFF]

Don't follow this method, it's a poor implementation. Instead, create a task which listens to a key press and use callasm to run it.

How do you integrate wait key in asm? I tried looping until a button is pressed but I think I got stuck in an infinite loop.

Spoiler:

.text
.align 2
.thumb
.thumb_func

main:
push {r0-r2, lr}
ldr r0, =(0x3001770)
ldrh r1, [r0, #0x2E] @byte in super state for keypress
cmp r1, #0x0
beq cont
ldr r0, =(0x202E8C4) @var 0x8000 location
strh r1, [r0]
pop {r0-r1, PC}

cont:
in
ldr r0, =(0x3001770)
ldrh r1, [r0, #0x2E] @byte in super state for keypress
cmp r1, #0x0
beq cont
ldr r0, =(0x202E8C4) @var 0x8000 location
strh r1, [r0]
pop {r0-r2, PC}

.align 2

I also tried using waitbutton command from PKSV then callasm this routine but It just sets the var to 0. Also waitbutton only accepts "A" and "B"

Spoiler:

.text
.align 2
.thumb
.thumb_func

main:
push {r0-r2, lr}
ldr r0, =(0x3001770)
ldrh r1, [r0, #0x2E] @byte in super state for keypress
ldr r0, =(0x202E8C4) @var 0x8000 location
strh r1, [r0]
pop {r0-r1, PC}

.align 2

 

[Blah]

How do you integrate wait key in asm? I tried looping until a button is pressed but I think I got stuck in an infinite loop.

Spoiler:

.text
.align 2
.thumb
.thumb_func

main:
push {r0-r2, lr}
ldr r0, =(0x3001770)
ldrh r1, [r0, #0x2E] @byte in super state for keypress
cmp r1, #0x0
beq cont
ldr r0, =(0x202E8C4) @var 0x8000 location
strh r1, [r0]
pop {r0-r1, PC}

cont:
in
ldr r0, =(0x3001770)
ldrh r1, [r0, #0x2E] @byte in super state for keypress
cmp r1, #0x0
beq cont
ldr r0, =(0x202E8C4) @var 0x8000 location
strh r1, [r0]
pop {r0-r2, PC}

.align 2

I also tried using waitbutton command from PKSV then callasm this routine but It just sets the var to 0. Also waitbutton only accepts "A" and "B"

Spoiler:

.text
.align 2
.thumb
.thumb_func

main:
push {r0-r2, lr}
ldr r0, =(0x3001770)
ldrh r1, [r0, #0x2E] @byte in super state for keypress
ldr r0, =(0x202E8C4) @var 0x8000 location
strh r1, [r0]
pop {r0-r1, PC}

.align 2

You need two routines to pull this off. The first routine would pause script execution, and start a key listener task. Then the key listener task would check for a new key press, and destroy the task/resume the script

 

[Pokémon Hack Lab]

Battle Modes!

In this post, we will be implementing a base skeleton structure to allow the hacker to add in their own battle modes, I'll also be including some example "add-ons" so you know how to do it yourself. The post currently contains possibilities for the hacker to implement routines which run once at the end of each turn (perfect for tournament clauses) and a routine which runs once every move is chosen and used (perfect for trainer sliding *hint hint danillS*).

I'm calling it a skeleton, but it's actually more like a hook into a routine which runs your routines!
It works like this:
1) Hook from original to routine which runs routines
2) If flag is set, routine runs the routines it's told to run
3) Returns back to hooking location

So all you really need to do to add new battle modes, is add to the list of routines we call (Which is simple, I'll explain in detail later). I should also mention that these routines are called in ALL types of battle including wild, trainer, and scripted. Happy hacking!

Battle Routine By Move:

This routine will run, on average four times per turn. Once you select your move, once you use your move, once the opponents uses their move and at the end of the aftermath. This makes the routine a perfect branching place for an Oak-tutorial like battle.

How to insert:
Look at the routine below. The last line .table has an incomplete pointer. It says 0x[pointer to routine table]. Find enough free space (takes 4 byte per routine) in your ROM and set the pointer for .table to that. You do not add +1 to the pointer, nor is it in reverse hex. Once you've fixed the pointer, compile the routine into free space. The last pointer in the routine NEEDS to be 00 00 00 00.

Spoiler:

.text
.align 2
.thumb
.thumb_func

main:
	push {r0-r4}
	mov r0, #0xBF @flag to check divided by 4
	lsl r0, r0, #0x2
	ldr r1, =(0x806E6D0 +1)
	bl linker
	cmp r0, #0x0
	beq noCrash
	ldr r4, .table

loop:
	ldr r1, [r4]
	cmp r1, #0x0 @check table entry is null
	beq noCrash
	bl linker @call table routine
	add r4, r4, #0x4 @get next table routine
	b loop
	

noCrash:
	pop {r0-r4}
	lsl r0, r0, #0x18
	lsr r0, r0, #0x18
	mov r10, r0
	lsl r1, r1, #0x10
	lsr r1, r1, #0x10
	ldr r2, =(0x2022874)
	ldr r0, =(0x800E2EA +1)
	bx r0

linker:
	bx r1
	
	
.align 2

.table:
	.word 0x[pointer to routine table] @THIS IS FREE SPACE IF IT'S YOUR FIRST TIME USING THIS ROUTINE

Navigate to

Now navigate to 0xE2E0 and insert the byte changes:

00 4D 28 47 XX XX XX 08

Where XX XX XX is the reverse hex pointer to your routine +1.



Usage:
The routine is toggled by flag 0x2FC. Activate the flag to toggle routines called by this routine. To add routines into the list of called routines, navigate to the pointer of freespace you made .table point to. Insert into that table pointers in reverse hex +1 to wherever you compiled the addon routines make sure they have the 0x8 prefix. The structure of the table should be: [routine pointer in reverse hex +1 (4 bytes)] for each pointer in the table. I.e if I put the addon at 0x740000, the pointer would read 01 00 74 08.

Addons for Battle by move:

Prevent loss (white out):

Spoiler:

.text
.align 2
.thumb
.thumb_func

main:	
	push {r0-r1, lr}
	ldr r0, =(0x2023E8A)
	ldrb r1, [r0]
	cmp r1, #0x1
	bhi setZero
	b end

setZero:
	cmp r1, #0x5
	beq end
	mov r1, #0x0
	strb r1, [r0]

end:
	pop {r0-r1, pc}

Battle by turn:

This routine will run all of it's referenced routines at the end of the turn (right before the turn counter in incremented.

How to insert:
Look at the routine below. The last line .table has an incomplete pointer. It says 0x[pointer to routine table]. Find enough free space (takes 4 byte per routine) in your ROM and set the pointer for .table to that. You do not add +1 to the pointer, nor is it in reverse hex. Once you've fixed the pointer, compile the routine into free space.
Last entry in the table needs to be 00 00 00 00.

Credits to daniilS for helping with optimization.

Spoiler:

.text
.align 2
.thumb
.thumb_func
 
main:
        @check flag 0x2F8 to toggle routines (0xBE*4 = 0x2F8)
        mov r0, #0xBE
        lsl r0, r0, #0x2
        ldr r2, =(0x806E6D0 +1)
        bl linker
        cmp r0, #0x0
        beq skip
        ldr r4, .table
 
loop:
        ldr r2, [r4]
        cmp r2, #0x00
        beq skip
        bl linker @call table routine
        add r4, #0x4 @get next table routine
        b loop
       
skip:
        ldr r1, = 0x3004F90
        ldrb r0, [r1, #0x13]
        cmp r0, #0xFE
        bhi replacer
        add r0, #0x1
        strb r0, [r1, #0x13]
 
replacer:
        ldr r2, = (0x8013CBC + 1)
 
linker:
        bx r2
 
.align 2
 
.table:
        .word 0x[pointer to Routine table]

Now navigate to 0x13CB0 and insert the following byte changes:

00 48 00 47 XX XX XX 08

Usage:
The routine is toggled by flag 0x2F8. Activate the flag to toggle routines called by this routine. To add routines into the list of called routines, navigate to the pointer of freespace you made .table point to. Insert into that table pointers in reverse hex +1 to wherever you compiled the addon routines make sure they have the 0x8 prefix. The structure of the table should be: [routine pointer in reverse hex +1 (4 bytes)] for each pointer in the table. I.e if I put the addon at 0x740000, the pointer would read 01 00 74 08.

Battle by turn addons:

Sleeping clause:

Spoiler:

.text
.align 2
.thumb
.thumb_func

main:
	push {r0-r3,lr}
	mov r2, #0x0 @pokemon counter
	mov r3, #0x0 @sleeping counter

loop:
	cmp r2, #0x5
	beq validateBattle
	ldr r0, =(0x202402C + 0x50)
	mov r1, #0x64
	mul r1, r1, r2
	add r0, r0, r1
	ldrb r0, [r0]
	lsl r0, r0, #0x5
	lsr r0, r0, #0x5
	cmp r0, #0x0 @check sleeping
	beq next
	add r3, r3, #0x1
next:
	add r2, r2, #0x1
	b loop

validateBattle:
	cmp r3, #0x1 @check amount sleeping <=1
	ble end
	ldr r0, =(0x2023E8A)
	mov r1, #0x5
	strb r1, [r0]	

end:
	pop {r0-r3, pc}
	
	
.align 2

Battle end by turn:

Spoiler:

.text
.align 2
.thumb
.thumb_func

main:
	push {r0-r1,lr}
	ldr r0, =(0x20370CC)
	ldrb r0, [r0]
	ldr r1, =(0x3994FA3)
	ldrb r1, [r1]
	cmp r1, r0
	bne end
	ldr r0, =(0x2023E8A)
	mov r1, #0x5
	strb r1, [r0]	
end:
	pop {r0-r1, pc}
	
	
.align 2

Sleep Clause it works?

I correctly installed Delete Fainted Pokémon and it worked, but Sleep Clause did not :[

013CB0: 00 48 00 47 01 00 80 08
800000: BE 20 80 00 0B 4A 00 F0 11 F8 00 28 07 D0 08 4C 22 68 00 2A 03 D0 00 F0 09 F8 04 34 F8 E7 06 49 C8 7C FE 28 01 D8 01 30 C8 74 04 4A 10 47 C0 46 00 00 81 08 D1 E6 06 08 90 4F 00 03 BD 3C 01 08
810000: 01 00 82 08 00 00 00 00
820000: 0F B5 00 22 00 23 05 2A 0B D0 09 48 64 21 51 43 40 18 00 78 40 01 40 09 00 28 00 D0 01 33 01 32 F1 E7 01 2B 02 DD 03 48 05 21 01 70 0F BD C0 46 7C 40 02 02 8A 3E 02 02

 

[Kaito11073]

How do you input these codes?

 

[sylinuser]

I don't really feel like doing a challenge cup. Also some of your features can be achieved using the already created party checker routine. Species Clause, Evasion Clause, OHKO clause can all be done by it. Maybe if I feel like it in future :P

Custom nicknames for enemy Pokemon

So this works for any wild or trainer Pokemon. It basically allows you to nickname a Pokemon on the enemy team prior to battling. For those special trainers or maybe special Pokemon :)

How to insert:

There's actually a little bit of work before you can compile and insert routines. First look at the routine below. You'll notice at the last line there is a Pointer to something that I call "TABLE". This table is going to be a table full of nickname with each entry 0xB bytes long. Find some space in your ROM which you will use for this table and correct the offset accordingly.

Spoiler:

.text
.align 2
.thumb
.thumb_func

main:
	mov r0, #0x9C
	lsl r0, #0x2
	push {r1-r7}
    	ldr r2, =(0x806E6D0 +1)
	bl linker
	pop {r1-r7}
	cmp r0, #0x0
	beq old

nick:
	ldr r0, =(0x202402C)
	sub r0, r7, r0
	mov r1, #0x64
	ldr r2, =(0x81E4018 +1) @slot number
	bl linker
	mov r3, r0
	ldr r1, = (0x20370B8) @table entry position
	ldrb r1, [r1]
	mov r2, #0xB
	mul r1, r1, r2
	ldr r0, .TABLE
	add r0, r0, r1 @table start position
	mul r3, r3, r2
	add r0, r0, r3 @name to give
	mov r1, r7
	add r1, r1, #0x8 @nickname location
	mov r4, #0x0

nameLoop:
	cmp r4, #0xB
	beq end
	ldrb r3, [r0]
	strb r3, [r1]
	add r1, r1, #0x1
	add r0, r0, #0x1
	add r4, r4, #0x1
	b nameLoop

end:
	ldr r0, =(0x8040ADA +1)
	bx r0

old:
	mov r2, #0x0
	mov r3, r7
	add r3, #0x8

oldLoop:
	add r0, r3, r2
	add r1, r4, r2
	ldrb r1, [r1]
	strb r1, [r0]
	add r2, r2, #0x1
	cmp r2, #0x9
	ble oldLoop
	ldr r0, =(0x8040ADA +1)
	bx r0

linker:
	bx r2

.align 2

[B].TABLE:
	.word 0x8760000[/B]

Once you've made the modification to the pointer, compile and insert the routine into freespace.
Next navigate to offset 0x406DC and insert the following:

00 48 00 47 XX XX XX 08

Where XX is the pointer to the above routine in reverse hex +1.

Usage:
First navigate to your table which will contain the nicknames (it should be the offset in the routine you changed). You need to keep the table formatted like this [10 bytes (Name in hex)] [1 byte (0xFF)]. Insert as many names as you'd like.

Next, to activate the routine, you must setflag 0x270 AND you need to setvar 0x8000 0x[table starting index].
If you're battling a trainer with 6 Pokemon, the nicknames will be determined from the table. It will read six nicknames starting from the starting index given by variable 0x8000. There is no need to callasm. :)

I want to use this on my rom hack,
Can you help me?

i'm not really good at scripting

 

[DjTarma]

[FR] EV-reducing Berries

Find 0x49C bytes of free space at a word-aligned address, and take note of it.
Set the EV-reducing berries' Type to Type 1 ("Out of battle").
Set the items' Field script pointers to the address you noted, plus 1.
Set the items' Battle script pointer to 0xA2239.
Assemble the following routine, changing 0xXXXXXX to the address you noted (not plus 1).
Open the generated .bin file, navigate to the location address, and select 0x49C bytes.
Copy the bytes and paste them in your ROM, at the same address.
...
This will introduce the Pomeg Glitch; see tkim's post here on how to fix it.

I implemented this routine in my project and it is working "as it should". 😔
There is a huge problem: If I use a Kelpsy Berry, it will reduce my Pokémon's Attack EVs without error, but if I use a Protein, the item is not consumed. 😡
If I accidentally use it on a level 100 Pokemon, I can no longer increase the EVs.

How can this be fixed?

 

[Yave Yu]

I wonder is there has a code implements BW item use system...
If selected item (such as Potion) has many, on map use it to a Pokemon (or it won't affect) won't back to bag automaticly unless that item is last one.

 

[sylinuser]

I wonder is there has a code implements BW item use system...
If selected item (such as Potion) has many, on map use it to a Pokemon (or it won't affect) won't back to bag automaticly unless that item is last one.

yes there is.
i think its on HMA discord. try join that and you will see

 

[DjTarma]

Summary Screen Wrap-Around​

First of all, I would like to thank Zeturic for creating the original routine for this. My routine is different from theirs, and I have extended it a bit, which is why I am posting this here.

Anyway, this patch modifies the summary screens in both the Party Menu and in the PC so that if you are on the first Pokemon and you go upwards, you will loop around to the last Pokemon (and vice versa). Ordinarily, in this circumstance, nothing would happen.

(Download)

This folder contains the patch itself, and the two routines that comprise it. There were two functions which were replaced, and both of the new functions were shorter than the originals (hence why this could be turned into a patch).

This patch will skip over Eggs when scrolling while in the Party or PC, but if you want to see the Egg's summary (to see how long it will take to hatch), you can select their summary individually.

If you have more than one Egg in the party and move up or down (if the next slot is an egg), the game freezes.

 

[Marinebeast]

Here's a quick question!

I used the Ability Capsule script by Spherical Ice to create an Ability Capsule item, and it worked great-- but I'm making this for a romhack where almost all of the Pokemon have two abilities, so making an infinite-use key item that runs this script for a Pokemon would be preferable.

What edits would I need to make to the script (or post-compiled hexadecimal) in order to change this? I would imagine it's similar to the scripts that alter TMs or make other reusable key items, but at the moment I'm not confident with ASM script or trying to find the specific hex bytes that need to be altered.

Thanks so much in advance. This thread's incredibly helpful and I appreciate all the excellent content being shared here!

 

[AkameTheBulbasaur]

If you have more than one Egg in the party and move up or down (if the next slot is an egg), the game freezes.

Great catch!

I fixed the problem now. I updated the download. All you need to do is reapply the patch and it should be fixed now.

Turns out that the Party routine was not updating the counter correctly when there was an Egg, creating an infinite loop which soft-locked the game.

Not anymore though! I tried it with two Eggs (it should work for more than two as well, hopefully).

Here's a quick question!

I used the Ability Capsule script by Spherical Ice to create an Ability Capsule item, and it worked great-- but I'm making this for a romhack where almost all of the Pokemon have two abilities, so making an infinite-use key item that runs this script for a Pokemon would be preferable.

What edits would I need to make to the script (or post-compiled hexadecimal) in order to change this? I would imagine it's similar to the scripts that alter TMs or make other reusable key items, but at the moment I'm not confident with ASM script or trying to find the specific hex bytes that need to be altered.

Thanks so much in advance. This thread's incredibly helpful and I appreciate all the excellent content being shared here!

As it turns out, you are in luck. I did this exact same thing in my game. The way you do it is very simple.

First, you write out an NPC script which has the Item's effect. You will want to write it in such a way that it does not remove the item after the script is over. Remember where you inserted it.

Next, you can use this routine by Darthatron to allow an item to run a script when you "use" it. Replace the "08AABBCC" with the address of your NPC Script (do not add one). Also, make sure to put the address where you will insert this routine after the ".equ ROM, 0x08" part (so if you put it at 0xAABBCC you would have ".equ ROM, 0x08AABBCC").

Spoiler:

.text
.align 2
.thumb
.thumb_func
.global RunScriptFromItem

/*
---------------------------------------------------------
This routine was made originally by Darthatron with mild
syntax edits from me.

The purpose of this routine is to allow the user to run
an NPC Script when using an Item from the bag.

First, we do some sort of setting up. We put the address
of the second half of the routine into 0x02039998. Then
we BL to 0x080A103C. This somehow allows us to eventually
run the second part of the routine.

The second part of the routine allows us to run the NPC
script itself. We give it the address, and then it runs
the script.
---------------------------------------------------------
*/

.equ ROM, 0x8

SetUp:
push {r4, lr}
mov r4, r0
ldr r0, .SecondPart
ldr r1, .CodeToRun
str r0, [r1]
mov r0, r4
bl CallFunction
pop {r4}
pop {r0}
bx r0

Main:
push {r4, lr}
mov r4, r0
ldr r0, .ScriptToCall
bl CallNPCScript
mov r0, r4
bl CallRoutine
pop {r4}
pop {r0}
bx r0

CallFunction:
ldr r1, .Function
bx r1

CallNPCScript:
ldr r1, .CallNPCScript
bx r1

CallRoutine:
ldr r1, .Routine
bx r1

.align 2
.CallNPCScript: .word 0x08069AE5
.CodeToRun: .word 0x02039998
.Function: .word 0x080A103D
.SecondPart: .word Main+ROM+1
.Routine: .word 0x08077509
.ScriptToCall: .word 0x08AABBCC

Finally, in the Item Editor, I believe there is an option to allow the item to run a routine when used. You set the address of that routine to the address of Darthatron's routine. Then you only need to set the Item to be a Key Item in the editor, and you should be done.

 

[DjTarma]

Great catch!

I fixed the problem now. I updated the download. All you need to do is reapply the patch and it should be fixed now.

Turns out that the Party routine was not updating the counter correctly when there was an Egg, creating an infinite loop which soft-locked the game.

Not anymore though! I tried it with two Eggs (it should work for more than two as well, hopefully).

Thanks!!!

 

[Marinebeast]

Thank you Akame for the pointers! That pointer script works great and should help a lot in the future when I can't run something directly from an item.

I did notice, previously in the thread, there was mention of Everstone nature-passing functionality being ported to FireRed, but I'm not sure if it was posted.
Was this ever done/is there a script for it anywhere? I know there's the CFRU standalone item pack out there that has the Everstone update in it, but it writes to an offset that's unfortunately already very full in the hack I'm shining up.

 

[DjTarma]

Nature Changing​

Before I begin, I should mention that this only works for FireRed at the moment. This is because it uses the Lustre stat, which in FireRed is unused but in Emerald is not. If you can find another stat to use, (or you don't have contests in your Emerald hack), then you can use this.

I'm having trouble inserting the Synchronize upgrade element.
The method of how this is inserted is very poorly explained. Could you make a step-by-step video of how to implement the whole context?
My game freezes if I have the first Pokémon with Synchronize.

 

[AkameTheBulbasaur]

I'm having trouble inserting the Synchronize upgrade element.
The method of how this is inserted is very poorly explained. Could you make a step-by-step video of how to implement the whole context?
My game freezes if I have the first Pokémon with Synchronize.

The manual assumes that the reader is familiar with how to insert THUMB Assembly routines, so my apologies if it was unclear for you. It might have also been unclear how to use the ".equ ROM" statement at the top.

The purpose of it is to be a dynamic address, which is helpful as the Synchronise routine is actually two routines baked into one. So, let's say you put the combined routine at 0xAABBCC. Setting "equ ROM, 0x08AABBCC" creates a keyword named "ROM", which is equal to 0x08AABBCC. So, when the routine calls the GetNature function at "GetNatureFunction+ROM", it will be able to format the pointer correctly.

Anyway, using it is very simple and saves you time in the long run since you don't have to insert as many routines. I thought it has a comment saying to put the address of the routine you were inserting by it, but I realised that the version that was up here was missing that. I added that in now, but I'll explain what to do here in case you are still confused.

Here is what you should do:
1. Find some free space in the ROM where the routine will go and write it down. The routine should have the number of bytes it uses written at the top (I realised the Synchronise one did not, so I updated it to - it uses 0x138 bytes).

2. Put the offset where the routine will go after the "ROM 0x8" piece at the top. If you are going to put the routine at 0xAABBCC, then you should have ".equ ROM, 0x08AABBCC".

3. Insert the routine at the offset you used in the ".equ ROM" line. They need to match always (so if you move the routine after inserting it, that will break it).

4. Put in the byte changes which are indicated at the top of the routine. Remember that XX XX XX 08 is the offset of the routine, plus one, in reverse. So, if you had 0xAABBCC it would become CD BB AA 08.

PM me if you are still having trouble and I'd be happy to help you.

 

[robertussan]

Sitrus Berry Update:

Spoiler:

Restore 25% of maximum HP.

FireRed:-

Spoiler:

Item Use Effect:

.text
.align 2
.thumb
.thumb_func
.global sitrusoverworld

Main:

  ldr r1, [sp, #0xC]   @ItemIndex
  cmp r1, #0x8E @Sirtus
  bne Skip
  lsr r0, r0, #0x1   @HP to Restore

Skip:  
  cmp r0, #0x0
  bne Exit
  mov r0, #0x1

Exit:
  ldr r1, =0x8041CA4+1
  bx r1

@@At x2528B8: FE 00
@@At x41C94: 00 49 08 47 XX+1 XX XX 08

Hold Item Effect:

.text
.align 2
.thumb
.thumb_func
.global sitruspinch

Main:

  ldrh r1, [r2, #0x2E]   @ItemIndex
  ldrh r3, [r2, #0x28]
  mov r5, r9
  cmp r1, #0x8E @Sitrus
  bne NotZero
  ldrh r0, [r2, #0x2C]
  lsr r5, r0, #0x2   @HP to Restore
  cmp r5, #0x0
  bne NotZero
  mov r5, #0x1

NotZero:
  str r5, [r4]
  ldr r1, =0x801BF08+1
  bx r1

@At x1BF00: 00 49 08 47 XX+1 XX XX 08

Emerald:-

Spoiler:

Item Use Effect:

.text
.align 2
.thumb
.thumb_func
.global sitrusoverworld

Main:

  ldr r1, [sp, #0xC]   @ItemIndex
  cmp r1, #0x8E @Sirtus
  bne Skip
  lsr r0, r0, #0x1   @HP to Restore

Skip:  
  cmp r0, #0x0
  bne Exit
  mov r0, #0x1

Exit:
  ldr r1, =0x806C610+1
  bx r1

@@At x31E54C: FE 00
@@At x6C600: 00 49 08 47 XX+1 XX XX 08

Hold Item Effect:

.text
.align 2
.thumb
.thumb_func
.global sitruspinch

Main:

  ldrh r1, [r2, #0x2E]   @ItemIndex
  ldrh r3, [r2, #0x28]
  mov r5, r9
  cmp r1, #0x8E @Sitrus
  bne NotZero
  ldrh r0, [r2, #0x2C]
  lsr r5, r0, #0x2   @HP to Restore
  cmp r5, #0x0
  bne NotZero
  mov r5, #0x1

NotZero:
  str r5, [r4]
  ldr r1, =0x804478C+1
  bx r1

@At x44784: 00 49 08 47 XX+1 XX XX 08

Berry Activation Update:

Spoiler:

Activates consumable berries as soon as possible (end move or a certain multi-hit strike) after the required consumption condition is met, consistent to later generations, rather than activating on End Turn.

Emerald:-

Spoiler:

.text
.align 2
.thumb
.thumb_func
.global endmoveberries

.include "T:/asdS/thumb/bsmacros.asm"
@@https://www.pokecommunity.com/showpost.php?p=9062722&postcount=332
@@ Paste all the content from the 'BS Macro & Defines' Spoiler in this link to a new blank ASM file and include its path.

.equ RomAreaOffset, 0x8000000
.equ BerryLoc, 0xE10000
.equ ContraryID, 0x7F
.equ GluttonyID, 0x53
.equ BattleData, 0x2024084
.equ Sitrus, 0x8E
.equ Return, 0x08045674+1
.equ Return2, 0x0804582A+1
.equ ItemBuffer, 0x2024208
.equ ScriptPointer, 0x2024214
.equ ScriptPusher, 0x803FAFC+1
.equ MiscBufferCountersArea, 0x2024474
.equ Bank_F, 0x202420F
.equ ActiveBank, 0x2024064
.equ Damage, 0x20241F0
.equ NoOfBattlers, 0x202406C
.equ UserBank, 0x202420B
.equ TargetPartner, 0x202420E
.equ BattleOutcome, 0x2022F58
.equ Divider, 0x82e7540+1
.equ ConfuseAccToNature, 0x806e880+1
.equ RNG, 0x806F5CC+1
.equ DivMod, 0x82E7Be0+1
.equ OranHealBSLoc, OranHealBS+RomAreaOffset
.equ HealAndConfuseBSLoc, HealAndConfuseBS+RomAreaOffset
.equ FocusBerryBSLoc, FocusBerryBS+RomAreaOffset
.equ StatRaiseBSLoc, StatRaiseBS+RomAreaOffset 

.org 0x45280
    mov r7, #0x0
    ldr r0, =NoOfBattlers
    ldrb r0, [r0]
    cmp r7, r0
    bcc CheckBankHP
    b 0x4582A

CheckBankHP:
    ldr r1, =BattleData
    mov r8, r1
    mov r0, #0x58
    mul r0, r7
    add r0, r0, r1
    ldrh r2, [r0, #0x28]
    cmp r2, #0x0
    bne HasHP
    b 0x45674

HasHP:
    ldr r4, =ItemBuffer
    ldrh r0, [r0, #0x2E] 
    strh r0, [r4]
    bl 0xD74DC
    lsl r0, r0, #0x18
    lsr r5, r0, #0x18
    sub r0, r5, #1
    cmp r0, #0x1B
    bls LoadBerryTable
    b 0x45674

LoadBerryTable:
    lsl r0, r0, #2
    ldr r1, BerryTableLoc
    add r0, r0, r1
    ldr r3, [r0]
    ldrh r0, [r4]
    bl 0xD7500
    lsl r0, r0, #0x18
    lsr r0, r0, #0x18
    mov r9, r0
    mov pc, r3
    
.align 2
BerryTableLoc: .word BerryLoc+RomAreaOffset

.align 2
.pool


.org BerryLoc
.word HPRestoreBerry+RomAreaOffset @Oran, Sitrus, Berry Juice 
.word 0x8045354  @Cheri Berry
.word 0x8045444  @Chesto Berry
.word 0x8045390  @Pecha Berry
.word 0x80453CC  @Rawst Berry
.word 0x8045408  @Aspear Berry
.word 0x8045674       @Leppa Berry
.word 0x804548C  @Persim Berry
.word 0x8045520  @Lum Berry
.word HPRestoreConfuseBerry+RomAreaOffset @Figy
.word HPRestoreConfuseBerry+RomAreaOffset @Wiki
.word HPRestoreConfuseBerry+RomAreaOffset @Mago
.word HPRestoreConfuseBerry+RomAreaOffset @Aguav
.word HPRestoreConfuseBerry+RomAreaOffset @Iapapa
.word StatRaiseBerry+RomAreaOffset @Leichi
.word StatRaiseBerry+RomAreaOffset @Ganlon
.word StatRaiseBerry+RomAreaOffset @Salac
.word StatRaiseBerry+RomAreaOffset @Petaya
.word StatRaiseBerry+RomAreaOffset @Apicot
.word LansatBerry+RomAreaOffset @Lansat
.word StarfBerry+RomAreaOffset @Starf
.word 0x8045674
.word 0x8045614 @White Herb
.word 0x8045674
.word 0x8045674
.word 0x8045674
.word 0x8045674
.word 0x80454C8 @Mental Herb

@@@@@@@@@@@@@@@Oran


.align 2
HPRestoreBerry:
    mov r1, r8
    mov r0, #0x58
    mul r0, r7
    add r2, r0, r1
    ldrh r1, [r2, #0x2C]
    ldrh r3, [r2, #0x28]
    lsr r0, r1, #1
    cmp r3, r0
    bls RestoreHP
    b Quit

RestoreHP:
    ldrh r0, [r4]
    ldr r4, =Damage
    mov r5, r9
    cmp r0, #Sitrus  @Sitrus
    bne NotZero
    ldrh r0, [r2, #0x2C]
    lsr r5, r0, #0x2
    cmp r5, #0x0
    bne NotZero
    mov r5, #0x1

NotZero:
    add r0, r3, r5
    cmp r0, r1
    ble NegDamage
    sub r5, r1, r3

NegDamage:
    neg r5, r5
    str r5, [r4]
    ldr r6, =ScriptPusher
    bl Linker
    ldr r1, =ScriptPointer
    ldr r0, =OranHealBSLoc
    str r0, [r1]
    mov r0, #0x1
    str r0, [sp, #0xC]
    b SetupBuffersAndExit

.align 2
.pool


@@@@@@@@@@@@@@@@@@@@@@@@@@
HPRestoreConfuseBerry:
    mov r0, r5
    sub r0, #0xA
    mov r10, r0
    mov r0, #0x58
    mov r1, r7
    mul r1, r0
    str r1, [sp, #0x18]
    mov r4, r1
    add r4, r8
    ldrh r0, [r4, #0x2C]
    ldrh r1, [r4, #0x28]
    lsr r0, r0, #0x1
    cmp r1, r0
    bls RestoreHPAttemptConfuse
    b Quit

RestoreHPAttemptConfuse:
    ldr r1, =BattleOutcome
    mov r0, #0xFD
    strb r0, [r1]
    mov r0, #0x8
    strb r0, [r1, #0x1]
    mov r0, r10
    strb r0, [r1, #0x2]
    mov r0, #0xFF
    strb r0, [r1, #0x3]
    ldr r5, =Damage
    ldrh r0, [r4, #0x2C]
    mov r1, r9
    ldr r6, =Divider
    bl Linker
    str r0, [r5]
    cmp r0, #0x0
    bne NotZeroWiki
    mov r0, #0x1
    str r0, [r5]

NotZeroWiki:
    ldrh r2, [r4, #0x28]
    ldr r0, [r5]
    add r0, r2, r0
    ldrh r1, [r4, #0x2C]
    cmp r0, r1
    ble CheckConfusion
    sub r0, r1, r2
    str r0, [r5]

CheckConfusion:
    ldr r0, [r5]
    neg r0, r0
    str r0, [r5]
    mov r0, r8
    add r0, #0x48
    ldr r2, [sp, #0x18]
    add r0, r2, r0
    ldr r0, [r0]
    mov r1, r10
    ldr r6, =ConfuseAccToNature
    bl Linker
    lsl r0, r0, #0x10
    blt BerryConfuse
    ldr r6, =ScriptPusher
    bl Linker
    ldr r1, =ScriptPointer
    ldr r0, =OranHealBSLoc
    str r0, [r1]
    mov r0, #0x1
    str r0, [sp, #0xC]
    b SetupBuffersAndExit

BerryConfuse:
    ldr r6, =ScriptPusher
    bl Linker
    ldr r1, =ScriptPointer
    ldr r0, =HealAndConfuseBSLoc
    str r0, [r1]
    mov r0, #0x1
    str r0, [sp, #0xC]
    b SetupBuffersAndExit
.align 2
.pool


@@@@@@@@@@@@@@@@@@
StatRaiseBerry:
    mov r0, r5
    sub r0, #0xF
    mov r10, r0
    mov r0, #0x58
    mul r0, r7
    mov r3, r8
    add r5, r0, r3
    ldrh r4, [r5, #0x28]
    ldrh r0, [r5, #0x2C]

GluttonyCheck:
    mov r2, #0x20
    add r2, r2, r5
    ldrb r2, [r2]
    cmp r2, #GluttonyID
    bne CheckPinchActivation
    lsl r0, r0, #0x1

CheckPinchActivation:
    mov r1, r9
    ldr r6, =Divider
    bl Linker
    cmp r4, r0
    bls CheckForContrary
    b Quit

CheckForContrary:
    mov r6, #0xC
    cmp r2, #ContraryID
    bne NoContrary_Re
    mov r6, #0x0

NoContrary_Re:
    mov r0, r10
    add r0, #0x19
    add r0, r0, r5
    ldrb r0, [r0]
    cmp r0, r6
    bne BoostStat
    b Quit

BoostStat:
    ldr r1, =BattleOutcome
    mov r2, #0xFD
    strb r2, [r1]
    mov r0, #5
    strb r0, [r1, #0x1]
    mov r0, r10
    add r0, #0x1
    strb r0, [r1, #0x2]
    mov r0, #0xFF
    strb r0, [r1, #0x3]
    ldr r0, =TargetPartner
    strb r7, [r0]
    ldr r1, =MiscBufferCountersArea
    mov r0, r10
    add r0, #0x11
    strb r0, [r1, #0x1A]
    sub r0, r0, #0x2
    strb r0, [r1, #0x10]
    mov r0, #0x0
    strb r0, [r1, #0x11]    
    ldr r6, =ScriptPusher
    bl Linker
    ldr r1, =ScriptPointer
    ldr r0, =StatRaiseBSLoc
    str r0, [r1]
    mov r0, #0x1
    str r0, [sp, #0xC]
    b SetupBuffersAndExit
.align 2
.pool

@@@@@@@@@@@@@Lansat Berry:
LansatBerry:
    mov r0, #0x58
    mul r0, r7
    mov r3, r8
    add r5, r0, r3
    ldrh r4, [r5, #0x28]
    ldrh r0, [r5, #0x2C]

GluttonyCheck_Lansat:
    mov r2, #0x20
    add r2, r2, r5
    ldrb r2, [r2]
    cmp r2, #GluttonyID
    bne CheckPinchActivation_Lansat
    lsl r0, r0, #0x1

CheckPinchActivation_Lansat:
    mov r1, r9
    ldr r6, =Divider
    bl Linker
    cmp r4, r0
    bls CheckFocus
    b Quit   

CheckFocus:
    ldr r2, [r5, #0x50]
    mov r3, #0x80
    lsl r3, r3, #0xD
    mov r0, r2
    and r0, r3
    cmp r0, #0x0
    beq SetFocus
    b Quit    

SetFocus:
    orr r2, r3
    str r2, [r5, #0x50]
    ldr r6, =ScriptPusher
    bl Linker
    ldr r1, =ScriptPointer
    ldr r0, =FocusBerryBSLoc
    str r0, [r1]
    mov r0, #0x1
    str r0, [sp, #0xC]
    b SetupBuffersAndExit
.align 2
.pool

@@@@@@@@@@@@@@@
StarfBerry:
    mov r0, #0x58
    mul r0, r7
    mov r3, r8
    add r5, r0, r3
    ldrh r4, [r5, #0x28]
    ldrh r0, [r5, #0x2C]

GluttonyCheck_Starf:
    mov r2, #0x20
    add r2, r2, r5
    ldrb r2, [r2]
    cmp r2, #GluttonyID
    bne CheckPinchActivation_Starf
    lsl r0, r0, #0x1

CheckPinchActivation_Starf:
    mov r1, r9
    ldr r6, =Divider
    bl Linker
    cmp r4, r0
    bgt Quit

CheckStats:
    mov r6, #0xC
    cmp r2, #ContraryID
    bne NoContrary
    mov r6, #0x0

NoContrary:
    mov r0, #0x0
    mov r10, r0
    add r0, r5, #0x1
    mov r1, r8
    add r1, #0x18
    add r0, r0, r1
    ldrb r0, [r1]
    lsl r0, r0, #0x18
    asr r0, r0, #0x18
    cmp r0, r6
    bne RaisableStat
    mov r0, r8
    add r0, #0x19
    add r1, r5, r0

Loop:
    add r1, #1
    add r2, #1
    add r10, r2
    mov r3, r10
    cmp r3, #0x4
    bgt Quit
    ldrb r0, [r1]
    cmp r0, r6
    beq Loop

RaisableStat:
    mov r0, #0x58
    mov r0, r7
    add r4, r0, r7
    ldr r5, =0x202409C
    mov r9, r6

StatSelect:    
    ldr r6, =RNG
    bl Linker
    lsl r0, r0, #0x10
    lsr r0, r0, #0x10
    mov r1, #0x5
    ldr r6, =DivMod
    bl Linker
    lsl r0, r0, #0x10
    lsr r0, r0, #0x10
    mov r10, r0
    add r0, r0, r4
    add r0, r0, r5
    ldrb r0, [r0] 
    lsl r0, r0, #0x18
    asr r0, r0, #0x18
    mov r6, r9
    cmp r0, r6
    beq StatSelect

BoostRandomStat:
    ldr r1, =BattleOutcome
    mov r2, #0xFD
    strb r2, [r1]
    mov r0, #5
    strb r0, [r1, #0x1]
    mov r0, r10
    add r0, #0x1
    strb r0, [r1, #0x2]
    mov r0, #0xFF
    strb r0, [r1, #0x3]
    ldr r0, =TargetPartner
    strb r7, [r0]
    ldr r1, =MiscBufferCountersArea
    mov r0, r10
    add r0, #0x21
    strb r0, [r1, #0x1A]
    add r0, #6
    strb r0, [r1, #0x10]
    mov r0, #0x0
    strb r0, [r1, #0x11]    
    ldr r6, =ScriptPusher
    bl Linker
    ldr r1, =ScriptPointer
    ldr r0, =StatRaiseBSLoc
    str r0, [r1]
    mov r0, #0x1
    str r0, [sp, #0xC]


SetupBuffersAndExit:
    ldr r0, =MiscBufferCountersArea
    strb r7, [r0, #0x17]
    ldr r0, =Bank_F
    strb r7, [r0]
    ldr r4, =ActiveBank
    strb r7, [r4]

Quit2:
    ldr r1, =Return2
    bx r1

Quit:
    ldr r1, =Return
    bx r1

Linker:
     bx r6

.align 2
.pool

SwapBanks:
    ldr r1, =UserBank
    ldrb r0, [r1]
    ldr r3, =Bank_F
    ldrb r2, [r3]
    strb r0, [r3]
    strb r2, [r1]
    bx lr
.align 2
.pool

@@@@OranBerryBS:
OranHealBS:
playanimation 0xA 0x7 0x0

printstring 0x12A

waitmessage 0x40

orword 0x2024280 0x100

graphicalhpupdate 0xA

datahpupdate 0xA

removeitem 0xA
return
.align 2

@@@@
HealAndConfuseBS:
playanimation 0xA 0x7 0x0

printstring 0x12A

waitmessage 0x40

orword 0x2024280 0x100

graphicalhpupdate 0xA

datahpupdate 0xA

printstring 0x144
waitmessage 0x40

callasm SwapBanks+RomAreaOffset+1
setbyte 0x2024335 0x47
seteffecttarget
callasm SwapBanks+RomAreaOffset+1
removeitem 0xA
return

@@@@
FocusBerryBS:
playanimation 0xA 0x7 0x0

printstring 0x146

waitmessage 0x40

removeitem 0xA
return

.align 2
@@@@@@@
StatRaiseBS:
playanimation 0xA 0x7 0x0
callasm SwapBanks+RomAreaOffset+1
statbuffchange 0x41 StatRaiseAnimation+RomAreaOffset

StatRaiseAnimation:
callasm SwapBanks+RomAreaOffset+1
setbyte 0x2024337 0x4
playanimation 0x2 0x1 0x2024484

printfromtable 0x85CC89C

waitmessage 0x40
removeitem 0xA
return

For any folks having trouble with the Sitrus Berry use effect, remove these two lines from the routine, and it should work:
cmp r1, #0x8E
bne Skip

 

[ad2099]

How about I would like to know if there is currently a routine that use the functions to generate a pokemon with all its specific data, basically to be able to replicate a pokemon for example from another trainer, keeping the data of the other trainer, for FR Y E