Code: ASM Resource Thread

[Blah]

Pokemon Obedience via Level and Happiness!

How it works:
If your Pokemon outlevels the level your badges say you can control, it will disobey you if it's unhappy. The concept was pretty simple sounding, but there was a lot of work that went into it. This should keep some similarities to the anime.
I should note that if your Pokemon loves you, and you don't have the badge to train it, it will still listen to you :3

This one is called love.asm

How to insert:
Compile and insert into freespace the following code:

Spoiler:

.text
.align 2
.thumb
.thumb_func


main:
	mov r4, #0x82
	lsl r4, r4, #0x4
	mov r2, #0x0

badgeLoop:
	mov r0, r4
	ldr r6, =(0x806E6D0 +1)
	bl linkerOne
	cmp r0, #0x1
	bne trainLevel
	add r4, r4, #0x1
	add r2, r2, #0x1
	cmp r2, #0x8
	beq obey
	b badgeLoop

trainLevel:
	@no flags set = lvl 20. Increment by 10 per additional flag
	mov r0, #0xA
	mov r2, #0x82
	lsl r2, r2, #0x4
	sub r4, r4, r2
	mul r4, r4, r0
	add r4, #0x14

PokemonLevel:
	ldrh r0, [r5]
	mul r0, r7
	ldr r6, = (0x2024284)
	add r0, r0, r6
	mov r1, #0x38
	ldr r6, = (0x803FBE8 +1)
	bl linkerOne
	cmp r0, r4
	ble obey
	


isHappy:
	@if it loves you and you don't have badges, it will obey
	@if it doesn't love you and you don't have badges it will disobey
	ldrh r0, [r5]
	mul r0, r7
	ldr r6, = (0x2024284)
	add r0, r0, r6
	mov r1, #0x20
	ldr r6, =(0x803FBE8 +1)
	bl linkerOne
	cmp r0, #0x7F @this is half possible of max happiness tone to your liking
	bls disobey

obey:
	mov r0, #0x1
	b end
	

disobey:
	ldr r0, =(0x801D414 +1) @you can simply mov r0 to 0x0 too
	bx r0

end:
	mov r2, #0x0
	ldr r1, =(0x801D42A +1)
	bx r1


linkerOne:
	bx r6
	
	

.align 2

Here's a compiled version:

82 24 24 01 00 22 20 1C 15 4E 00 F0 28 F8 01 28 04 D1 01 34 01 32 08 2A 1A D0 F4 E7 0A 20 82 22 12 01 A4 1A 44 43 14 34 28 88 78 43 0D 4E 80 19 38 21 0D 4E 00 F0 13 F8 A0 42 09 DD 28 88 78 43 08 4E 80 19 20 21 08 4E 00 F0 09 F8 7F 28 01 D9 01 20 01 E0 05 48 00 47 00 22 05 49 08 47 30 47 D1 E6 06 08 84 42 02 02 E9 FB 03 08 15 D4 01 08 2B D4 01 08

Navigate to 0x1D3E0 and insert:

 00 48 00 47 XX XX XX 08

Where XX XX XX is the reverse hex pointer to location you compiled the routine.

I should mention there was a little bit of this routine which I'm skipping over. Basically it checks if the Pokemon is a Mew or Deoxys. It then checks if the Mew/Deoxys has it's obedience set. I find the need for this non-existent because the obedience is checked by happiness and badges my way. In the end, if you want to keep these two (rather pointless) checks, insert at 0x1D406.

Sorry for the double post. I want to keep my routines on separate posts to help in formatting the first post's index :x

Requested here: https://www.pokecommunity.com/posts/8510180/
I made a special exception and decided to do it for her here by that I mean no other requests were on the table:)

 

[Christos]

I'm going to suggest something as well since it's kind of similar to all these routines you're doing. It's something that's been done in OR/AS. Going to put this in a spoiler:

Spoiler:

copied from Serebii: Once you have the three Regis, Regirock, Regice and Registeel, you can unlock Regigigas. The method to get this is rather complicated. In Pacifidlog Town, in the north-eastern house, a girl will tell you stories her grandfather told her. At random, she will tell you a part of the story about how to get Regigigas. This involves location and the other features. Take all three of the Pokémon to the Island Cave during the day, and make Regice hold a frozen item such as CasteliaCone, Snowball or Never-Melt Ice, and have Regice have a nickname, and Regigigas will challenge you.

So basically, a routine that would check if any of your Pokémon (or a specific one) are holding a certain item, or any of your Pokémon are nicknamed, though I believe the first one would be more useful.

 

[tzujm33]

Is it possible to make exp dependend on how big the level gap between you and the opponent pokemon are? for example that you get 100% of the exp if you beat a Pokemon, that is on a higher level or the same level as your pokemon, but only get 50% if your Pokemon is 10 level higher than the opponent Pokemon or so.

 

[Shiny Quagsire]

Dood, this sounds awesome, I hope you get some cool ideas from this.

Here's what came to my mind (For Fire Red U):

Spoiler:

A way to change the warp points for the ship animation in Fire Red, so that you can use it to travel to other maps (If already possible then I apologize, I just haven't found a way to change them w/o ASM).

Spoiler:

Ooh, I think I know this one, It doesn't require ASM, but it's actually a table I found a loooong while back. Either way, I believe the table is located at 0846AEFC, and the cutscene is executed using special 0x17B and the number in variable 0x8006. If you want to, you can repoint the table and then increase the length, setting the byte at 08147148 to the new number of locations you have. As for the format, I believe it's <bank> <map> <xpos> <ypos> <something>.

 

[Blah]

I'm going to suggest something as well since it's kind of similar to all these routines you're doing. It's something that's been done in OR/AS. Going to put this in a spoiler:

Spoiler:

copied from Serebii: Once you have the three Regis, Regirock, Regice and Registeel, you can unlock Regigigas. The method to get this is rather complicated. In Pacifidlog Town, in the north-eastern house, a girl will tell you stories her grandfather told her. At random, she will tell you a part of the story about how to get Regigigas. This involves location and the other features. Take all three of the Pokémon to the Island Cave during the day, and make Regice hold a frozen item such as CasteliaCone, Snowball or Never-Melt Ice, and have Regice have a nickname, and Regigigas will challenge you.

So basically, a routine that would check if any of your Pokémon (or a specific one) are holding a certain item, or any of your Pokémon are nicknamed, though I believe the first one would be more useful.

I accept your challenge!
Nickname checks are done in a script via special2 0x7B. It returns 1 in the variable if it wasn't nicknamed.

Is it possible to make exp dependend on how big the level gap between you and the opponent pokemon are? for example that you get 100% of the exp if you beat a Pokemon, that is on a higher level or the same level as your pokemon, but only get 50% if your Pokemon is 10 level higher than the opponent Pokemon or so.

I'll add it to my projects list. iirc, this is read off of a table isn't it?

Ooh, I think I know this one, It doesn't require ASM, but it's actually a table I found a loooong while back. Either way, I believe the table is located at 0846AEFC, and the cutscene is executed using special 0x17B and the number in variable 0x8006. If you want to, you can repoint the table and then increase the length, setting the byte at 08147148 to the new number of locations you have. As for the format, I believe it's <bank> <map> <xpos> <ypos> <something>.

Thanks :D

Party Item Checker:

How it works:
So I use the variables 0x8000 and 0x8001 again.
0x8000 Should be set to Pokemon species (2 bytes)
0x8001 Needs to be set to Item ID (1 byte...can be changes to 2 if you inserted more than 255 items)

case 1:
If a Pokemon in your party has the item specified by 0x8001 and the species matches 0x8000, return that Pokemon's slot

case 2:
If 0x8000 is set to 0x0 (no species), the routine will search your whole party and return the slot of the Pokemon holding the item specified in 0x8001

case 3:
If no Pokemon in the party are holding the item, returns 0x6.

The result will be stored in variable 0x8000. The result will, obviously, be 0x0-0x5 (slot) for item found and 0x6 for not found.


How to insert:

Compile and insert into free space the following routine:

Spoiler:

.text
.align 2
.thumb
.thumb_func

main:
	push {r0-r6, lr}
	ldr r6, =(0x2024029)
	ldrb r6, [r6]
	mov r5, #0x0

PokeLoop:
	cmp r6, r5
	beq none
	mov r0, #0x64
	mul r0, r0, r5
	mov r1, r0
	ldr r0, =(0x2024284)
	add r0, r0, r1
	mov r1, #0xC
	ldr r2, =(0x803FBE8 +1)
	bl linker
	ldr r3, .ITEM
	ldrb r3, [r3]
	cmp r0, r3
	beq PokeMatch

next:
	add r5, r5, #0x1
	b PokeLoop
	

PokeMatch:
	ldr r4, .MON
	ldrh r4, [r4]
	cmp r4, #0x0
	beq found
	ldr r2, =(0x803FBE8 +1)
	mov r0, #0x64
	mul r0, r0, r5
	mov r1, r0
	ldr r0, =(0x2024284)
	add r0, r0, r1
	mov r1, #0xB
	bl linker
	ldr r4, .MON
	ldrh r4, [r4]
	cmp r0, r4
	bne next

found:
	ldr r2, .MON
	strb r5, [r2]
	pop {r0-r6, pc}
	

none:
	ldr r0, .MON
	mov r1, #0x6
	strb r1, [r0]
	pop {r0-r6, pc}	
	
linker:
	bx r2
	
	
.align 2

.ITEM:
	.word 0x020270B8 + (0x8001 * 2) @ITEM ID
.MON:
	.word 0x020270B8 + (0x8000 *2) @PKMN SPECIES

Here's a compiled version:

7F B5 18 4E 36 78 00 25 AE 42 22 D0 64 20 68 43 01 1C 15 48 40 18 0C 21 14 4A 00 F0 1E F8 0F 4B 1B 78 98 42 01 D0 01 35 EE E7 0D 4C 24 88 00 2C 0C D0 0E 4A 64 20 68 43 01 1C 0B 48 40 18 0B 21 00 F0 0B F8 06 4C 24 88 A0 42 EC D1 04 4A 15 70 7F BD 03 48 06 21 01 70 7F BD 10 47 BA 70 03 02 B8 70 03 02 29 40 02 02 84 42 02 02 E9 FB 03 08

Usage:
In a script,
setvar 0x8000 0xspecies
setvar 0x8001 0xItemID
callasm 0x[Where you inserted the above routine +1]

That's it!

 

[daniilS]

Is it possible to make exp dependend on how big the level gap between you and the opponent pokemon are? for example that you get 100% of the exp if you beat a Pokemon, that is on a higher level or the same level as your pokemon, but only get 50% if your Pokemon is 10 level higher than the opponent Pokemon or so.

You mean like in BW? Because that has been ported already.

 

[tzujm33]

Well i didnt meant especially like in bw when i wrote my post, because i didnt play bw and thus didnt know that it had such a exp system. I now looked the bw system up and yes, it comes close to what i want, even though i would like it to be a bit more radical.
Um i searched for a thread were this port is explained and if such a thread exist, i couldnt find it.
I would be really thankful if you could send me a link to the port!

 

[BLAx501!]

I was writing you some ideas when I lost all the text I had wrote... Very frustrating xD

Well, I have 3 ideas to show up, here we go!

1.- Forced evolution For some points it would be great to have this, like for example give your starter a final evolutionary stage really powerful, or for some plot twists (like when on the manga, Red's Poliwhirl evolves to Poliwrath).

2.- Keeping TM like on BW: This was done before, but it doesn't work properly. I don't usually leave comments here so I can't put any link yet, but if you want I can send you them by Profile Message or Private Message.

3.- Skip Prof. Oak's introduction: In my opinion this introducion is okay for the original games, but not everyone likes it, and it's bad for people who look for a really inmersive story, cause it has to start always more or less the same. It is possible to skip it (I don't know how it's done, but I guess you just have to branch instead of the direction of the intro, the direction of where the game itself starts) and to give preset names to both the player and the rival, but again, I'm not as good to do it yet xD.


Well, I hope I don't bother you with these ideas xD. Thanks in advanced an really nice work here :D

 

[Blah]

Well i didnt meant especially like in bw when i wrote my post, because i didnt play bw and thus didnt know that it had such a exp system. I now looked the bw system up and yes, it comes close to what i want, even though i would like it to be a bit more radical.
Um i searched for a thread were this port is explained and if such a thread exist, i couldnt find it.
I would be really thankful if you could send me a link to the port!

I don't know where it is either. Perhaps you can ask daniilS via VM or something.

I was writing you some ideas when I lost all the text I had wrote... Very frustrating xD

Well, I have 3 ideas to show up, here we go!

1.- Forced evolution For some points it would be great to have this, like for example give your starter a final evolutionary stage really powerful, or for some plot twists (like when on the manga, Red's Poliwhirl evolves to Poliwrath).

2.- Keeping TM like on BW: This was done before, but it doesn't work properly. I don't usually leave comments here so I can't put any link yet, but if you want I can send you them by Profile Message or Private Message.

3.- Skip Prof. Oak's introduction: In my opinion this introducion is okay for the original games, but not everyone likes it, and it's bad for people who look for a really inmersive story, cause it has to start always more or less the same. It is possible to skip it (I don't know how it's done, but I guess you just have to branch instead of the direction of the intro, the direction of where the game itself starts) and to give preset names to both the player and the rival, but again, I'm not as good to do it yet xD.


Well, I hope I don't bother you with these ideas xD. Thanks in advanced an really nice work here :D

1) For forced evolution, I don't know what you're really talking about. You mean just make a Pokemon evolve without giving the player time to hit the "b" button? I'll look into Pokemon evolution sure.

2) I haven't seen it so VMing me it would be nice. Anyways this is rather easy, I've done it before. I'll post the results at the bottom of this post.

3) Skipping the introduction was already done by Knizz. There's a post in the research and development section's quick research thread.

Preventing TMs from being consumed on use

Quick research:
TMs are deleted in two places. The first place is in their own function. When called from the bag, after use the TM has it's own deletion mechanism. The second way is from the bag, after you use a TM the bag attempts to delete it as well. Well, the solution is quite simple. There's two ways to do this, either go to 0809A1D8 call your own function there which checks if the item is a TM, and if it is, just jump to the end. Or much more simply you just remove the parts from the bag and tm function that deletes the TM (Which is what I did). The former way is a way you can make another item you have unconsumable.

To insert:
Do the byte changes below
0x124F78: 00 00 00 00
0x125C80: 00 00 00 00

Make it Ungivable:
insert that at 0x1326B8: 00 00 17 E0

Make it consumable after animation:
Insert: 00 00 00 00 at 0x124F78

To remove the quantities showing up in the bag:

Compile and insert into free space:

Spoiler:

.text
.align 2
.thumb
.thumb_func

main:
	cmp r5, #0x0
	bne end
	ldr r3, =(0x8131EFE +1)
	bx r3

end:
	mov r0, r7
	mov r1, #0x8
	mov r2, r4
	ldr r6, =(0x81335B0 +1)
	bl link
	ldr r3, =(0x8131EFE +1)
	bx r3

link:
	bx r6

.align 2

Here's a compiled version:

00 2D 01 D1 05 4B 18 47 38 1C 08 21 22 1C 04 4E 00 F0 02 F8 01 4B 18 47 30 47 C0 46 FF 1E 13 08 B1 35 13 08

Now navigate to 0x131EF4 and insert:

00 48 00 47 XX XX XX 08

Where XX XX XX is the pointer to where you assembled the routine +1

Now navigate to 0x131EA5 and change the byte to E0

Unsellable:
Basically for the TMs, you can still sell them to vendors. To change this, you need to modify each TM individually. It's unfortunate, but the game checks if an item can be sold my comparing it's market price to zero. If it's strictly greater than zero, then you can sell it to a vendor, seems to be the rule. So to make TMs unsellable you need to set their market prices individually to zero.
I can't use my own checks to disguise the TMs as unique because the sell routine in shops are used for ALL items including potions, berries, TMs, and other items like nuggets.


Present :3

 

[Christos]

1) For forced evolution, I don't know what you're really talking about. You mean just make a Pokemon evolve without giving the player time to hit the "b" button? I'll look into Pokemon evolution sure.

I think what BLAxTOISE meant by forced evolution is making a Pokémon from your party evolve from a script. I can see this being used as an alternative for trade evolutions, for example paying someone to make your Pokémon evolve.

 

[BLAx501!]

1) For forced evolution, I don't know what you're really talking about. You mean just make a Pokemon evolve without giving the player time to hit the "b" button? I'll look into Pokemon evolution sure.

Exactly, I was meant to say that @Christos hahahahaha. As far as I know, there are two problems with that. Even if you have found the starting offset of the routine (I'm not 100% sure of what I'm saying xD), you need to find the one who returns you to the regular gameplay after it. Also, you need to check the species involved into the process, to make it coherent.

This will just make the TM's usage infinite. It will still allow you to sell the TM, give it to a Pokemon..ect.

Playing with the Mistery Values on an Item Editor you can get the TM behave like HM in terms of equipping them, selling or tossing them. Did you get the amount of TM removed?? It's purely aesthetic, but it would be nice.

As far as I know, changing the first Mistery Value of a TM from 00 to 01, it displays like an HM, without the amount, but with the HM tag behind the TM number.


Thanks for answering so quickly :P

 

[Blah]

I think what BLAxTOISE meant by forced evolution is making a Pokémon from your party evolve from a script. I can see this being used as an alternative for trade evolutions, for example paying someone to make your Pokémon evolve.

Thanks for clearing that up.

Exactly, I was meant to say that @Christos hahahahaha. As far as I know, there are two problems with that. Even if you have found the starting offset of the routine (I'm not 100% sure of what I'm saying xD), you need to find the one who returns you to the regular gameplay after it. Also, you need to check the species involved into the process, to make it coherent.

Playing with the Mistery Values on an Item Editor you can get the TM behave like HM in terms of equipping them, selling or tossing them. Did you get the amount of TM removed?? It's purely aesthetic, but it would be nice.

As far as I know, changing the first Mistery Value of a TM from 00 to 01, it displays like an HM, without the amount, but with the HM tag behind the TM number.


Thanks for answering so quickly :P

1) For the TMs, no I did not remove the number that appears beside it (I just simply modified it to work like HMs in the ways you mentioned above, except the quantity). I think that this is directly related to the "HM tag". When the bag opens it displays it's contents and this number appears depending on this value. I'll try to track this down later, it's definitely not going to be easy.

2) Your evolution request is turning out to be quite the big request! There's a lot of work that goes into evolution including stat updates, Pokedex updates, species updates and depending on if it has a nickname or not the nickname updates. There's also Having to figure out which Pokemon evolves into which Pokemon too. Although normally I wouldn't take on something like this that'd take me a while, I've decided that I'll do it because it's actually a very neat and fun feature :P

 

[Trainer 781]

Thanks for clearing that up.

sy.

2) Your evolution request is turning out to be quite the big request! There's a lot of work that goes into evolution including stat updates, Pokedex updates, species updates and depending on if it has a nickname or not the nickname updates. There's also Having to figure out which Pokemon evolves into which Pokemon too. Although normally I wouldn't take on something like this that'd take me a while, I've decided that I'll do it because it's actually a very neat and fun feature :P

There is Chaos Rush's Thread for changing species of a pokemon via script and using JPAN's ASM for Ruby. https://www.pokecommunity.com/threads/279194. This might save you some work.

 

[daniilS]

There is Chaos Rush's Thread for changing species of a pokemon via script and using JPAN's ASM for Ruby. https://www.pokecommunity.com/threads/279194. This might save you some work.

Actually, I wouldn't recommend using JPAN's method: for some reason he wrote a completely custom decryptor, while there is an existing one in the rom already. It's way easier to use because changing a pokémon's species requires just a single callasm. (If anybody is interested, I made this in ancient times: )

Spoiler:

.text
.align 2
.thumb
.thumb_func
.global Indexnumber_changeand20bytes_recalc

main:
	push {r0-r3, lr}
getpokeoffset:
	ldr r0, varnumber_8004
	ldr r3, vardecrypt
	bl bxr3
	ldrh r2, [r0]
	mov r0, #100
	mul r2, r0
	ldr r0, partystart
	add r3, r2, r0
	push {r3}
getandsetnewindexnumber:
	ldr r0, vartocontainnewindexnumber
	ldr r3, vardecrypt
	bl bxr3
	mov r2, r0
	mov r1, #0xB
	ldr r0, [sp]
	ldr r3, pokeencrypt
	bl bxr3
recalc20bytes:
	pop {r0}
	ldr r3, effectivestatsrecalc
	bl bxr3
	pop {r0-r3, pc}
bxr3:
	bx r3
	
.align 2
	varnumber_8004:			.word 0x8004
	vardecrypt:			.word 0x0806E454+1
	partystart:			.word 0x02024284
	vartocontainnewindexnumber:	.word 0x8005
	pokeencrypt:			.word 0x0804037C+1
	effectivestatsrecalc:		.word 0x0803e47c+1
	
/*Insert anywhere. then use special 0x9F to select a pokemon, waitstate, setvar 0x8005 to the desired index number, and callasm this routine+1*/

However, I believe the thing that's important about his request is playing the evolution animation, which isn't as easy to do as this.

 

[Blah]

Thanks, I'm actually already done the parts of getting the evolution done. I'm working on animation right now :)

Also yours, Danills, doesn't seem to work to update the nickname, pokedex entry, new moves or get the next evolution automagically?
I've fixed these in my version.

 

[daniilS]

Thanks, I'm actually already done the parts of getting the evolution done. I'm working on animation right now :)

Also yours, Danills, doesn't seem to work to update the nickname, pokedex entry, new moves or get the next evolution automagically?
I've fixed these in my version.

Nope, because mine was more of a reply to using JPAN's decryptor. The routine I had written is used for Rotom.

 

[Red John]

Can you create an evolution like arceus in which the Pokemon will change form if holding an item without showing the evolution screen

 

[daniilS]

Can you create an evolution like arceus in which the Pokemon will change form if holding an item without showing the evolution screen

That's not even an evolution, it's an index number change, like in that other routine I sent. And I have made such a routine in the past indeed, the problem is it's so horribly coded that it only works if the indexes are the same as in PRPB, and nobody is able to understand it. Rewriting it is on my to-do list for the Christmas holiday.

 

[Blah]

Hmm, so I'm at this point where I can silently make the evolution happen without a problem in sight. However, once I add in the animation, it works fine too, until the part where the animation is over and it's time to enter back into OW. We get a gamefreeze once that happens. That and you can cancel the animation process by pressing "b". So it's very buggy and it will take time to rework.

I'll save the Evolution + animation till a later time. Currently it's 70% done, just have to figure out how to remove the freeze.

Until then here's the "silent evolution" one. Which, ironically, is a lot longer than with the animation.

Forced Evolution (silently):

(with animation to come at a later date).

How to insert:
Compile and insert into free space the following routine:

Spoiler:

.text
.align 2
.thumb
.thumb_func

main:
	push {r0-r7, lr}
	ldr r0, .SLOT @calculate address of Pokemon we want to evolve
	ldrh r0, [r0]
	mov r1, #0x64
	mul r0, r0, r1
	ldr r1, =(0x2024284)
	add r0, r0, r1
	mov r7, r0
	mov r1, #0xB 
	ldr r3, =(0x803FBE8 +1) @get current species, prior to evolving
	bl linker
	mov r5, r0
	bl getEvolvedForm @check what species it evolves into
	mov r6, r0
	mov r0, r7
	mov r1, #0x38
	ldr r3, =(0x803FBE8 +1) @save level before evolution
	bl linker
	mov r4, r0

SetEvolve:
	mov r0, r7 @evolve it
	ldr r2, .VAR
	mov r1, r6
	strh r1, [r2]
	mov r1, #0xB
	ldr r3, =(0x804037C +1)
	bl linker
	mov r0, r7
	ldr r3, =(0x803E47C +1) @recalculate stats
	bl linker

AddToDex:
	mov r0, r6
	ldr r3, =(0x8043298 +1) @get dex index of species
	bl linker
	mov r0, r6
	mov r1, #0x2
	ldr r3, =(0x8088E74 +1) @normal dex
	bl linker
	mov r0, r6
	mov r1, #0x3
	ldr r3, =(0x8088E74 +1) @national
	bl linker

FinishCalc:
	mov r0, r7 @check current level (after evolving)
	mov r1, #0x38
	ldr r3, =(0x803FBE8 +1)
	bl linker
	cmp r0, r4 @exp curves skewed level
	bne AdjustLvl
	b Nickname

getEvolvedForm:
	mov r1, #0x4 @calculate the evolution of a species
	mul r1, r1, r0
	add r0, r0, r1
	lsl r0, r0, #0x03
	ldr r3, = (0x8259754)
	add r1, r0, r3
	ldrh r0, [r1, #0x2] @evolution 2 i.e Pidgeot
	ldrh r2, [r1, #0x4] @evolution 1 i.e Pidgeotto
	cmp r0, r2
	bgt setter
	bx lr

setter:
	mov r0, r2 @give next evolved form
	bx lr

Nickname:
	mov r0, r7
	ldr r1, =(0x2021CD0) @store current nickname here
	mov r2, r1
	mov r1, #0x2
	ldr r3, =(0x803FBE8 +1)
	bl linker
	ldr r0, =(0x8245EE0)@calculate species default name
	mov r1, #0xB
	mul r1, r1, r5
	add r1, r1, r0
	mov r5, r1
	ldr r1, =(0x2021CD0)
	mov r4, r1
	mov r0, #0x0
	
checkEqual:
	cmp r0, #0xA            @While nickname has char
	beq setName
	add r5, r5, #0x1        @get next char of species name
	ldrb r1, [r5]
	add r4, r4, #0x1        @get next char of nickname
	ldrb r2, [r4]
	cmp r2, r1                @if x != y ==> has nickname
	bne end
	cmp r2, #0xFF          @strings are 0xFF terminated
	beq checkOne
	b contLoop

checkOne:
	cmp r1, #0xFF
	beq setName
	b end

contLoop:
	add r0, r0, #0x1 @loop counter ++
	b checkEqual

setName:
	ldr r2, =(0x8245EE0) @set nickname as species name
	mov r0, #0xB
	mul r6, r6, r0
	add r6, r6, r2
	mov r0, r7
	mov r2, r6
	mov r1, #0x2
	ldr r3, =(0x804037C +1)
	bl linker
	b end
	
	
AdjustLvl:
	cmp r0, r4
	beq Nickname
	mov r2, r0
	mov r0, r7
	mov r1, #0x19
	ldr r3, =(0x803FBE8 +1) @x = currentExp * 1.1
	bl linker
	mov r1, r0
	lsr r0, #0x4
	cmp r2, r4           @if current lvl < old lvl; currentExp -= x
	bls subtract
	add r1, r1, r0 
	b updateExp
	
subtract:
	sub r1, r1, r0       @else currentExp += x

updateExp:
	ldr r2, .VAR
	str r1, [r2]
	mov r1, #0x19
	mov r0, r7
	ldr r3, =(0x804037C +1)
	bl linker
	mov r0, r7
	ldr r3, =(0x803E47C +1)
	bl linker
	mov r0, r7
	mov r1, #0x38
	ldr r3, =(0x803FBE8 +1)
	bl linker
	b AdjustLvl


end:
	pop {r0-r7, pc}
	
 
linker:
	bx r3
	

.align 2

.VAR:
	.word 0x20270B8 + (0x8000 *2) @change to any 2 byte free space in RAM
.SLOT:
	.word 0x20270B8 + (0x8001 *2) @slot of Pokemon to evolve

Here's a compiled version:

FF B5 49 48 00 88 64 21 48 43 48 49 40 18 07 1C 0B 21 47 4B 00 F0 84 F8 05 1C 00 F0 29 F8 06 1C 38 1C 38 21 42 4B 00 F0 7B F8 04 1C 38 1C 3D 4A 31 1C 11 80 0B 21 3F 4B 00 F0 72 F8 38 1C 3E 4B 00 F0 6E F8 30 1C 3D 4B 00 F0 6A F8 30 1C 02 21 3B 4B 00 F0 65 F8 30 1C 03 21 39 4B 00 F0 60 F8 38 1C 38 21 32 4B 00 F0 5B F8 A0 42 37 D1 0C E0 04 21 41 43 40 18 C0 00 32 4B C1 18 48 88 8A 88 90 42 00 DC 70 47 10 1C 70 47 38 1C 2E 49 0A 1C 02 21 27 4B 00 F0 44 F8 2C 48 0B 21 69 43 09 18 0D 1C 29 49 0C 1C 00 20 0A 28 0D D0 01 35 29 78 01 34 22 78 8A 42 32 D1 FF 2A 00 D0 02 E0 FF 29 02 D0 2C E0 01 30 EF E7 20 4A 0B 20 46 43 B6 18 38 1C 32 1C 02 21 17 4B 00 F0 22 F8 1F E0 A0 42 D3 D0 02 1C 38 1C 19 21 11 4B 00 F0 19 F8 01 1C 00 09 A2 42 01 D9 09 18 00 E0 09 1A 09 4A 11 60 19 21 38 1C 0B 4B 00 F0 0B F8 38 1C 0A 4B 00 F0 07 F8 38 1C 38 21 06 4B 00 F0 02 F8 DF E7 FF BD 18 47 C0 46 B8 70 03 02 BA 70 03 02 84 42 02 02 E9 FB 03 08 7D 03 04 08 7D E4 03 08 99 32 04 08 75 8E 08 08 54 97 25 08 D0 1C 02 02 E0 5E 24 08

Usage:

Set the slot of the Pokemon you want to evolve in var 0x8001 (0x0 to 0x5). Then callasm to this routine and the rest is done automagically.

You can use this routine in conjunction with the checkItem routine to make a Pokemon evolve if it's holding an Item. Or if you wanted an evolution scene inside the Overworld this is useful too.
Like I said, an animated version will come out later once I figure out a way to fix some bugs. No promises on the date, it's very complicated :P

 

[Christos]

Usage:

Set the slot of the Pokemon you want to evolve in var 0x8001 (0x0 to 0x5). Then callasm to this routine and the rest is done automagically.

What if the Pokémon I choose to evolve has two evolutions available, like Gloom, Slowpoke or Poliwhirl? Would it just go for the normal level-up evolution, which is the first in their data?