Development: Heads-up Display

[Touched]

Most games have a HUD, which allows players to check vital status information, such as health, money, etc. The Pokemon series has no need for this information, as it's all packed away in the start menu. However, with the mechanics of the game being altered, one could feasibly implement a hunger and thirst system, or a fatigue system. These mechanics would need a HUD of some sort in order to be properly implemented.

Since the HUD is usually displayed on the map, and not on any menus, I sought the map rendering routine. I found it at 0805ABB0. This routine does some checks every frame to see if the camera has moved, and updates the appropriate area of the display if it has. However, for the purposes of this research, we have no interest in the body of this routine. We are only interested in the part that returns the function (the branch at 0805AC7E).

ROM:0805AC7E loc_805AC7E                             ; CODE XREF: ROM:0805AC52j
ROM:0805AC7E                 LDR     R0, =0x3000E90
ROM:0805AC80                 MOVS    R1, R7
ROM:0805AC82                 MOV     R2, R8
ROM:0805AC84                 BL      sub_805A5D4
ROM:0805AC88                 LDR     R1, =0x300506C
ROM:0805AC8A                 LDRH    R0, [R1]
ROM:0805AC8C                 SUBS    R0, R0, R7
ROM:0805AC8E                 STRH    R0, [R1]
ROM:0805AC90                 LDR     R1, =0x3005068
ROM:0805AC92                 LDRH    R0, [R1]
ROM:0805AC94                 MOV     R2, R8
ROM:0805AC96                 SUBS    R0, R0, R2
ROM:0805AC98                 STRH    R0, [R1]
ROM:0805AC9A                 POP     {R3}
ROM:0805AC9C                 MOV     R8, R3
ROM:0805AC9E                 POP     {R4-R7}
ROM:0805ACA0                 POP     {R0}
ROM:0805ACA2                 BX      R0

So we'd like to inject a routine that loads our HUD after the map updates.

From the looks of the code around the call to this function, this function is a void (doesn't return anything), therefore we can just use r1 without fear of overwriting anything.

ldr r1, =0xDEADBEEF
bx r1

Where 0xDEADBEEF is the offset of your new routine. This code then assembles to

01 49 08 47 EF BE AD DE

That code is going to be 8 bytes. 4 bytes for both opcodes and another 4 for that symbol. So we can overwrite the instructions here: 0805AC9A. One problem - this isn't word aligned. So we need to align that symbol properly. Just pad it with 0s:

01 49 08 47 00 00 EF BE AD DE

Now we can insert at 0805AC9A. Remember to replace the fake offset with your new routine. I chose 087FF000. Also remember to set the Thumb bit.

Now we need to restore functionality to this routine, be adding the opcodes we overwrote. So here is a skeleton routine that you must insert at the offset you chose:

.thumb
.align 2

main:
	bl main_func
	pop {r3}
	mov r8, r3
	pop {r4-r7}
	pop {r0}
	bx r0

main_func:
	mov r0, r0 @nop
	@ Render HUD here

Now the next thing is we must be careful not to do too much in this function to prevent lag. So using this skeleton, I wrote some stuff to the OAM at a fixed pair of coordinates, on the highest priority, and got this:

So it works. Now I just have to work on loading custom graphics and whatever into the VRAM. Right now, overworlds will flicker, but this is just because I'm overwriting OBJ1 in the OAM. I'll update more when I have it.

 

[cscof]

you may also want to take that woman off the top of that building before she falls and breaks a bone or something

 

[Bill Cipher]

you may also want to take that woman off the top of that building before she falls and breaks a bone or something

I think the whole idea is SHE is the HUD.

 

[cscof]

I think the whole idea is SHE is the HUD.

I know, it was an attempt at a bad joke

 

[Danno]

This could prove to be very useful for my hack, thanks for the research, if used I'll surely give you credit!

 

[Touched]

I've got an update. I wrote an example routine (very hurriedly, I might add, it's unoptimized and is very slow) that reads what status ailments your party has and displays it on the HUD.

Spoiler:

Insert this in the same manner described in the first post. Note that you can directly load into the OAM and Palette memory because of this being loaded after the game loads its graphics - the engine will not overwrite your changes.

.thumb
.align 2

main:
	bl render
	pop {r3}
	mov r8, r3
	pop {r4-r7}
	pop {r0}
	bx r0

render:
	push {r0-r7, lr}
	mov r4, #0x0
	ldr r5, .POKEMON_PARTY
	mov r6, #0x0
status_party_loop:
	ldr r2, .POKEMON_GETATTR
	mov r0, r5
	mov r1, #0x37 @Ailment attr
	bl call_via_r2
	orr r6, r0
	cmp r4, #0x5
	bge status_draw
	add r4, #0x1
	add r5, #0x64
	b status_party_loop

status_draw:
	mov r0, #0x7 
	and r0, r6
	cmp r0, #0x0
	beq status_poison
	mov r4, #0x2
	bl status_loop
status_poison:
	mov r0, #0x88
	and r0, r6
	cmp r0, #0x0
	beq status_burn
	mov r4, #0x0
	bl status_loop
status_burn:
	mov r0, #0x10
	and r0, r6
	cmp r0, #0x0
	beq status_freeze
	mov r4, #0x4
	bl status_loop

status_freeze:
	mov r0, #0x20
	and r0, r6
	cmp r0, #0x0
	beq status_para
	mov r4, #0x3
	bl status_loop
	
status_para:
	mov r0, #0x40
	and r0, r6
	cmp r0, #0x0
	beq status_end
	mov r4, #0x1
	bl status_loop
	b status_end
@PSN PAR SLP FRZ BRN PkRS FNT

status_loop:
	push {r0-r7, lr}
	mov r0, #0x4 @ Icon, multiples of 4
	mul r0, r4
	mov r1, #0x20 @ X coord
	mul r1, r4
	mov r2, r4 @ Obj num
	bl draw
	pop {r0-r7, pc}

status_end:
	pop {r0-r7, pc}
call_via_r2:
	bx r2

draw:
	push {r0-r6}
	mov r4, r0
	mov r5, r1
	mov r6, r2

	@ Load tiles
	ldr r0, .TILES
	mov r1, #0x7C @ Tile number
	lsl r1, #0x5 @ Multiply by 32
	add r1, r0
	ldr r0, .GRAPHICS
	swi #0x12

	ldr r0, .OAM
	
	@ Objnum * 8
	mov r1, #0x10 @ object 0x10
	add r1, r6
	lsl r1, #0x3

	@ Calculate properties offset
	add r0, r1

	@ Set Object Attributes

	@ Attribute 0
	@ BLDCNT for blending?
	mov r1, #0x90 @ Y Coordinate (8 bits)
	mov r2, #0x40 @#0x04 @80
	lsl r2, #0x8
	orr r1, r2
	strh r1, [r0, #0x0]

	@ Attribute 1
	mov r1, #0x40 @80
	lsl r1, #0x8

	@ X Coordinate (9 bits)
	mov r2, #0x00
	lsl r2, #0x8
	mov r3, #0x2
	add r3, r5
	orr r2, r3
	orr r1, r2
	strh r1, [r0, #0x2]

	@ Attribute 2

	@mov r1, #0x1c
	mov r1, #0x7c @ Tile number
	add r1, r4
	mov r2, #0x04 @ Priority
	lsl r2, #0x8
	orr r1, r2

	@ Set pal
	push {r0-r3}
	ldr r0, .STATUS_GRAPHICS_PAL
	ldr r1, .PAL_DEST
	mov r2, #0x8
	swi #0xC
	pop {r0-r3}

	@ Add in Palette number
	mov r2, #0xE
	mov r3, #0xF
	and r2, r3 @ 4 bits
	lsl r2, #0xC
	orr r1, r2

	strh r1, [r0, #0x4]
	
end:
	pop {r0-r6}
	bx lr

.align 2
.OAM: .word 0x07000000
.TILES: .word 0x06010000
.GRAPHICS: .word 0x08E9BF48 @0x083EF524 @.word 0x083CD5E8
.DISPCNT: .word 0x04000000
.BLDCNT: .word 0x04000050
.BLDALPHA: .word 0x04000052
.MOSAIC: .word 0x0400004C
.PAL_DEST: .word 0x05000200 + 0x1C0
.POKEMON_GETATTR: .word 0x0803FBE8 + 1
.POKEMON_PARTY: .word 0x02024284
.STATUS_GRAPHICS_IMG: .word 0x08E9BF48
.STATUS_GRAPHICS_PAL: .word 0x08E9BF28

Screenshots:

I caught a Pikachu, and my Bulbasaur was paralysed in the process:
"image removed"

Here is the HUD reflecting that change:
"image removed"

I then battled a Weedle with my Pikachu, and got poisoned:

"image removed"
"image removed"

And the HUD shows my entire party's status ailments:
"image removed"

 

[kearnseyboy6]

That is really, really amazing! Great work. I look forward to it being completed!

 

[Mana1]

Looks pretty good so far! Do the images for PSN and PAR disappear if you interact with a person? Or do they interfere in anyway with textboxes?

This has potential for a tonne of RPG-style features. Number of pokeballs? Event ticks? Capture the flags? Your idea is genius and a great stepping stone to some new, unique features among FR hacks.

 

[J9794]

awesome, really freaking awesome

 

[Le pug]

Hunger and thirsty... systems my hack needs since youre stranded on an island. So it's possible to have it to where... you do this and maybe after 1000 steps you have like a battery life and it drains by 1 bar or so ?

 

[cscof]

It would be cool if the HUD would show if your party is doing well or not, as in the HUD would be green if all your pokes have full health/pp and no status ailments, yellow around half/ with status ailments, and red if you need to get to a pokecenter right away

 

[hydrostorm]

you may also want to take that woman off the top of that building before she falls and breaks a bone or something

There is a reason why the offset is 0xDEADBEEF as in DEAD BEEF.

Where 0xDEADBEEF is the offset of your new routine.

 

[Chronosplit]

There is a reason why the offset is 0xDEADBEEF as in DEAD BEEF.

She's secretly a Miltank! D:

This could actually be a pretty cool update for the VS Seeker: display a bar after using it or a counter of how many steps are left until it's recharged. Or maybe even a little tiny compass/itemfinder in the corner.

 

[Danny0317]

So while Touched is working hard to make this available, you guys are making jokes about old ladies and "DEADBEEF.."

Really guys? Really?

Anyways Touched, this is looking great. Perhpahs a world map icon would be good to? Just a suggestion :)

 

[Shiny Quagsire]

Or perhaps display an RTC in the corner of the screen, or even a repel step counter, either of which using a micro-sized font. Both of those would be useful to players.

For RTC it might be neat to have it like the clocks in Animal Crossing, where it pops out if you idle for a few seconds.

 

[Spherical Ice]

You could perhaps use DavidJCobb's Coin Case message box hack to display the time in a textbox.

 

[cscof]

Maybe the HUD could serve as a mini-version of the bottom screen of a DS

 

[Touched]

I found the offset where you can inject the HUD for Emerald: 0808A24E

That's the same routine as in the first post, so the procedure for injecting should identical.

I'm gonna move this to a C build, since that's easier.